t/lei_mail_sync.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 require_mods(qw(DBD::SQLite));
   8 require_ok 'PublicInbox::LeiMailSync';
   9 my ($dir, $for_destroy) = tmpdir();
  10 my $lms = PublicInbox::LeiMailSync->new("$dir/t.sqlite3");
  11
  12 $lms->lms_begin;
  13 $lms->lms_commit;
  14 my $ro = PublicInbox::LeiMailSync->new("$dir/t.sqlite3");
  15 is_deeply([$ro->folders], [], 'no folders, yet');
  16
  17 my $imap = 'imaps://bob@[::1]/INBOX;UIDVALIDITY=9';
  18 $lms->lms_begin;
  19 is($lms->set_src('deadbeef', $imap, 1), 1, 'set IMAP once');
  20 ok($lms->set_src('deadbeef', $imap, 1) == 0, 'set IMAP idempotently');
  21 $lms->lms_commit;
  22 is_deeply([$ro->folders], [$imap], 'IMAP folder added');
  23 is_deeply([$ro->folders($imap)], [$imap], 'IMAP folder with full GLOB');
  24 is_deeply([$ro->folders('imaps://bob@[::1]/INBOX')], [$imap],
  25                 'IMAP folder with partial GLOB');
  26
  27 is_deeply($ro->locations_for('deadbeef'),
  28         { $imap => [ 1 ] }, 'locations_for w/ imap');
  29
  30 my $maildir = 'maildir:/home/user/md';
  31 my $fname = 'foo:2,S';
  32 $lms->lms_begin;
  33 ok($lms->set_src('deadbeef', $maildir, \$fname), 'set Maildir once');
  34 ok($lms->set_src('deadbeef', $maildir, \$fname) == 0, 'set Maildir again');
  35 $lms->lms_commit;
  36 is_deeply($ro->locations_for('deadbeef'),
  37         { $imap => [ 1 ], $maildir => [ $fname ] },
  38         'locations_for w/ maildir + imap');
  39
  40 is_deeply([sort($ro->folders)], [$imap, $maildir], 'both folders shown');
  41 my @res;
  42 $ro->each_src($maildir, sub {
  43         my ($oidbin, $id) = @_;
  44         push @res, [ unpack('H*', $oidbin), $id ];
  45 });
  46 is_deeply(\@res, [ ['deadbeef', \$fname] ], 'each_src works on Maildir');
  47
  48 @res = ();
  49 $ro->each_src($imap, sub {
  50         my ($oidbin, $id) = @_;
  51         push @res, [ unpack('H*', $oidbin), $id ];
  52 });
  53 is_deeply(\@res, [ ['deadbeef', 1] ], 'each_src works on IMAP');
  54
  55 is_deeply($ro->location_stats($maildir), { 'name.count' => 1 },
  56         'Maildir location stats');
  57 is_deeply($ro->location_stats($imap),
  58         { 'uid.count' => 1, 'uid.max' => 1, 'uid.min' => 1 },
  59         'IMAP location stats');
  60 $lms->lms_begin;
  61 is($lms->clear_src($imap, 1), 1, 'clear_src on IMAP');
  62 is($lms->clear_src($maildir, \$fname), 1, 'clear_src on Maildir');
  63 ok($lms->clear_src($imap, 1) == 0, 'clear_src again on IMAP');
  64 ok($lms->clear_src($maildir, \$fname) == 0, 'clear_src again on Maildir');
  65 $lms->lms_commit;
  66 is_deeply($ro->location_stats($maildir), {}, 'nothing left');
  67
  68 done_testing;