t/lei-q-remote-import.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 require_git 2.6;
   6 require_mods(qw(json DBD::SQLite Search::Xapian));
   7 use PublicInbox::MboxReader;
   8 my ($ro_home, $cfg_path) = setup_public_inboxes;
   9 my $sock = tcp_server;
  10 my ($tmpdir, $for_destroy) = tmpdir;
  11 my $cmd = [ '-httpd', '-W0', "--stdout=$tmpdir/1", "--stderr=$tmpdir/2" ];
  12 my $env = { PI_CONFIG => $cfg_path };
  13 my $td = start_script($cmd, $env, { 3 => $sock }) or BAIL_OUT("-httpd: $?");
  14 my $host_port = tcp_host_port($sock);
  15 my $url = "http://$host_port/t2/";
  16 my $exp1 = [ eml_load('t/plack-qp.eml') ];
  17 my $exp2 = [ eml_load('t/iso-2202-jp.eml') ];
  18 my $slurp_emls = sub {
  19         open my $fh, '<', $_[0] or BAIL_OUT "open: $!";
  20         my @eml;
  21         PublicInbox::MboxReader->mboxrd($fh, sub {
  22                 my $eml = shift;
  23                 $eml->header_set('Status');
  24                 push @eml, $eml;
  25         });
  26         \@eml;
  27 };
  28
  29 test_lei({ tmpdir => $tmpdir }, sub {
  30         my $o = "$ENV{HOME}/o.mboxrd";
  31         my @cmd = ('q', '-o', "mboxrd:$o", 'm:qp@example.com');
  32         lei_ok(@cmd);
  33         ok(-f $o && !-s _, 'output exists but is empty');
  34         unlink $o or BAIL_OUT $!;
  35         lei_ok(@cmd, '-I', $url);
  36         is_deeply($slurp_emls->($o), $exp1, 'got results after remote search');
  37         unlink $o or BAIL_OUT $!;
  38         lei_ok(@cmd);
  39         ok(-f $o && -s _, 'output exists after import but is not empty') or
  40                 diag $lei_err;
  41         is_deeply($slurp_emls->($o), $exp1, 'got results w/o remote search');
  42         unlink $o or BAIL_OUT $!;
  43
  44         $cmd[-1] = 'm:199707281508.AAA24167@hoyogw.example';
  45         lei_ok(@cmd, '-I', $url, '--no-import-remote');
  46         is_deeply($slurp_emls->($o), $exp2, 'got another after remote search');
  47         unlink $o or BAIL_OUT $!;
  48         lei_ok(@cmd);
  49         ok(-f $o && !-s _, '--no-import-remote did not memoize');
  50
  51         open my $fh, '>', "$o.lock";
  52         $cmd[-1] = 'm:qp@example.com';
  53         unlink $o or BAIL_OUT $!;
  54         lei_ok(@cmd, '--lock=none');
  55         ok(-f $o && -s _, '--lock=none respected');
  56         unlink $o or BAIL_OUT $!;
  57         ok(!lei(@cmd, '--lock=dotlock,timeout=0.000001'), 'dotlock fails');
  58         ok(-f $o && !-s _, 'nothing output on lock failure');
  59         unlink "$o.lock" or BAIL_OUT $!;
  60         lei_ok(@cmd, '--lock=dotlock,timeout=0.000001',
  61                 \'succeeds after lock removal');
  62
  63         my $ibx = create_inbox 'local-external', indexlevel => 'medium', sub {
  64                 my ($im) = @_;
  65                 $im->add(eml_load('t/utf8.eml')) or BAIL_OUT '->add';
  66         };
  67         lei_ok(qw(add-external -q), $ibx->{inboxdir});
  68         lei_ok(qw(q -o), "mboxrd:$o", '--only', $url,
  69                 'm:testmessage@example.com');
  70         ok(-s $o, 'got result from remote external');
  71         my $exp = eml_load('t/utf8.eml');
  72         is_deeply($slurp_emls->($o), [$exp], 'got expected result');
  73         lei_ok(qw(q --no-external -o), "mboxrd:/dev/stdout",
  74                         'm:testmessage@example.com');
  75         is($lei_out, '', 'message not imported when in local external');
  76
  77         open $fh, '>', $o or BAIL_OUT;
  78         print $fh <<'EOF' or BAIL_OUT;
  79 From a@z Mon Sep 17 00:00:00 2001
  80 From: nobody@localhost
  81 Date: Sat, 13 Mar 2021 18:23:01 +0600
  82 Message-ID: <never-before-seen@example.com>
  83 Status: RO
  84
  85 whatever
  86 EOF
  87         close $fh or BAIL_OUT;
  88         lei_ok(qw(q -o), "mboxrd:$o", 'm:testmessage@example.com');
  89         is_deeply($slurp_emls->($o), [$exp],
  90                 'got expected result after clobber') or diag $lei_err;
  91         lei_ok(qw(q -o mboxrd:/dev/stdout m:never-before-seen@example.com));
  92         like($lei_out, qr/seen\@example\.com>\nStatus: OR\n\nwhatever/sm,
  93                 '--import-before imported totally unseen message');
  94 });
  95 done_testing;