t/lei_xsearch.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use List::Util qw(shuffle);
   7 use PublicInbox::TestCommon;
   8 use PublicInbox::Eml;
   9 require_mods(qw(DBD::SQLite Search::Xapian));
  10 require PublicInbox::ExtSearchIdx;
  11 require_git 2.6;
  12 require_ok 'PublicInbox::LeiXSearch';
  13 require_ok 'PublicInbox::LeiALE';
  14 my ($home, $for_destroy) = tmpdir();
  15 my @ibx;
  16 for my $V (1..2) {
  17         for my $i (3..6) {
  18                 push @ibx, create_inbox("v$V-$i", indexlevel => 'full',
  19                                         version => $V, sub {
  20                         my ($im, $ibx) = @_;
  21                         for my $j (0..9) {
  22                                 my $eml = PublicInbox::Eml->new(<<EOM);
  23 From: x\@example.com
  24 To: $ibx->{-primary_address}
  25 Date: Fri, 02 Oct 1993 0$V:0$i:0$j +0000
  26 Subject: v${V}i${i}j$j
  27 Message-ID: <v${V}i${i}j$j\@example>
  28
  29 ${V}er ${i}on j$j
  30 EOM
  31                                 $im->add($eml) or BAIL_OUT '->add';
  32                         }
  33                 }); # create_inbox
  34         }
  35 }
  36 my $first = shift @ibx; is($first->{name}, 'v1-3', 'first plucked');
  37 my $last = pop @ibx; is($last->{name}, 'v2-6', 'last plucked');
  38 my $eidx = PublicInbox::ExtSearchIdx->new("$home/eidx");
  39 $eidx->attach_inbox($first);
  40 $eidx->attach_inbox($last);
  41 $eidx->eidx_sync({fsync => 0});
  42 my $es = PublicInbox::ExtSearch->new("$home/eidx");
  43 my $lxs = PublicInbox::LeiXSearch->new;
  44 for my $ibxish (shuffle($es, @ibx)) {
  45         $lxs->prepare_external($ibxish);
  46 }
  47 for my $loc ($lxs->locals) {
  48         $lxs->attach_external($loc);
  49 }
  50 my $nr = $lxs->xdb->get_doccount;
  51 my $mset = $lxs->mset('d:19931002..19931003', { limit => $nr });
  52 is($mset->size, $nr, 'got all messages');
  53 my @msgs;
  54 for my $mi ($mset->items) {
  55         if (my $smsg = $lxs->smsg_for($mi)) {
  56                 push @msgs, $smsg;
  57         } else {
  58                 diag "E: ${\$mi->get_docid} missing";
  59         }
  60 }
  61 is(scalar(@msgs), $nr, 'smsgs retrieved for all');
  62
  63 $mset = $lxs->recent(undef, { limit => 1 });
  64 is($mset->size, 1, 'one result');
  65
  66 my @ibxish = $lxs->locals;
  67 is(scalar(@ibxish), scalar(@ibx) + 1, 'got locals back');
  68 is($lxs->search, $lxs, '->search works');
  69 is($lxs->over, undef, '->over fails');
  70
  71 {
  72         $lxs = PublicInbox::LeiXSearch->new;
  73         my $v2ibx = create_inbox 'v2full', version => 2, sub {
  74                 $_[0]->add(eml_load('t/plack-qp.eml'));
  75         };
  76         my $v1ibx = create_inbox 'v1medium', indexlevel => 'medium',
  77                                 tmpdir => "$home/v1tmp", sub {
  78                 $_[0]->add(eml_load('t/utf8.eml'));
  79         };
  80         $lxs->prepare_external($v1ibx);
  81         $lxs->prepare_external($v2ibx);
  82         for my $loc ($lxs->locals) {
  83                 $lxs->attach_external($loc);
  84         }
  85         my $mset = $lxs->mset('m:testmessage@example.com');
  86         is($mset->size, 1, 'got m: match on medium+full XSearch mix');
  87         my $mitem = ($mset->items)[0];
  88         my $smsg = $lxs->smsg_for($mitem) or BAIL_OUT 'smsg_for broken';
  89
  90         my $ale = PublicInbox::LeiALE::_new("$home/ale");
  91         $ale->refresh_externals($lxs);
  92         my $exp = [ $smsg->{blob}, 'blob', -s 't/utf8.eml' ];
  93         is_deeply([ $ale->git->check($smsg->{blob}) ], $exp, 'ale->git->check');
  94
  95         $lxs = PublicInbox::LeiXSearch->new;
  96         $lxs->prepare_external($v2ibx);
  97         $ale->refresh_externals($lxs);
  98         is_deeply([ $ale->git->check($smsg->{blob}) ], $exp,
  99                         'ale->git->check remembered inactive external');
 100
 101         rename("$home/v1tmp", "$home/v1moved") or BAIL_OUT "rename: $!";
 102         $ale->refresh_externals($lxs);
 103         is($ale->git->check($smsg->{blob}), undef,
 104                         'missing after directory gone');
 105 }
 106
 107 done_testing;