t/lei_store.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Test::More;
   7 use PublicInbox::TestCommon;
   8 require_mods(qw(DBD::SQLite Search::Xapian));
   9 require_git 2.6;
  10 require_ok 'PublicInbox::LeiStore';
  11 require_ok 'PublicInbox::ExtSearch';
  12 my ($home, $for_destroy) = tmpdir();
  13 my $opt = { 1 => \(my $out = ''), 2 => \(my $err = '') };
  14 my $store_dir = "$home/sto";
  15 local $ENV{GIT_COMMITTER_EMAIL} = 'lei@example.com';
  16 local $ENV{GIT_COMMITTER_NAME} = 'lei user';
  17 my $sto = PublicInbox::LeiStore->new($store_dir, { creat => 1 });
  18 ok($sto, '->new');
  19 my $smsg = $sto->add_eml(eml_load('t/data/0001.patch'));
  20 like($smsg->{blob}, qr/\A[0-9a-f]+\z/, 'add returned OID');
  21 my $eml = eml_load('t/data/0001.patch');
  22 is($sto->add_eml($eml), undef, 'idempotent');
  23 $sto->done;
  24 {
  25         my $es = $sto->search;
  26         my $msgs = $es->over->query_xover(0, 1000);
  27         is(scalar(@$msgs), 1, 'one message');
  28         is($msgs->[0]->{blob}, $smsg->{blob}, 'blob matches');
  29         my $mset = $es->mset("mid:$msgs->[0]->{mid}");
  30         is($mset->size, 1, 'search works');
  31         is_deeply($es->mset_to_artnums($mset), [ $msgs->[0]->{num} ],
  32                 'mset_to_artnums');
  33         my @kw = $es->msg_keywords(($mset->items)[0]);
  34         is_deeply(\@kw, [], 'no flags');
  35 }
  36
  37 for my $parallel (0, 1) {
  38         $sto->{priv_eidx}->{parallel} = $parallel;
  39         my $docids = $sto->set_eml_vmd($eml, { kw => [ qw(seen draft) ] });
  40         is(scalar @$docids, 1, 'set keywords on one doc');
  41         $sto->done;
  42         my @kw = $sto->search->msg_keywords($docids->[0]);
  43         is_deeply(\@kw, [qw(draft seen)], 'kw matches');
  44
  45         $docids = $sto->add_eml_vmd($eml, {kw => [qw(seen draft)]});
  46         $sto->done;
  47         is(scalar @$docids, 1, 'idempotently added keywords to doc');
  48         @kw = $sto->search->msg_keywords($docids->[0]);
  49         is_deeply(\@kw, [qw(draft seen)], 'kw matches after noop');
  50
  51         $docids = $sto->remove_eml_vmd($eml, {kw => [qw(seen draft)]});
  52         is(scalar @$docids, 1, 'removed from one doc');
  53         $sto->done;
  54         @kw = $sto->search->msg_keywords($docids->[0]);
  55         is_deeply(\@kw, [], 'kw matches after remove');
  56
  57         $docids = $sto->remove_eml_vmd($eml, {kw=> [qw(answered)]});
  58         is(scalar @$docids, 1, 'removed from one doc (idempotently)');
  59         $sto->done;
  60         @kw = $sto->search->msg_keywords($docids->[0]);
  61         is_deeply(\@kw, [], 'kw matches after remove (idempotent)');
  62
  63         $docids = $sto->add_eml_vmd($eml, {kw => [qw(answered)]});
  64         is(scalar @$docids, 1, 'added to empty doc');
  65         $sto->done;
  66         @kw = $sto->search->msg_keywords($docids->[0]);
  67         is_deeply(\@kw, ['answered'], 'kw matches after add');
  68
  69         $docids = $sto->set_eml_vmd($eml, { kw => [] });
  70         is(scalar @$docids, 1, 'set to clobber');
  71         $sto->done;
  72         @kw = $sto->search->msg_keywords($docids->[0]);
  73         is_deeply(\@kw, [], 'set clobbers all');
  74
  75         my $set = eml_load('t/plack-qp.eml');
  76         $set->header_set('Message-ID', "<set\@$parallel>");
  77         my $ret = $sto->set_eml($set, { kw => [ 'seen' ] });
  78         is(ref $ret, 'PublicInbox::Smsg', 'initial returns smsg');
  79         my $ids = $sto->set_eml($set, { kw => [ 'seen' ] });
  80         is_deeply($ids, [ $ret->{num} ], 'set_eml idempotent');
  81         $ids = $sto->set_eml($set, { kw => [ qw(seen answered) ] });
  82         is_deeply($ids, [ $ret->{num} ], 'set_eml to change kw');
  83         $sto->done;
  84         @kw = $sto->search->msg_keywords($ids->[0]);
  85         is_deeply(\@kw, [qw(answered seen)], 'set changed kw');
  86 }
  87
  88 SKIP: {
  89         require_mods(qw(Storable), 1);
  90         ok($sto->can('ipc_do'), 'ipc_do works if we have Storable');
  91         $eml->header_set('Message-ID', '<ipc-test@example>');
  92         my $pid = $sto->ipc_worker_spawn('lei-store');
  93         ok($pid > 0, 'got a worker');
  94         my $smsg = $sto->ipc_do('set_eml', $eml, { kw => [ qw(seen) ] });
  95         is(ref($smsg), 'PublicInbox::Smsg', 'set_eml works over ipc');
  96         my $ids = $sto->ipc_do('set_eml', $eml, { kw => [ qw(seen) ] });
  97         is_deeply($ids, [ $smsg->{num} ], 'docid returned');
  98
  99         $eml->header_set('Message-ID');
 100         my $no_mid = $sto->ipc_do('set_eml', $eml, { kw => [ qw(seen) ] });
 101         my $wait = $sto->ipc_do('done');
 102         my @kw = $sto->search->msg_keywords($no_mid->{num});
 103         is_deeply(\@kw, [qw(seen)], 'ipc set changed kw');
 104
 105         is(ref($smsg), 'PublicInbox::Smsg', 'no mid works ipc');
 106         $ids = $sto->ipc_do('set_eml', $eml, { kw => [ qw(seen) ] });
 107         is_deeply($ids, [ $no_mid->{num} ], 'docid returned w/o mid w/ ipc');
 108         $sto->ipc_do('done');
 109         $sto->ipc_worker_stop;
 110         $ids = $sto->ipc_do('set_eml', $eml, { kw => [ qw(seen answered) ] });
 111         is_deeply($ids, [ $no_mid->{num} ], 'docid returned w/o mid w/o ipc');
 112         $wait = $sto->ipc_do('done');
 113
 114         my $lse = $sto->search;
 115         @kw = $lse->msg_keywords($no_mid->{num});
 116         is_deeply(\@kw, [qw(answered seen)], 'set changed kw w/o ipc');
 117         is($lse->kw_changed($eml, [qw(answered seen)]), 0,
 118                 'kw_changed false when unchanged');
 119         is($lse->kw_changed($eml, [qw(answered seen flagged)]), 1,
 120                 'kw_changed true when +flagged');
 121         is($lse->kw_changed(eml_load('t/plack-qp.eml'), ['seen']), undef,
 122                 'kw_changed undef on unknown message');
 123 }
 124
 125 done_testing;