t/lei-import-maildir.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use Cwd qw(abs_path);
   6 test_lei(sub {
   7         my $md = "$ENV{HOME}/md";
   8         for ($md, "$md/new", "$md/cur", "$md/tmp") {
   9                 mkdir($_) or BAIL_OUT("mkdir $_: $!");
  10         }
  11         symlink(abs_path('t/data/0001.patch'), "$md/cur/x:2,S") or
  12                 BAIL_OUT "symlink $md $!";
  13         lei_ok(qw(import), $md, \'import Maildir');
  14         my $imp_err = $lei_err;
  15
  16         my %i;
  17         lei_ok('inspect', $md); $i{no_type} = $lei_out;
  18         lei_ok('inspect', "maildir:$md"), $i{with_type} = $lei_out;
  19         lei_ok(['inspect', $md], undef, { -C => $ENV{HOME}, %$lei_opt });
  20         $i{rel_no_type} = $lei_out;
  21         lei_ok(['inspect', "maildir:$md"], undef,
  22                 { -C => $ENV{HOME}, %$lei_opt });
  23         $i{rel_with_type} = $lei_out;
  24         my %v = map { $_ => 1 } values %i;
  25         is(scalar(keys %v), 1, 'inspect handles relative and absolute paths');
  26         my $inspect = json_utf8->decode([ keys %v ]->[0]);
  27         is_deeply($inspect, {"maildir:$md" => { 'name.count' => 1 }},
  28                 'inspect maildir: path had expected output');
  29
  30         lei_ok(qw(q s:boolean));
  31         my $res = json_utf8->decode($lei_out);
  32         like($res->[0]->{'s'}, qr/use boolean/, 'got expected result')
  33                         or diag explain($imp_err, $res);
  34         is_deeply($res->[0]->{kw}, ['seen'], 'keyword set');
  35         is($res->[1], undef, 'only got one result');
  36
  37         lei_ok('inspect', "blob:$res->[0]->{blob}");
  38         $inspect = json_utf8->decode($lei_out);
  39         is(ref(delete $inspect->{"lei/store"}), 'ARRAY', 'lei/store IDs');
  40         is_deeply($inspect, { sync => { "maildir:$md" => [ 'x:2,S' ] } },
  41                 'maildir sync info as expected');
  42
  43         lei_ok qw(ls-sync);
  44         is($lei_out, "maildir:$md\n", 'ls-sync as expected');
  45
  46         lei_ok(qw(import), $md, \'import Maildir again');
  47         $imp_err = $lei_err;
  48         lei_ok(qw(q -d none s:boolean), \'lei q w/o dedupe');
  49         my $r2 = json_utf8->decode($lei_out);
  50         is_deeply($r2, $res, 'idempotent import')
  51                         or diag explain($imp_err, $res);
  52         rename("$md/cur/x:2,S", "$md/cur/x:2,SR") or BAIL_OUT "rename: $!";
  53         lei_ok('import', "maildir:$md", \'import Maildir after +answered');
  54         lei_ok(qw(q -d none s:boolean), \'lei q after +answered');
  55         $res = json_utf8->decode($lei_out);
  56         like($res->[0]->{'s'}, qr/use boolean/, 'got expected result');
  57         is_deeply($res->[0]->{kw}, ['answered', 'seen'], 'keywords set');
  58         is($res->[1], undef, 'only got one result');
  59
  60         symlink(abs_path('t/utf8.eml'), "$md/cur/u:2,ST") or
  61                 BAIL_OUT "symlink $md $!";
  62         lei_ok('import', "maildir:$md", \'import Maildir w/ trashed message');
  63         $imp_err = $lei_err;
  64         lei_ok(qw(q -d none m:testmessage@example.com));
  65         $res = json_utf8->decode($lei_out);
  66         is_deeply($res, [ undef ], 'trashed message not imported')
  67                         or diag explain($imp_err, $res);
  68 });
  69 done_testing;