t/msgtime.t

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::MsgTime;
   8
   9 sub datestamp ($) {
  10         my ($date) = @_;
  11         local $SIG{__WARN__} = sub {};  # Suppress warnings
  12         my $mime = PublicInbox::MIME->create(
  13                 header => [
  14                         From => 'a@example.com',
  15                         To => 'b@example.com',
  16                         'Content-Type' => 'text/plain',
  17                         Subject => 'this is a subject',
  18                         'Message-ID' => '<a@example.com>',
  19                         Date => $date,
  20                         'Received' => '(majordomo@vger.kernel.org) by vger.kernel.org via listexpand\n\tid S932173AbXAVSQY (ORCPT <rfc822;w@1wt.eu>);\n\tMon, 22 Jan 2007 13:16:24 -0500',
  21                 ],
  22                 body => "hello world\n",
  23             );
  24         my @ts = PublicInbox::MsgTime::msg_datestamp($mime->header_obj);
  25         return \@ts;
  26 }
  27
  28 sub timestamp ($) {
  29         my ($received) = @_;
  30         local $SIG{__WARN__} = sub {};  # Suppress warnings
  31         my $mime = PublicInbox::MIME->create(
  32                 header => [
  33                         From => 'a@example.com',
  34                         To => 'b@example.com',
  35                         'Content-Type' => 'text/plain',
  36                         Subject => 'this is a subject',
  37                         'Message-ID' => '<a@example.com>',
  38                         Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  39                         'Received' => '(majordomo@vger.kernel.org) by vger.kernel.org via listexpand\n\tid S932173AbXAVSQY (ORCPT <rfc822;w@1wt.eu>);\n\t' . $received,
  40                 ],
  41                 body => "hello world\n",
  42             );
  43         my @ts = PublicInbox::MsgTime::msg_timestamp($mime->header_obj);
  44         return \@ts;
  45 }
  46
  47 # Verify that the parser sucks up the timezone for dates
  48 for (my $min = -1440; $min <= 1440; $min += 30) {
  49         my $sign = ($min < 0) ? '-': '+';
  50         my $h = abs(int($min / 60));
  51         my $m = $min % 60;
  52
  53         my $ts_expect = 749520000 - ($min * 60);
  54         my $tz_expect = sprintf('%s%02d%02d', $sign, $h, $m);
  55         if ($tz_expect >= 1400 || $tz_expect <= -1400) {
  56                 $tz_expect = '+0000';
  57         }
  58         my $date = sprintf("Fri, 02 Oct 1993 00:00:00 %s%02d%02d",
  59                            $sign, $h, $m);
  60         my $result = datestamp($date);
  61         is_deeply($result, [ $ts_expect, $tz_expect ], $date);
  62 }
  63
  64 # Verify that the parser sucks up the timezone and for received timestamps
  65 for (my $min = -1440; $min <= 1440; $min += 30) {
  66         my $sign = ($min < 0) ? '-' : '+';
  67         my $h = abs(int($min / 60));
  68         my $m = $min %60;
  69
  70         my $ts_expect = 1169471784 - ($min * 60);
  71         my $tz_expect = sprintf('%s%02d%02d', $sign, $h, $m);
  72         if ($tz_expect >= 1400 || $tz_expect <= -1400) {
  73                 $tz_expect = '+0000';
  74         }
  75         my $received = sprintf('Mon, 22 Jan 2007 13:16:24 %s%02d%02d',
  76                                $sign, $h, $m);
  77         is_deeply(timestamp($received), [ $ts_expect, $tz_expect ],
  78                 $received);
  79 }
  80
  81 sub is_datestamp ($$) {
  82         my ($date, $expect) = @_;
  83         is_deeply(datestamp($date), $expect, $date);
  84 }
  85 is_datestamp('Wed, 13 Dec 2006 10:26:38 +1', [1166001998, '+0100']);
  86 is_datestamp('Fri, 3 Feb 2006 18:11:22 -00', [1138990282, '+0000']);
  87 is_datestamp('Thursday, 20 Feb 2003 01:14:34 +000', [1045703674, '+0000']);
  88 is_datestamp('Fri, 28 Jun 2002 12:54:40 -700', [1025294080, '-0700']);
  89 is_datestamp('Sat, 12 Jan 2002 12:52:57 -200', [1010847177, '-0200']);
  90 is_datestamp('Mon, 05 Nov 2001 10:36:16 -800', [1004985376, '-0800']);
  91 is_datestamp('Tue, 3 Jun 2003 8:58:23 --500', [1054648703, '-0500']);
  92 is_datestamp('Thu, 18 May 100 10:40:43 +0200 (MET DST)', [958639243, '+0200']);
  93 is_datestamp('Thu, 18 May 2000 10:40:43 +0200', [958639243, '+0200']);
  94 is_datestamp('Tue, 27 Feb 2007 16:23:25 -0060', [1172597005, '-0100']);
  95 done_testing();