t/lei-tag.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 require_git 2.6;
   6 require_mods(qw(json DBD::SQLite Search::Xapian));
   7 my ($ro_home, $cfg_path) = setup_public_inboxes;
   8 my $check_kw = sub {
   9         my ($exp, %opt) = @_;
  10         my $args = $opt{args} // [];
  11         my $mid = $opt{mid} // 'testmessage@example.com';
  12         lei_ok('q', "m:$mid", @$args);
  13         my $res = json_utf8->decode($lei_out);
  14         is($res->[1], undef, 'only got one result');
  15         my $msg = $opt{msg} ? " $opt{msg}" : '';
  16         ($exp ? is_deeply($res->[0]->{kw}, $exp, "got @$exp$msg")
  17                 : is($res->[0]->{kw}, undef, "got undef$msg")) or
  18                         diag explain($res);
  19         if (exists $opt{L}) {
  20                 $exp = $opt{L};
  21                 ($exp ? is_deeply($res->[0]->{L}, $exp, "got @$exp$msg")
  22                         : is($res->[0]->{L}, undef, "got undef$msg")) or
  23                                 diag explain($res);
  24         }
  25 };
  26
  27 test_lei(sub {
  28         lei_ok(qw(ls-label)); is($lei_out, '', 'no labels, yet');
  29         lei_ok(qw(import t/utf8.eml));
  30         lei_ok(qw(tag t/utf8.eml +kw:flagged +L:urgent));
  31         $check_kw->(['flagged'], L => ['urgent']);
  32         lei_ok(qw(ls-label)); is($lei_out, "urgent\n", 'label found');
  33         ok(!lei(qw(tag -F eml t/utf8.eml +kw:seeen)), 'bad kw rejected');
  34         like($lei_err, qr/`seeen' is not one of/, 'got helpful error');
  35
  36         ok(!lei(qw(tag -F eml t/utf8.eml +k:seen)), 'bad prefix rejected');
  37         like($lei_err, qr/Unable to handle.*\Q+k:seen\E/, 'bad prefix noted');
  38
  39         ok(!lei(qw(tag -F eml t/utf8.eml)), 'no keywords');
  40         like($lei_err, qr/no keywords or labels specified/,
  41                 'lack of kw/L noted');
  42
  43         my $mb = "$ENV{HOME}/mb";
  44         my $md = "$ENV{HOME}/md";
  45         lei_ok(qw(q m:testmessage@example.com -o), "mboxrd:$mb");
  46         ok(-s $mb, 'wrote mbox result');
  47         lei_ok(qw(q m:testmessage@example.com -o), $md);
  48         my @fn = glob("$md/cur/*");
  49         scalar(@fn) == 1 or xbail $lei_err, 'no mail', \@fn;
  50         rename($fn[0], "$fn[0]S") or BAIL_OUT "rename $!";
  51         $check_kw->(['flagged'], msg => 'after bad request');
  52         lei_ok(qw(tag -F eml t/utf8.eml -kw:flagged));
  53         $check_kw->(undef, msg => 'keyword cleared');
  54         lei_ok(qw(tag -F mboxrd +kw:seen), $mb);
  55         $check_kw->(['seen'], msg => 'mbox Status ignored');
  56         lei_ok(qw(tag -kw:seen +kw:answered), $md);
  57         $check_kw->(['answered'], msg => 'Maildir Status ignored');
  58
  59         open my $in, '<', 't/utf8.eml' or BAIL_OUT $!;
  60         lei_ok([qw(tag -F eml - +kw:seen +L:nope)],
  61                 undef, { %$lei_opt, 0 => $in });
  62         $check_kw->(['answered', 'seen'], msg => 'stdin works');
  63         lei_ok(qw(q L:urgent));
  64         my $res = json_utf8->decode($lei_out);
  65         is($res->[0]->{'m'}, 'testmessage@example.com', 'L: query works');
  66         lei_ok(qw(q kw:seen));
  67         my $r2 = json_utf8->decode($lei_out);
  68         is_deeply($r2, $res, 'kw: query works, too') or
  69                 diag explain([$r2, $res]);
  70
  71         lei_ok(qw(_complete lei tag));
  72         my %c = map { $_ => 1 } split(/\s+/, $lei_out);
  73         ok($c{'+L:urgent'} && $c{'-L:urgent'} &&
  74                 $c{'+L:nope'} && $c{'-L:nope'}, 'completed with labels');
  75
  76         my $mid = 'qp@example.com';
  77         lei_ok qw(q -f mboxrd --only), "$ro_home/t2", "mid:$mid";
  78         $in = $lei_out;
  79         lei_ok [qw(tag -F mboxrd --stdin +kw:seen +L:qp)],
  80                 undef, { %$lei_opt, 0 => \$in };
  81         $check_kw->(['seen'], L => ['qp'], mid => $mid,
  82                         args => [ '--only', "$ro_home/t2" ],
  83                         msg => 'external-only message');
  84         lei_ok(qw(ls-label));
  85         is($lei_out, "nope\nqp\nurgent\n", 'ls-label shows qp');
  86
  87         lei_ok qw(tag -F eml t/utf8.eml +L:inbox +L:x);
  88         lei_ok qw(q m:testmessage@example.com);
  89         $check_kw->([qw(answered seen)], L => [qw(inbox nope urgent x)]);
  90         lei_ok(qw(ls-label));
  91         is($lei_out, "inbox\nnope\nqp\nurgent\nx\n", 'ls-label shows qp');
  92
  93         lei_ok qw(q L:inbox);
  94         is(json_utf8->decode($lei_out)->[0]->{blob},
  95                 $r2->[0]->{blob}, 'label search works');
  96
  97         ok(!lei(qw(tag -F eml t/utf8.eml +L:ALLCAPS)), '+L:ALLCAPS fails');
  98         lei_ok(qw(ls-label));
  99         is($lei_out, "inbox\nnope\nqp\nurgent\nx\n", 'ls-label unchanged');
 100
 101         if (0) { # TODO label+kw search w/ externals
 102                 lei_ok(qw(q L:qp), "mid:$mid", '--only', "$ro_home/t2");
 103         }
 104 });
 105 done_testing;