t/lei_store.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Test::More;
   7 use PublicInbox::TestCommon;
   8 require_mods(qw(DBD::SQLite Search::Xapian));
   9 require_git 2.6;
  10 require_ok 'PublicInbox::LeiStore';
  11 require_ok 'PublicInbox::ExtSearch';
  12 my ($home, $for_destroy) = tmpdir();
  13 my $opt = { 1 => \(my $out = ''), 2 => \(my $err = '') };
  14 my $store_dir = "$home/sto";
  15 local $ENV{GIT_COMMITTER_EMAIL} = 'lei@example.com';
  16 local $ENV{GIT_COMMITTER_NAME} = 'lei user';
  17 my $sto = PublicInbox::LeiStore->new($store_dir, { creat => 1 });
  18 ok($sto, '->new');
  19 my $smsg = $sto->add_eml(eml_load('t/data/0001.patch'));
  20 like($smsg->{blob}, qr/\A[0-9a-f]+\z/, 'add returned OID');
  21 my $eml = eml_load('t/data/0001.patch');
  22 is($sto->add_eml($eml), undef, 'idempotent');
  23 $sto->done;
  24 is_deeply([$sto->maildir_keywords('/foo:2,')], [], 'Maildir no keywords');
  25 is_deeply([$sto->maildir_keywords('/foo:2,S')], ['seen'], 'Maildir seen');
  26 is_deeply([$sto->maildir_keywords('/foo:2,RS')], ['answered', 'seen'],
  27         'Maildir answered + seen');
  28 is_deeply([$sto->maildir_keywords('/foo:2,RSZ')], ['answered', 'seen'],
  29         'Maildir answered + seen w/o Z');
  30 {
  31         my $es = $sto->search;
  32         my $msgs = $es->over->query_xover(0, 1000);
  33         is(scalar(@$msgs), 1, 'one message');
  34         is($msgs->[0]->{blob}, $smsg->{blob}, 'blob matches');
  35         my $mset = $es->mset("mid:$msgs->[0]->{mid}");
  36         is($mset->size, 1, 'search works');
  37         is_deeply($es->mset_to_artnums($mset), [ $msgs->[0]->{num} ],
  38                 'mset_to_artnums');
  39         my @kw = $es->msg_keywords(($mset->items)[0]);
  40         is_deeply(\@kw, [], 'no flags');
  41 }
  42
  43 for my $parallel (0, 1) {
  44         $sto->{priv_eidx}->{parallel} = $parallel;
  45         my $docids = $sto->set_eml_keywords($eml, qw(seen draft));
  46         is(scalar @$docids, 1, 'set keywords on one doc');
  47         $sto->done;
  48         my @kw = $sto->search->msg_keywords($docids->[0]);
  49         is_deeply(\@kw, [qw(draft seen)], 'kw matches');
  50
  51         $docids = $sto->add_eml_keywords($eml, qw(seen draft));
  52         $sto->done;
  53         is(scalar @$docids, 1, 'idempotently added keywords to doc');
  54         @kw = $sto->search->msg_keywords($docids->[0]);
  55         is_deeply(\@kw, [qw(draft seen)], 'kw matches after noop');
  56
  57         $docids = $sto->remove_eml_keywords($eml, qw(seen draft));
  58         is(scalar @$docids, 1, 'removed from one doc');
  59         $sto->done;
  60         @kw = $sto->search->msg_keywords($docids->[0]);
  61         is_deeply(\@kw, [], 'kw matches after remove');
  62
  63         $docids = $sto->remove_eml_keywords($eml, qw(answered));
  64         is(scalar @$docids, 1, 'removed from one doc (idempotently)');
  65         $sto->done;
  66         @kw = $sto->search->msg_keywords($docids->[0]);
  67         is_deeply(\@kw, [], 'kw matches after remove (idempotent)');
  68
  69         $docids = $sto->add_eml_keywords($eml, qw(answered));
  70         is(scalar @$docids, 1, 'added to empty doc');
  71         $sto->done;
  72         @kw = $sto->search->msg_keywords($docids->[0]);
  73         is_deeply(\@kw, ['answered'], 'kw matches after add');
  74
  75         $docids = $sto->set_eml_keywords($eml);
  76         is(scalar @$docids, 1, 'set to clobber');
  77         $sto->done;
  78         @kw = $sto->search->msg_keywords($docids->[0]);
  79         is_deeply(\@kw, [], 'set clobbers all');
  80
  81         my $set = eml_load('t/plack-qp.eml');
  82         $set->header_set('Message-ID', "<set\@$parallel>");
  83         my $ret = $sto->set_eml($set, 'seen');
  84         is(ref $ret, 'PublicInbox::Smsg', 'initial returns smsg');
  85         my $ids = $sto->set_eml($set, qw(seen));
  86         is_deeply($ids, [ $ret->{num} ], 'set_eml idempotent');
  87         $ids = $sto->set_eml($set, qw(seen answered));
  88         is_deeply($ids, [ $ret->{num} ], 'set_eml to change kw');
  89         $sto->done;
  90         @kw = $sto->search->msg_keywords($ids->[0]);
  91         is_deeply(\@kw, [qw(answered seen)], 'set changed kw');
  92 }
  93
  94 SKIP: {
  95         require_mods(qw(Storable), 1);
  96         ok($sto->can('ipc_do'), 'ipc_do works if we have Storable');
  97         $eml->header_set('Message-ID', '<ipc-test@example>');
  98         my $pid = $sto->ipc_worker_spawn('lei-store');
  99         ok($pid > 0, 'got a worker');
 100         my $smsg = $sto->ipc_do('set_eml', $eml, qw(seen));
 101         is(ref($smsg), 'PublicInbox::Smsg', 'set_eml works over ipc');
 102         my $ids = $sto->ipc_do('set_eml', $eml, qw(seen));
 103         is_deeply($ids, [ $smsg->{num} ], 'docid returned');
 104
 105         $eml->header_set('Message-ID');
 106         my $no_mid = $sto->ipc_do('set_eml', $eml, qw(seen));
 107         my $wait = $sto->ipc_do('done');
 108         my @kw = $sto->search->msg_keywords($no_mid->{num});
 109         is_deeply(\@kw, [qw(seen)], 'ipc set changed kw');
 110
 111         is(ref($smsg), 'PublicInbox::Smsg', 'no mid works ipc');
 112         $ids = $sto->ipc_do('set_eml', $eml, qw(seen));
 113         is_deeply($ids, [ $no_mid->{num} ], 'docid returned w/o mid w/ ipc');
 114         $sto->ipc_do('done');
 115         $sto->ipc_worker_stop;
 116         $ids = $sto->ipc_do('set_eml', $eml, qw(seen answered));
 117         is_deeply($ids, [ $no_mid->{num} ], 'docid returned w/o mid w/o ipc');
 118         $wait = $sto->ipc_do('done');
 119
 120         my $lse = $sto->search;
 121         @kw = $lse->msg_keywords($no_mid->{num});
 122         is_deeply(\@kw, [qw(answered seen)], 'set changed kw w/o ipc');
 123         is($lse->kw_changed($eml, [qw(answered seen)]), 0,
 124                 'kw_changed false when unchanged');
 125         is($lse->kw_changed($eml, [qw(answered seen flagged)]), 1,
 126                 'kw_changed true when +flagged');
 127         is($lse->kw_changed(eml_load('t/plack-qp.eml'), ['seen']), undef,
 128                 'kw_changed undef on unknown message');
 129 }
 130
 131 done_testing;