t/mda.t

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Email::MIME;
   7 use File::Temp qw/tempdir/;
   8 use Cwd;
   9 use IPC::Run qw(run);
  10
  11 my $mda = "blib/script/public-inbox-mda";
  12 my $tmpdir = tempdir(CLEANUP => 1);
  13 my $home = "$tmpdir/pi-home";
  14 my $pi_home = "$home/.public-inbox";
  15 my $pi_config = "$pi_home/config";
  16 my $maindir = "$tmpdir/main.git";
  17 my $main_bin = getcwd()."/t/main-bin";
  18 my $main_path = "$main_bin:$ENV{PATH}"; # for spamc ham mock
  19 my $fail_bin = getcwd()."/t/fail-bin";
  20 my $fail_path = "$fail_bin:$ENV{PATH}"; # for spamc spam mock
  21 my $addr = 'test-public@example.com';
  22 my $cfgpfx = "publicinbox.test";
  23 my $failbox = "$home/fail.mbox";
  24
  25 {
  26         ok(-x "$main_bin/spamc",
  27                 "spamc ham mock found (run in top of source tree");
  28         ok(-x "$fail_bin/spamc",
  29                 "spamc mock found (run in top of source tree");
  30         ok(-x $mda, "$mda is executable");
  31         is(1, mkdir($home, 0755), "setup ~/ for testing");
  32         is(1, mkdir($pi_home, 0755), "setup ~/.public-inbox");
  33         is(0, system(qw(git init -q --bare), $maindir), "git init (main)");
  34
  35         my %cfg = (
  36                 "$cfgpfx.address" => $addr,
  37                 "$cfgpfx.mainrepo" => $maindir,
  38         );
  39         while (my ($k,$v) = each %cfg) {
  40                 is(0, system(qw(git config --file), $pi_config, $k, $v),
  41                         "setup $k");
  42         }
  43 }
  44
  45 {
  46         my $good_rev;
  47         local $ENV{PI_FAILBOX} = $failbox;
  48         local $ENV{HOME} = $home;
  49         local $ENV{RECIPIENT} = $addr;
  50         my $simple = Email::Simple->new(<<EOF);
  51 From: Me <me\@example.com>
  52 To: You <you\@example.com>
  53 Cc: $addr
  54 Message-Id: <blah\@example.com>
  55 Subject: hihi
  56 Date: Thu, 01 Jan 1970 00:00:00 +0000
  57
  58 EOF
  59         my $in = $simple->as_string;
  60
  61         # ensure successful message delivery
  62         {
  63                 local $ENV{PATH} = $main_path;
  64                 run([$mda], \$in);
  65                 local $ENV{GIT_DIR} = $maindir;
  66                 my $rev = `git rev-list HEAD`;
  67                 like($rev, qr/\A[a-f0-9]{40}/, "good revision committed");
  68                 chomp $rev;
  69                 my $cmt = `git cat-file commit $rev`;
  70                 like($cmt, qr/^author Me <me\@example\.com> 0 \+0000\n/m,
  71                         "author info set correctly");
  72                 like($cmt, qr/^committer test <test-public\@example\.com>/m,
  73                         "committer info set correctly");
  74                 $good_rev = $rev;
  75         }
  76
  77         # ensure failures work, fail with bad spamc
  78         {
  79                 ok(!-e $failbox, "nothing in PI_FAILBOX before");
  80                 local $ENV{PATH} = $fail_path;
  81                 run([$mda], \$in);
  82                 local $ENV{GIT_DIR} = $maindir;
  83                 my @revs = `git rev-list HEAD`;
  84                 is(scalar @revs, 1, "bad revision not committed");
  85                 ok(-s $failbox > 0, "PI_FAILBOX is written to");
  86         }
  87
  88         fail_bad_header($good_rev, "bad recipient", <<"");
  89 From: Me <me\@example.com>
  90 To: You <you\@example.com>
  91 Message-Id: <bad-recipient\@example.com>
  92 Subject: hihi
  93 Date: Thu, 01 Jan 1970 00:00:00 +0000
  94
  95         my $fail = fail_bad_header($good_rev, "duplicate Message-ID", <<"");
  96 From: Me <me\@example.com>
  97 To: You <you\@example.com>
  98 Cc: $addr
  99 Message-ID: <blah\@example.com>
 100 Subject: hihi
 101 Date: Thu, 01 Jan 1970 00:00:00 +0000
 102
 103         like($fail->[2], qr/CONFLICT/, "duplicate Message-ID message");
 104
 105         fail_bad_header($good_rev, "missing From:", <<"");
 106 To: $addr
 107 Message-ID: <missing-from\@example.com>
 108 Subject: hihi
 109 Date: Thu, 01 Jan 1970 00:00:00 +0000
 110
 111         fail_bad_header($good_rev, "short subject:", <<"");
 112 To: $addr
 113 From: cat\@example.com
 114 Message-ID: <short-subject\@example.com>
 115 Subject: a
 116 Date: Thu, 01 Jan 1970 00:00:00 +0000
 117
 118         fail_bad_header($good_rev, "no date", <<"");
 119 To: $addr
 120 From: u\@example.com
 121 Message-ID: <no-date\@example.com>
 122 Subject: hihi
 123
 124         fail_bad_header($good_rev, "bad date", <<"");
 125 To: $addr
 126 From: u\@example.com
 127 Message-ID: <bad-date\@example.com>
 128 Subject: hihi
 129 Date: deadbeef
 130
 131 }
 132
 133 sub fail_bad_header {
 134         my ($good_rev, $msg, $in) = @_;
 135         open my $fh, '>', $failbox or die "failed to open $failbox: $!\n";
 136         close $fh or die "failed to close $failbox: $!\n";
 137         my ($out, $err) = ("", "");
 138         local $ENV{PATH} = $main_path;
 139         run([$mda], \$in, \$out, \$err);
 140         local $ENV{GIT_DIR} = $maindir;
 141         my $rev = `git rev-list HEAD`;
 142         chomp $rev;
 143         is($rev, $good_rev, "bad revision not commited ($msg)");
 144         ok(-s $failbox > 0, "PI_FAILBOX is written to ($msg)");
 145         [ $in, $out, $err ];
 146 }
 147
 148 done_testing();