t/nntpd-tls.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Socket qw(SOCK_STREAM IPPROTO_TCP SOL_SOCKET);
   7 # IO::Poll and Net::NNTP are part of the standard library, but
   8 # distros may split them off...
   9 foreach my $mod (qw(DBD::SQLite IO::Socket::SSL Net::NNTP IO::Poll)) {
  10         eval "require $mod";
  11         plan skip_all => "$mod missing for $0" if $@;
  12 }
  13 Net::NNTP->can('starttls') or
  14         plan skip_all => 'Net::NNTP does not support TLS';
  15 IO::Socket::SSL->VERSION(2.007) or
  16         plan skip_all => 'IO::Socket::SSL <2.007 not supported by Net::NNTP';
  17
  18 my $cert = 'certs/server-cert.pem';
  19 my $key = 'certs/server-key.pem';
  20 unless (-r $key && -r $cert) {
  21         plan skip_all =>
  22                 "certs/ missing for $0, run $^X ./create-certs.perl in certs/";
  23 }
  24
  25 use_ok 'PublicInbox::TLS';
  26 use_ok 'IO::Socket::SSL';
  27 use PublicInbox::TestCommon;
  28 require PublicInbox::InboxWritable;
  29 require PublicInbox::MIME;
  30 require PublicInbox::SearchIdx;
  31 our $need_zlib;
  32 eval { require Compress::Raw::Zlib } or
  33         $need_zlib = 'Compress::Raw::Zlib missing';
  34 my $version = 2; # v2 needs newer git
  35 require_git('2.6') if $version >= 2;
  36 my ($tmpdir, $for_destroy) = tmpdir();
  37 my $err = "$tmpdir/stderr.log";
  38 my $out = "$tmpdir/stdout.log";
  39 my $inboxdir = "$tmpdir";
  40 my $pi_config = "$tmpdir/pi_config";
  41 my $group = 'test-nntpd-tls';
  42 my $addr = $group . '@example.com';
  43 my $starttls = tcp_server();
  44 my $nntps = tcp_server();
  45 my $ibx = PublicInbox::Inbox->new({
  46         inboxdir => $inboxdir,
  47         name => 'nntpd-tls',
  48         version => $version,
  49         -primary_address => $addr,
  50         indexlevel => 'basic',
  51 });
  52 $ibx = PublicInbox::InboxWritable->new($ibx, {nproc=>1});
  53 $ibx->init_inbox(0);
  54 {
  55         open my $fh, '>', $pi_config or die "open: $!\n";
  56         print $fh <<EOF
  57 [publicinbox "nntpd-tls"]
  58         inboxdir = $inboxdir
  59         address = $addr
  60         indexlevel = basic
  61         newsgroup = $group
  62 EOF
  63         ;
  64         close $fh or die "close: $!\n";
  65 }
  66
  67 {
  68         my $im = $ibx->importer(0);
  69         my $mime = PublicInbox::MIME->new(do {
  70                 open my $fh, '<', 't/data/0001.patch' or die;
  71                 local $/;
  72                 <$fh>
  73         });
  74         ok($im->add($mime), 'message added');
  75         $im->done;
  76         if ($version == 1) {
  77                 my $s = PublicInbox::SearchIdx->new($ibx, 1);
  78                 $s->index_sync;
  79         }
  80 }
  81
  82 my $nntps_addr = $nntps->sockhost . ':' . $nntps->sockport;
  83 my $starttls_addr = $starttls->sockhost . ':' . $starttls->sockport;
  84 my $env = { PI_CONFIG => $pi_config };
  85 my $td;
  86
  87 for my $args (
  88         [ "--cert=$cert", "--key=$key",
  89                 "-lnntps://$nntps_addr",
  90                 "-lnntp://$starttls_addr" ],
  91 ) {
  92         for ($out, $err) {
  93                 open my $fh, '>', $_ or die "truncate: $!";
  94         }
  95         my $cmd = [ '-nntpd', '-W0', @$args, "--stdout=$out", "--stderr=$err" ];
  96         $td = start_script($cmd, $env, { 3 => $starttls, 4 => $nntps });
  97         my %o = (
  98                 SSL_hostname => 'server.local',
  99                 SSL_verifycn_name => 'server.local',
 100                 SSL_verify_mode => SSL_VERIFY_PEER(),
 101                 SSL_ca_file => 'certs/test-ca.pem',
 102         );
 103         my $expect = { $group => [qw(1 1 n)] };
 104
 105         # start negotiating a slow TLS connection
 106         my $slow = tcp_connect($nntps, Blocking => 0);
 107         $slow = IO::Socket::SSL->start_SSL($slow, SSL_startHandshake => 0, %o);
 108         my $slow_done = $slow->connect_SSL;
 109         my @poll;
 110         if ($slow_done) {
 111                 diag('W: connect_SSL early OK, slow client test invalid');
 112                 use PublicInbox::Syscall qw(EPOLLIN EPOLLOUT);
 113                 @poll = (fileno($slow), EPOLLIN | EPOLLOUT);
 114         } else {
 115                 @poll = (fileno($slow), PublicInbox::TLS::epollbit());
 116         }
 117         # we should call connect_SSL much later...
 118
 119         # NNTPS
 120         my $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 121         my $list = $c->list;
 122         is_deeply($list, $expect, 'NNTPS LIST works');
 123         unlike(get_capa($c), qr/\bSTARTTLS\r\n/,
 124                 'STARTTLS not advertised for NNTPS');
 125         is($c->command('QUIT')->response(), Net::Cmd::CMD_OK(), 'QUIT works');
 126         is(0, sysread($c, my $buf, 1), 'got EOF after QUIT');
 127
 128         # STARTTLS
 129         $c = Net::NNTP->new($starttls_addr, %o);
 130         $list = $c->list;
 131         is_deeply($list, $expect, 'plain LIST works');
 132         ok($c->starttls, 'STARTTLS succeeds');
 133         is($c->code, 382, 'got 382 for STARTTLS');
 134         $list = $c->list;
 135         is_deeply($list, $expect, 'LIST works after STARTTLS');
 136         unlike(get_capa($c), qr/\bSTARTTLS\r\n/,
 137                 'STARTTLS not advertised after STARTTLS');
 138
 139         # Net::NNTP won't let us do dumb things, but we need to test
 140         # dumb things, so use Net::Cmd directly:
 141         my $n = $c->command('STARTTLS')->response();
 142         is($n, Net::Cmd::CMD_ERROR(), 'error attempting STARTTLS again');
 143         is($c->code, 502, '502 according to RFC 4642 sec#2.2.1');
 144
 145         # STARTTLS with bad hostname
 146         $o{SSL_hostname} = $o{SSL_verifycn_name} = 'server.invalid';
 147         $c = Net::NNTP->new($starttls_addr, %o);
 148         like(get_capa($c), qr/\bSTARTTLS\r\n/, 'STARTTLS advertised');
 149         $list = $c->list;
 150         is_deeply($list, $expect, 'plain LIST works again');
 151         ok(!$c->starttls, 'STARTTLS fails with bad hostname');
 152         $c = Net::NNTP->new($starttls_addr, %o);
 153         $list = $c->list;
 154         is_deeply($list, $expect, 'not broken after bad negotiation');
 155
 156         # NNTPS with bad hostname
 157         $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 158         is($c, undef, 'NNTPS fails with bad hostname');
 159         $o{SSL_hostname} = $o{SSL_verifycn_name} = 'server.local';
 160         $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 161         ok($c, 'NNTPS succeeds again with valid hostname');
 162
 163         # slow TLS connection did not block the other fast clients while
 164         # connecting, finish it off:
 165         until ($slow_done) {
 166                 IO::Poll::_poll(-1, @poll);
 167                 $slow_done = $slow->connect_SSL and last;
 168                 @poll = (fileno($slow), PublicInbox::TLS::epollbit());
 169         }
 170         $slow->blocking(1);
 171         ok(sysread($slow, my $greet, 4096) > 0, 'slow got greeting');
 172         like($greet, qr/\A201 /, 'got expected greeting');
 173         is(syswrite($slow, "QUIT\r\n"), 6, 'slow wrote QUIT');
 174         ok(sysread($slow, my $end, 4096) > 0, 'got EOF');
 175         is(sysread($slow, my $eof, 4096), 0, 'got EOF');
 176         $slow = undef;
 177
 178         SKIP: {
 179                 skip 'TCP_DEFER_ACCEPT is Linux-only', 2 if $^O ne 'linux';
 180                 my $var = Socket::TCP_DEFER_ACCEPT();
 181                 defined(my $x = getsockopt($nntps, IPPROTO_TCP, $var)) or die;
 182                 ok(unpack('i', $x) > 0, 'TCP_DEFER_ACCEPT set on NNTPS');
 183                 defined($x = getsockopt($starttls, IPPROTO_TCP, $var)) or die;
 184                 is(unpack('i', $x), 0, 'TCP_DEFER_ACCEPT is 0 on plain NNTP');
 185         };
 186         SKIP: {
 187                 skip 'SO_ACCEPTFILTER is FreeBSD-only', 2 if $^O ne 'freebsd';
 188                 if (system('kldstat -m accf_data >/dev/null')) {
 189                         skip 'accf_data not loaded? kldload accf_data', 2;
 190                 }
 191                 require PublicInbox::Daemon;
 192                 my $var = PublicInbox::Daemon::SO_ACCEPTFILTER();
 193                 my $x = getsockopt($nntps, SOL_SOCKET, $var);
 194                 like($x, qr/\Adataready\0+\z/, 'got dataready accf for NNTPS');
 195                 $x = getsockopt($starttls, IPPROTO_TCP, $var);
 196                 is($x, undef, 'no BSD accept filter for plain NNTP');
 197         };
 198
 199         $c = undef;
 200         $td->kill;
 201         $td->join;
 202         is($?, 0, 'no error in exited process');
 203         my $eout = eval {
 204                 open my $fh, '<', $err or die "open $err failed: $!";
 205                 local $/;
 206                 <$fh>;
 207         };
 208         unlike($eout, qr/wide/i, 'no Wide character warnings');
 209 }
 210 done_testing();
 211
 212 sub get_capa {
 213         my ($sock) = @_;
 214         syswrite($sock, "CAPABILITIES\r\n");
 215         my $capa = '';
 216         do {
 217                 my $r = sysread($sock, $capa, 8192, length($capa));
 218                 die "unexpected: $!" unless defined($r);
 219                 die 'unexpected EOF' if $r == 0;
 220         } until $capa =~ /\.\r\n\z/;
 221
 222         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 223         if ($need_zlib) {
 224                 unlike($capa, $deflate_capa,
 225                         'COMPRESS DEFLATE NOT advertised '.$need_zlib);
 226         } else {
 227                 like($capa, $deflate_capa, 'COMPRESS DEFLATE advertised');
 228         }
 229         $capa;
 230 }
 231
 232 1;