t/lei-mirror.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use PublicInbox::Inbox;
   6 require_mods(qw(-httpd lei));
   7 require_cmd('curl');
   8 my $sock = tcp_server();
   9 my ($tmpdir, $for_destroy) = tmpdir();
  10 my $http = 'http://'.tcp_host_port($sock);
  11 my ($ro_home, $cfg_path) = setup_public_inboxes;
  12 my $cmd = [ qw(-httpd -W0 ./t/lei-mirror.psgi),
  13         "--stdout=$tmpdir/out", "--stderr=$tmpdir/err" ];
  14 my $td = start_script($cmd, { PI_CONFIG => $cfg_path }, { 3 => $sock });
  15 test_lei({ tmpdir => $tmpdir }, sub {
  16         my $home = $ENV{HOME};
  17         my $t1 = "$home/t1-mirror";
  18         lei_ok('add-external', $t1, '--mirror', "$http/t1/", \'--mirror v1');
  19         ok(-f "$t1/public-inbox/msgmap.sqlite3", 't1-mirror indexed');
  20         is(PublicInbox::Inbox::try_cat("$t1/description"),
  21                 "mirror of $http/t1/\n", 'description set');
  22
  23         lei_ok('ls-external');
  24         like($lei_out, qr!\Q$t1\E!, 't1 added to ls-externals');
  25
  26         my $t2 = "$home/t2-mirror";
  27         lei_ok('add-external', $t2, '--mirror', "$http/t2/", \'--mirror v2');
  28         ok(-f "$t2/msgmap.sqlite3", 't2-mirror indexed');
  29         ok(-f "$t2/description", 't2 description');
  30         is(PublicInbox::Inbox::try_cat("$t2/description"),
  31                 "mirror of $http/t2/\n", 'description set');
  32
  33         lei_ok('ls-external');
  34         like($lei_out, qr!\Q$t2\E!, 't2 added to ls-externals');
  35
  36         ok(!lei('add-external', $t2, '--mirror', "$http/t2/"),
  37                 '--mirror fails if reused') or diag "$lei_err.$lei_out = $?";
  38         like($lei_err, qr/\Q$t2\E' already exists/, 'destination in error');
  39
  40         ok(!lei('add-external', "$home/t2\nnewline", '--mirror', "$http/t2/"),
  41                 '--mirror fails on newline');
  42         like($lei_err, qr/`\\n' not allowed/, 'newline noted in error');
  43
  44         lei_ok('ls-external');
  45         like($lei_out, qr!\Q$t2\E!, 'still in ls-externals');
  46         unlike($lei_out, qr!\Qnewline\E!, 'newline entry not added');
  47
  48         ok(!lei('add-external', "$t2-fail", '-Lmedium'), '--mirror v2');
  49         like($lei_err, qr/not a directory/, 'non-directory noted');
  50         ok(!-d "$t2-fail", 'destination not created on failure');
  51         lei_ok('ls-external');
  52         unlike($lei_out, qr!\Q$t2-fail\E!, 'not added to ls-external');
  53
  54         lei_ok('add-external', "$t1-pfx", '--mirror', "$http/pfx/t1/",
  55                         \'--mirror v1 w/ PSGI prefix');
  56         ok(!-e "$t1-pfx/mirror.done", 'no leftover mirror.done');
  57
  58         my $d = "$home/404";
  59         ok(!lei(qw(add-external --mirror), "$http/404", $d), 'mirror 404');
  60         unlike($lei_err, qr!unlink.*?404/mirror\.done!,
  61                 'no unlink failure message');
  62         ok(!-d $d, "`404' dir not created");
  63         lei_ok('ls-external');
  64         unlike($lei_out, qr!\Q$d\E!s, 'not added to ls-external');
  65
  66         my %phail = (
  67                 HTTPS => 'https://public-inbox.org/' . 'phail',
  68                 ONION =>
  69 'http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/' .
  70 'phail,'
  71         );
  72         for my $t (qw(HTTPS ONION)) {
  73         SKIP: {
  74                 my $k = "TEST_LEI_EXTERNAL_$t";
  75                 $ENV{$k} or skip "$k unset", 1;
  76                 my $url = $phail{$t};
  77                 my $dir = "phail-$t";
  78                 ok(!lei(qw(add-external -Lmedium --mirror),
  79                         $url, $dir), '--mirror non-existent v2');
  80                 is($? >> 8, 22, 'curl 404');
  81                 ok(!-d $dir, 'directory not created');
  82                 unlike($lei_err, qr/# mirrored/, 'no success message');
  83                 like($lei_err, qr/curl.*404/, "curl 404 shown for $k");
  84         } # SKIP
  85         } # for
  86 });
  87
  88 SKIP: {
  89         undef $sock;
  90         my $d = "$tmpdir/d";
  91         mkdir $d or xbail "mkdir $d $!";
  92         my $opt = { -C => $d, 2 => \(my $err) };
  93         ok(!run_script([qw(-clone -q), "$http/404"], undef, $opt), '404 fails');
  94         ok(!-d "$d/404", 'destination not created');
  95
  96         ok(run_script([qw(-clone -q -C), $d, "$http/t2"], undef, $opt),
  97                 '-clone succeeds on v2');
  98         ok(-f "$d/t2/git/0.git/config", 'epoch cloned');
  99
 100         # writeBitmaps is the default for bare repos in git 2.22+,
 101         # so we may stop setting it ourselves.
 102         0 and is(xqx(['git', "--git-dir=$d/t2/git/0.git", 'config',
 103                 qw(--bool repack.writeBitmaps)]), "true\n",
 104                 'write bitmaps set (via include.path=all.git/config');
 105
 106         is(xqx(['git', "--git-dir=$d/t2/git/0.git", 'config',
 107                 qw(include.path)]), "../../all.git/config\n",
 108                 'include.path set');
 109
 110         ok(-s "$d/t2/all.git/objects/info/alternates",
 111                 'all.git alternates created');
 112         ok(-f "$d/t2/manifest.js.gz", 'manifest saved');
 113         ok(!-e "$d/t2/mirror.done", 'no leftover mirror.done');
 114         ok(run_script([qw(-fetch -C), "$d/t2"], undef, $opt),
 115                 '-fetch succeeds w/ manifest.js.gz');
 116         unlike($err, qr/git fetch/, 'no fetch done w/ manifest');
 117         unlink("$d/t2/manifest.js.gz") or xbail "unlink $!";
 118         ok(run_script([qw(-fetch -C), "$d/t2"], undef, $opt),
 119                 '-fetch succeeds w/o manifest.js.gz');
 120         like($err, qr/git fetch/, 'fetch forced w/o manifest');
 121
 122         ok(run_script([qw(-clone -q -C), $d, "$http/t1"], undef, $opt),
 123                 'cloning v1 works');
 124         ok(-d "$d/t1", 'v1 cloned');
 125         ok(!-e "$d/t1/mirror.done", 'no leftover file');
 126         ok(-f "$d/t1/manifest.js.gz", 'manifest saved');
 127         ok(run_script([qw(-fetch -C), "$d/t1"], undef, $opt),
 128                 'fetching v1 works');
 129         unlike($err, qr/git fetch/, 'no fetch done w/ manifest');
 130         unlink("$d/t1/manifest.js.gz") or xbail "unlink $!";
 131         my $before = [ glob("$d/t1/*") ];
 132         ok(run_script([qw(-fetch -C), "$d/t1"], undef, $opt),
 133                 'fetching v1 works w/o manifest.js.gz');
 134         unlink("$d/t1/FETCH_HEAD"); # git internal
 135         like($err, qr/git fetch/, 'no fetch done w/ manifest');
 136         ok(unlink("$d/t1/manifest.js.gz"), 'manifest created');
 137         my $after = [ glob("$d/t1/*") ];
 138         is_deeply($before, $after, 'no new files created');
 139 }
 140
 141 ok($td->kill, 'killed -httpd');
 142 $td->join;
 143
 144 {
 145         require_ok 'PublicInbox::LeiMirror';
 146         my $mrr = { src => 'https://example.com/src/', dst => $tmpdir };
 147         my $exp = "mirror of https://example.com/src/\n";
 148         my $f = "$tmpdir/description";
 149         PublicInbox::LeiMirror::set_description($mrr);
 150         is(PublicInbox::Inbox::try_cat($f), $exp, 'description set on ENOENT');
 151
 152         my $fh;
 153         (open($fh, '>', $f) and close($fh)) or xbail $!;
 154         PublicInbox::LeiMirror::set_description($mrr);
 155         is(PublicInbox::Inbox::try_cat($f), $exp, 'description set on empty');
 156         (open($fh, '>', $f) and print $fh "x\n" and close($fh)) or xbail $!;
 157         is(PublicInbox::Inbox::try_cat($f), "x\n",
 158                 'description preserved if non-default');
 159 }
 160
 161 done_testing;