t/lei_mail_sync.t

   1 #!perl -w
   2 # Copyright (C) 2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 require_mods(qw(DBD::SQLite));
   8 require_ok 'PublicInbox::LeiMailSync';
   9 my ($dir, $for_destroy) = tmpdir();
  10 my $lms = PublicInbox::LeiMailSync->new("$dir/t.sqlite3");
  11
  12 $lms->lms_begin;
  13 $lms->lms_commit;
  14 my $ro = PublicInbox::LeiMailSync->new("$dir/t.sqlite3");
  15 is_deeply([$ro->folders], [], 'no folders, yet');
  16
  17 my $imap = 'imaps://bob@[::1]/INBOX;UIDVALIDITY=9';
  18 $lms->lms_begin;
  19 my $deadbeef = "\xde\xad\xbe\xef";
  20 is($lms->set_src($deadbeef, $imap, 1), 1, 'set IMAP once');
  21 ok($lms->set_src($deadbeef, $imap, 1) == 0, 'set IMAP idempotently');
  22 $lms->lms_commit;
  23 is_deeply([$ro->folders], [$imap], 'IMAP folder added');
  24 is_deeply([$ro->folders($imap)], [$imap], 'IMAP folder with full GLOB');
  25 is_deeply([$ro->folders('imaps://bob@[::1]/INBOX')], [$imap],
  26                 'IMAP folder with partial GLOB');
  27
  28 is_deeply($ro->locations_for($deadbeef),
  29         { $imap => [ 1 ] }, 'locations_for w/ imap');
  30
  31 my $maildir = 'maildir:/home/user/md';
  32 my $fname = 'foo:2,S';
  33 $lms->lms_begin;
  34 ok($lms->set_src($deadbeef, $maildir, \$fname), 'set Maildir once');
  35 ok($lms->set_src($deadbeef, $maildir, \$fname) == 0, 'set Maildir again');
  36 $lms->lms_commit;
  37 is_deeply($ro->locations_for($deadbeef),
  38         { $imap => [ 1 ], $maildir => [ $fname ] },
  39         'locations_for w/ maildir + imap');
  40
  41 if ('mess things up pretend old bug') {
  42         $lms->lms_begin;
  43         $lms->{dbh}->do('UPDATE folders SET loc = ? WHERE loc = ?', undef,
  44                         "$maildir/", $maildir);
  45         ok(delete $lms->{fmap}, 'clear folder map');
  46         $lms->lms_commit;
  47
  48         $lms->lms_begin;
  49         ok($lms->set_src($deadbeef, $maildir, \$fname), 'set Maildir once');
  50         $lms->lms_commit;
  51 };
  52
  53 is_deeply([sort($ro->folders)], [$imap, $maildir], 'both folders shown');
  54 my @res;
  55 $ro->each_src($maildir, sub {
  56         my ($oidbin, $id) = @_;
  57         push @res, [ unpack('H*', $oidbin), $id ];
  58 });
  59 is_deeply(\@res, [ ['deadbeef', \$fname] ], 'each_src works on Maildir');
  60
  61 @res = ();
  62 $ro->each_src($imap, sub {
  63         my ($oidbin, $id) = @_;
  64         push @res, [ unpack('H*', $oidbin), $id ];
  65 });
  66 is_deeply(\@res, [ ['deadbeef', 1] ], 'each_src works on IMAP');
  67
  68 is_deeply($ro->location_stats($maildir), { 'name.count' => 1 },
  69         'Maildir location stats');
  70 is_deeply($ro->location_stats($imap),
  71         { 'uid.count' => 1, 'uid.max' => 1, 'uid.min' => 1 },
  72         'IMAP location stats');
  73 $lms->lms_begin;
  74 is($lms->clear_src($imap, 1), 1, 'clear_src on IMAP');
  75 is($lms->clear_src($maildir, \$fname), 1, 'clear_src on Maildir');
  76 ok($lms->clear_src($imap, 1) == 0, 'clear_src again on IMAP');
  77 ok($lms->clear_src($maildir, \$fname) == 0, 'clear_src again on Maildir');
  78 $lms->lms_commit;
  79 is_deeply($ro->location_stats($maildir), {}, 'nothing left');
  80
  81 done_testing;