t/lei-mirror.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use PublicInbox::Inbox;
   6 require_mods(qw(-httpd lei));
   7 my $sock = tcp_server();
   8 my ($tmpdir, $for_destroy) = tmpdir();
   9 my $http = 'http://'.tcp_host_port($sock);
  10 my ($ro_home, $cfg_path) = setup_public_inboxes;
  11 my $cmd = [ qw(-httpd -W0 ./t/lei-mirror.psgi),
  12         "--stdout=$tmpdir/out", "--stderr=$tmpdir/err" ];
  13 my $td = start_script($cmd, { PI_CONFIG => $cfg_path }, { 3 => $sock });
  14 test_lei({ tmpdir => $tmpdir }, sub {
  15         my $home = $ENV{HOME};
  16         my $t1 = "$home/t1-mirror";
  17         lei_ok('add-external', $t1, '--mirror', "$http/t1/", \'--mirror v1');
  18         ok(-f "$t1/public-inbox/msgmap.sqlite3", 't1-mirror indexed');
  19         is(PublicInbox::Inbox::try_cat("$t1/description"),
  20                 "mirror of $http/t1/\n", 'description set');
  21
  22         lei_ok('ls-external');
  23         like($lei_out, qr!\Q$t1\E!, 't1 added to ls-externals');
  24
  25         my $t2 = "$home/t2-mirror";
  26         lei_ok('add-external', $t2, '--mirror', "$http/t2/", \'--mirror v2');
  27         ok(-f "$t2/msgmap.sqlite3", 't2-mirror indexed');
  28         ok(-f "$t2/description", 't2 description');
  29         is(PublicInbox::Inbox::try_cat("$t2/description"),
  30                 "mirror of $http/t2/\n", 'description set');
  31
  32         lei_ok('ls-external');
  33         like($lei_out, qr!\Q$t2\E!, 't2 added to ls-externals');
  34
  35         ok(!lei('add-external', $t2, '--mirror', "$http/t2/"),
  36                 '--mirror fails if reused') or diag "$lei_err.$lei_out = $?";
  37         like($lei_err, qr/\Q$t2\E' already exists/, 'destination in error');
  38
  39         ok(!lei('add-external', "$home/t2\nnewline", '--mirror', "$http/t2/"),
  40                 '--mirror fails on newline');
  41         like($lei_err, qr/`\\n' not allowed/, 'newline noted in error');
  42
  43         lei_ok('ls-external');
  44         like($lei_out, qr!\Q$t2\E!, 'still in ls-externals');
  45         unlike($lei_out, qr!\Qnewline\E!, 'newline entry not added');
  46
  47         ok(!lei('add-external', "$t2-fail", '-Lmedium'), '--mirror v2');
  48         like($lei_err, qr/not a directory/, 'non-directory noted');
  49         ok(!-d "$t2-fail", 'destination not created on failure');
  50         lei_ok('ls-external');
  51         unlike($lei_out, qr!\Q$t2-fail\E!, 'not added to ls-external');
  52
  53         lei_ok('add-external', "$t1-pfx", '--mirror', "$http/pfx/t1/",
  54                         \'--mirror v1 w/ PSGI prefix');
  55         ok(!-e "$t1-pfx/mirror.done", 'no leftover mirror.done');
  56
  57         my $d = "$home/404";
  58         ok(!lei(qw(add-external --mirror), "$http/404", $d), 'mirror 404');
  59         unlike($lei_err, qr!unlink.*?404/mirror\.done!,
  60                 'no unlink failure message');
  61         ok(!-d $d, "`404' dir not created");
  62         lei_ok('ls-external');
  63         unlike($lei_out, qr!\Q$d\E!s, 'not added to ls-external');
  64
  65         my %phail = (
  66                 HTTPS => 'https://public-inbox.org/' . 'phail',
  67                 ONION =>
  68 'http://7fh6tueqddpjyxjmgtdiueylzoqt6pt7hec3pukyptlmohoowvhde4yd.onion/' .
  69 'phail,'
  70         );
  71         for my $t (qw(HTTPS ONION)) {
  72         SKIP: {
  73                 my $k = "TEST_LEI_EXTERNAL_$t";
  74                 $ENV{$k} or skip "$k unset", 1;
  75                 my $url = $phail{$t};
  76                 my $dir = "phail-$t";
  77                 ok(!lei(qw(add-external -Lmedium --mirror),
  78                         $url, $dir), '--mirror non-existent v2');
  79                 is($? >> 8, 22, 'curl 404');
  80                 ok(!-d $dir, 'directory not created');
  81                 unlike($lei_err, qr/# mirrored/, 'no success message');
  82                 like($lei_err, qr/curl.*404/, "curl 404 shown for $k");
  83         } # SKIP
  84         } # for
  85 });
  86
  87 SKIP: {
  88         undef $sock;
  89         my $d = "$tmpdir/d";
  90         mkdir $d or xbail "mkdir $d $!";
  91         my $opt = { -C => $d, 2 => \(my $err) };
  92         ok(!run_script([qw(-clone -q), "$http/404"], undef, $opt), '404 fails');
  93         ok(!-d "$d/404", 'destination not created');
  94         delete $opt->{2};
  95
  96         ok(run_script([qw(-clone -q -C), $d, "$http/t2"], undef, $opt),
  97                 '-clone succeeds on v2');
  98         ok(-d "$d/t2/git/0.git", 'epoch cloned');
  99         ok(-f "$d/t2/manifest.js.gz", 'manifest saved');
 100         ok(!-e "$d/t2/mirror.done", 'no leftover mirror.done');
 101         ok(run_script([qw(-fetch -q -C), "$d/t2"], undef, $opt),
 102                 '-fetch succeeds w/ manifest.js.gz');
 103         unlink("$d/t2/manifest.js.gz") or xbail "unlink $!";
 104         ok(run_script([qw(-fetch -q -C), "$d/t2"], undef, $opt),
 105                 '-fetch succeeds w/o manifest.js.gz');
 106
 107         ok(run_script([qw(-clone -q -C), $d, "$http/t1"], undef, $opt),
 108                 'cloning v1 works');
 109         ok(-d "$d/t1", 'v1 cloned');
 110         ok(!-e "$d/t1/mirror.done", 'no leftover file');
 111         ok(run_script([qw(-fetch -q -C), "$d/t1"], undef, $opt),
 112                 'fetching v1 works');
 113         unlink("$d/t1/manifest.js.gz") or xbail "unlink $!";
 114         my $before = [ glob("$d/t1/*") ];
 115         ok(run_script([qw(-fetch -q -C), "$d/t1"], undef, $opt),
 116                 'fetching v1 works w/o manifest.js.gz');
 117         unlink("$d/t1/FETCH_HEAD"); # git internal
 118         ok(unlink("$d/t1/manifest.js.gz"), 'manifest created');
 119         my $after = [ glob("$d/t1/*") ];
 120         is_deeply($before, $after, 'no new files created');
 121 }
 122
 123 ok($td->kill, 'killed -httpd');
 124 $td->join;
 125
 126 {
 127         require_ok 'PublicInbox::LeiMirror';
 128         my $mrr = { src => 'https://example.com/src/', dst => $tmpdir };
 129         my $exp = "mirror of https://example.com/src/\n";
 130         my $f = "$tmpdir/description";
 131         PublicInbox::LeiMirror::set_description($mrr);
 132         is(PublicInbox::Inbox::try_cat($f), $exp, 'description set on ENOENT');
 133
 134         my $fh;
 135         (open($fh, '>', $f) and close($fh)) or xbail $!;
 136         PublicInbox::LeiMirror::set_description($mrr);
 137         is(PublicInbox::Inbox::try_cat($f), $exp, 'description set on empty');
 138         (open($fh, '>', $f) and print $fh "x\n" and close($fh)) or xbail $!;
 139         is(PublicInbox::Inbox::try_cat($f), "x\n",
 140                 'description preserved if non-default');
 141 }
 142
 143 done_testing;