t/lei-q-remote-import.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 require_mods(qw(lei -httpd));
   6 use PublicInbox::MboxReader;
   7 my ($ro_home, $cfg_path) = setup_public_inboxes;
   8 my $sock = tcp_server;
   9 my ($tmpdir, $for_destroy) = tmpdir;
  10 my $cmd = [ '-httpd', '-W0', "--stdout=$tmpdir/1", "--stderr=$tmpdir/2" ];
  11 my $env = { PI_CONFIG => $cfg_path };
  12 my $td = start_script($cmd, $env, { 3 => $sock }) or BAIL_OUT("-httpd: $?");
  13 my $host_port = tcp_host_port($sock);
  14 my $url = "http://$host_port/t2/";
  15 my $exp1 = [ eml_load('t/plack-qp.eml') ];
  16 my $exp2 = [ eml_load('t/iso-2202-jp.eml') ];
  17 my $slurp_emls = sub {
  18         open my $fh, '<', $_[0] or BAIL_OUT "open: $!";
  19         my @eml;
  20         PublicInbox::MboxReader->mboxrd($fh, sub {
  21                 my $eml = shift;
  22                 $eml->header_set('Status');
  23                 push @eml, $eml;
  24         });
  25         \@eml;
  26 };
  27
  28 test_lei({ tmpdir => $tmpdir }, sub {
  29         my $o = "$ENV{HOME}/o.mboxrd";
  30         my @cmd = ('q', '-o', "mboxrd:$o", 'm:qp@example.com');
  31         lei_ok(@cmd);
  32         ok(-f $o && !-s _, 'output exists but is empty');
  33         unlink $o or BAIL_OUT $!;
  34         lei_ok(@cmd, '-I', $url);
  35         is_deeply($slurp_emls->($o), $exp1, 'got results after remote search');
  36         unlink $o or BAIL_OUT $!;
  37         lei_ok(@cmd);
  38         ok(-f $o && -s _, 'output exists after import but is not empty') or
  39                 diag $lei_err;
  40         is_deeply($slurp_emls->($o), $exp1, 'got results w/o remote search');
  41         unlink $o or BAIL_OUT $!;
  42
  43         $cmd[-1] = 'm:199707281508.AAA24167@hoyogw.example';
  44         lei_ok(@cmd, '-I', $url, '--no-import-remote');
  45         is_deeply($slurp_emls->($o), $exp2, 'got another after remote search');
  46         unlink $o or BAIL_OUT $!;
  47         lei_ok(@cmd);
  48         ok(-f $o && !-s _, '--no-import-remote did not memoize');
  49
  50         open my $fh, '>', "$o.lock";
  51         $cmd[-1] = 'm:qp@example.com';
  52         unlink $o or BAIL_OUT $!;
  53         lei_ok(@cmd, '--lock=none');
  54         ok(-f $o && -s _, '--lock=none respected');
  55         unlink $o or BAIL_OUT $!;
  56         ok(!lei(@cmd, '--lock=dotlock,timeout=0.000001'), 'dotlock fails');
  57         ok(-f $o && !-s _, 'nothing output on lock failure');
  58         unlink "$o.lock" or BAIL_OUT $!;
  59         lei_ok(@cmd, '--lock=dotlock,timeout=0.000001',
  60                 \'succeeds after lock removal');
  61
  62         my $ibx = create_inbox 'local-external', indexlevel => 'medium', sub {
  63                 my ($im) = @_;
  64                 $im->add(eml_load('t/utf8.eml')) or BAIL_OUT '->add';
  65         };
  66         lei_ok(qw(add-external -q), $ibx->{inboxdir});
  67         lei_ok(qw(q -q -o), "mboxrd:$o", '--only', $url,
  68                 'm:testmessage@example.com');
  69         is($lei_err, '', 'no warnings or errors');
  70         ok(-s $o, 'got result from remote external');
  71         my $exp = eml_load('t/utf8.eml');
  72         is_deeply($slurp_emls->($o), [$exp], 'got expected result');
  73         lei_ok(qw(q --no-external -o), "mboxrd:/dev/stdout",
  74                         'm:testmessage@example.com');
  75         is($lei_out, '', 'message not imported when in local external');
  76
  77         open $fh, '>', $o or BAIL_OUT;
  78         print $fh <<'EOF' or BAIL_OUT;
  79 From a@z Mon Sep 17 00:00:00 2001
  80 From: nobody@localhost
  81 Date: Sat, 13 Mar 2021 18:23:01 +0600
  82 Message-ID: <never-before-seen@example.com>
  83 Status: OR
  84
  85 whatever
  86 EOF
  87         close $fh or BAIL_OUT;
  88         lei_ok(qw(q -o), "mboxrd:$o", 'm:testmessage@example.com');
  89         is_deeply($slurp_emls->($o), [$exp],
  90                 'got expected result after clobber') or diag $lei_err;
  91         lei_ok(qw(q -o mboxrd:/dev/stdout m:never-before-seen@example.com));
  92         like($lei_out, qr/seen\@example\.com>\nStatus: RO\n\nwhatever/sm,
  93                 '--import-before imported totally unseen message');
  94 });
  95 done_testing;