t/lei-q-save.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 use PublicInbox::Smsg;
   6 use List::Util qw(sum);
   7
   8 my $doc1 = eml_load('t/plack-qp.eml');
   9 $doc1->header_set('Date', PublicInbox::Smsg::date({ds => time - (86400 * 5)}));
  10 my $doc2 = eml_load('t/utf8.eml');
  11 $doc2->header_set('Date', PublicInbox::Smsg::date({ds => time - (86400 * 4)}));
  12 my $doc3 = eml_load('t/msg_iter-order.eml');
  13 $doc3->header_set('Date', PublicInbox::Smsg::date({ds => time - (86400 * 4)}));
  14
  15 my $pre_existing = <<'EOF';
  16 From x Mon Sep 17 00:00:00 2001
  17 Message-ID: <import-before@example.com>
  18 Subject: pre-existing
  19 Date: Sat, 02 Oct 2010 00:00:00 +0000
  20
  21 blah
  22 EOF
  23
  24 test_lei(sub {
  25         my $home = $ENV{HOME};
  26         my $in = $doc1->as_string;
  27         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
  28         lei_ok qw(q -q z:0.. d:last.week..), '-o', "MAILDIR:$home/md/";
  29         my %before = map { $_ => 1 } glob("$home/md/cur/*");
  30         my $f = (keys %before)[0] or xbail({before => \%before});
  31         is_deeply(eml_load($f), $doc1, 'doc1 matches');
  32         lei_ok qw(ls-mail-sync);
  33         is($lei_out, "maildir:$home/md\n", 'canonicalized mail sync name');
  34
  35         my @s = glob("$home/.local/share/lei/saved-searches/md-*");
  36         is(scalar(@s), 1, 'got one saved search');
  37         my $cfg = PublicInbox::Config->new("$s[0]/lei.saved-search");
  38         is($cfg->{'lei.q.output'}, "maildir:$home/md", 'canonicalized output');
  39         is_deeply($cfg->{'lei.q'}, ['z:0..', 'd:last.week..'],
  40                 'store relative time, not parsed (absolute) timestamp');
  41
  42         # ensure "lei up" works, since it compliments "lei q --save"
  43         $in = $doc2->as_string;
  44         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
  45         lei_ok qw(up -q md -C), $home;
  46         lei_ok qw(up -q . -C), "$home/md";
  47         lei_ok qw(up -q), "/$home/md";
  48         my %after = map { $_ => 1 } glob("$home/md/{new,cur}/*");
  49         is(delete $after{(keys(%before))[0]}, 1, 'original message kept');
  50         is(scalar(keys %after), 1, 'one new message added');
  51         $f = (keys %after)[0] or xbail({after => \%after});
  52         is_deeply(eml_load($f), $doc2, 'doc2 matches');
  53
  54         # check stdin
  55         lei_ok [qw(q - -o), "mboxcl2:mbcl2" ], undef,
  56                 { -C => $home, %$lei_opt, 0 => \'d:last.week..'};
  57         @s = glob("$home/.local/share/lei/saved-searches/mbcl2-*");
  58         $cfg = PublicInbox::Config->new("$s[0]/lei.saved-search");
  59         is_deeply $cfg->{'lei.q'}, 'd:last.week..',
  60                 'q --stdin stores relative time';
  61         my $size = -s "$home/mbcl2";
  62         ok(defined($size) && $size > 0, 'results written');
  63         lei_ok([qw(up mbcl2)], undef, { -C => $home, %$lei_opt });
  64         is(-s "$home/mbcl2", $size, 'size unchanged on noop up');
  65
  66         $in = $doc3->as_string;
  67         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
  68         lei_ok([qw(up mbcl2)], undef, { -C => $home, %$lei_opt });
  69         ok(-s "$home/mbcl2" > $size, 'size increased after up');
  70
  71         ok(!lei(qw(up -q), $home), 'up fails on unknown dir');
  72         like($lei_err, qr/--no-save was used/, 'error noted --no-save');
  73
  74         lei_ok(qw(q --no-save d:last.week.. -q -o), "$home/no-save");
  75         ok(!lei(qw(up -q), "$home/no-save"), 'up fails on --no-save');
  76         like($lei_err, qr/--no-save was used/, 'error noted --no-save');
  77
  78         lei_ok qw(ls-search); my @d = split(/\n/, $lei_out);
  79         lei_ok qw(ls-search -z); my @z = split(/\0/, $lei_out);
  80         is_deeply(\@d, \@z, '-z output matches non-z');
  81         is_deeply(\@d, [ "$home/mbcl2", "$home/md" ],
  82                 'ls-search output alphabetically sorted');
  83         lei_ok qw(ls-search -l);
  84         my $json = PublicInbox::Config->json->decode($lei_out);
  85         ok($json && $json->[0]->{output}, 'JSON has output');
  86         lei_ok qw(_complete lei up);
  87         like($lei_out, qr!^\Q$home/mbcl2\E$!sm, 'complete got mbcl2 output');
  88         like($lei_out, qr!^\Q$home/md\E$!sm, 'complete got maildir output');
  89
  90         unlink("$home/mbcl2") or xbail "unlink $!";
  91         lei_ok qw(_complete lei up);
  92         like($lei_out, qr!^\Q$home/mbcl2\E$!sm,
  93                 'mbcl2 output shown despite unlink');
  94         lei_ok([qw(up mbcl2)], undef, { -C => $home, %$lei_opt });
  95         ok(-f "$home/mbcl2"  && -s _ == 0, 'up recreates on missing output');
  96
  97         # no --augment
  98         open my $mb, '>', "$home/mbrd" or xbail "open $!";
  99         print $mb $pre_existing;
 100         close $mb or xbail "close: $!";
 101         lei_ok(qw(q -o mboxrd:mbrd m:qp@example.com -C), $home);
 102         open $mb, '<', "$home/mbrd" or xbail "open $!";
 103         is_deeply([grep(/pre-existing/, <$mb>)], [],
 104                 'pre-existing messsage gone w/o augment');
 105         close $mb;
 106         lei_ok(qw(q m:import-before@example.com));
 107         is(json_utf8->decode($lei_out)->[0]->{'s'},
 108                 'pre-existing', '--save imported before clobbering');
 109
 110         # --augment
 111         open $mb, '>', "$home/mbrd-aug" or xbail "open $!";
 112         print $mb $pre_existing;
 113         close $mb or xbail "close: $!";
 114         lei_ok(qw(q -a -o mboxrd:mbrd-aug m:qp@example.com -C), $home);
 115         open $mb, '<', "$home/mbrd-aug" or xbail "open $!";
 116         $mb = do { local $/; <$mb> };
 117         like($mb, qr/pre-existing/, 'pre-existing message preserved w/ -a');
 118         like($mb, qr/<qp\@example\.com>/, 'new result written w/ -a');
 119
 120         lei_ok(qw(up --all=local));
 121
 122         ok(!lei(qw(forget-search), "$home/bogus"), 'bogus forget');
 123         like($lei_err, qr/--save was not used/, 'error noted --save');
 124
 125         lei_ok qw(_complete lei forget-search);
 126         like($lei_out, qr/mbrd-aug/, 'forget-search completion');
 127         lei_ok(qw(forget-search -v), "$home/mbrd-aug");
 128         is($lei_out, '', 'no output');
 129         like($lei_err, qr/\bmbrd-aug\b/, '-v (verbose) reported unlinks');
 130         lei_ok qw(_complete lei forget-search);
 131         unlike($lei_out, qr/mbrd-aug/,
 132                 'forget-search completion cleared after forget');
 133         ok(!lei('up', "$home/mbrd-aug"), 'lei up fails after forget');
 134         like($lei_err, qr/--no-save was used/, 'error noted --no-save');
 135
 136         # dedupe=mid
 137         my $o = "$home/dd-mid";
 138         $in = $doc2->as_string . "\n-------\nappended list sig\n";
 139         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
 140         lei_ok(qw(q --dedupe=mid m:testmessage@example.com -o), $o);
 141         my @m = glob("$o/cur/*");
 142         is(scalar(@m), 1, '--dedupe=mid w/ --save');
 143         $in = $doc2->as_string . "\n-------\nanother list sig\n";
 144         lei_ok [qw(import -q -F eml -)], undef, { 0 => \$in, %$lei_opt };
 145         lei_ok 'up', $o;
 146         is_deeply([glob("$o/cur/*")], \@m, 'lei up dedupe=mid works');
 147
 148         for my $dd (qw(content)) {
 149                 $o = "$home/dd-$dd";
 150                 lei_ok(qw(q m:testmessage@example.com -o), $o, "--dedupe=$dd");
 151                 @m = glob("$o/cur/*");
 152                 is(scalar(@m), 3, 'all 3 matches with dedupe='.$dd);
 153         }
 154
 155         # dedupe=oid
 156         $o = "$home/dd-oid";
 157         my $ibx = create_inbox 'ibx', indexlevel => 'medium',
 158                         tmpdir => "$home/v1", sub {};
 159         lei_ok(qw(q --dedupe=oid m:qp@example.com -o), $o,
 160                 '-I', $ibx->{inboxdir});
 161         @m = glob("$o/cur/*");
 162         is(scalar(@m), 1, 'got first result');
 163
 164         my $im = $ibx->importer(0);
 165         my $diff = "X-Insignificant-Header: x\n".$doc1->as_string;
 166         $im->add(PublicInbox::Eml->new($diff));
 167         $im->done;
 168         lei_ok('up', $o);
 169         @m = glob("$o/{new,cur}/*");
 170         is(scalar(@m), 2, 'got 2nd result due to different OID');
 171
 172         SKIP: {
 173                 symlink($o, "$home/ln -s") or
 174                         skip "symlinks not supported in $home?: $!", 1;
 175                 lei_ok('up', "$home/ln -s");
 176                 lei_ok('forget-search', "$home/ln -s");
 177         };
 178
 179         my $v2 = "$home/v2"; # v2: as an output destination
 180         my (@before, @after);
 181         require PublicInbox::MboxReader;
 182         lei_ok(qw(q z:0.. -o), "v2:$v2");
 183         like($lei_err, qr/^# ([1-9][0-9]*) written to \Q$v2\E/sm,
 184                 'non-zero write output to stderr');
 185         lei_ok(qw(q z:0.. -o), "mboxrd:$home/before", '--only', $v2, '-j1,1');
 186         open my $fh, '<', "$home/before";
 187         PublicInbox::MboxReader->mboxrd($fh, sub { push @before, $_[0] });
 188         isnt(scalar(@before), 0, 'initial v2 written');
 189         my $orig = sum(map { -f $_ ? -s _ : () } (
 190                         glob("$v2/git/0.git/objects/*/*")));
 191         lei_ok(qw(import t/data/0001.patch));
 192         lei_ok 'up', $v2;
 193         lei_ok(qw(q z:0.. -o), "mboxrd:$home/after", '--only', $v2, '-j1,1');
 194         open $fh, '<', "$home/after";
 195         PublicInbox::MboxReader->mboxrd($fh, sub { push @after, $_[0] });
 196
 197         my $last = shift @after;
 198         $last->header_set('Status');
 199         is_deeply($last, eml_load('t/data/0001.patch'), 'lei up worked on v2');
 200         is_deeply(\@before, \@after, 'got same results');
 201
 202         my $v2s = "$home/v2s";
 203         lei_ok(qw(q --shared z:0.. -o), "v2:$v2s");
 204         my $shared = sum(map { -f $_ ? -s _ : () } (
 205                         glob("$v2s/git/0.git/objects/*/*")));
 206         ok($shared < $orig, 'fewer bytes stored with --shared') or
 207                 diag "shared=$shared orig=$orig";
 208
 209         lei_ok([qw(edit-search), $v2s], { VISUAL => 'cat', EDITOR => 'cat' });
 210         like($lei_out, qr/^\[lei/sm, 'edit-search can cat');
 211
 212         lei_ok('-C', "$home/v2s", qw(q -q -o ../s m:testmessage@example.com));
 213         lei_ok qw(ls-search);
 214         unlike $lei_out, qr{/\.\./s$}sm, 'relative path not in ls-search';
 215         like $lei_out, qr{^\Q$home\E/s$}sm,
 216                 'absolute path appears in ls-search';
 217         lei_ok qw(up ../s -C), "$home/v2s", \'relative lei up';
 218         lei_ok qw(up), "$home/s", \'absolute lei up';
 219
 220         # mess up a config file
 221         my @lss = glob("$home/" .
 222                 '.local/share/lei/saved-searches/*/lei.saved-search');
 223         my $out = xqx([qw(git config -f), $lss[0], 'lei.q.output']);
 224         xsys($^X, qw(-i -p -e), "s/\\[/\\0/", $lss[0])
 225                 and xbail "-ipe $lss[0]: $?";
 226         lei_ok qw(ls-search);
 227         like($lei_err, qr/bad config line.*?\Q$lss[0]\E/,
 228                 'git config parse error shown w/ lei ls-search');
 229         lei_ok qw(up --all), \'up works with bad config';
 230         like($lei_err, qr/bad config line.*?\Q$lss[0]\E/,
 231                 'git config parse error shown w/ lei up');
 232         xsys($^X, qw(-i -p -e), "s/\\0/\\[/", $lss[0])
 233                 and xbail "-ipe $lss[0]: $?";
 234         lei_ok qw(ls-search);
 235         is($lei_err, '', 'no errors w/ fixed config');
 236 });
 237 done_testing;