t/nntpd-tls.t

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Socket qw(SOCK_STREAM IPPROTO_TCP SOL_SOCKET);
   7 use PublicInbox::TestCommon;
   8 # IO::Poll and Net::NNTP are part of the standard library, but
   9 # distros may split them off...
  10 require_mods(qw(DBD::SQLite IO::Socket::SSL Net::NNTP IO::Poll));
  11 Net::NNTP->can('starttls') or
  12         plan skip_all => 'Net::NNTP does not support TLS';
  13 IO::Socket::SSL->VERSION(2.007) or
  14         plan skip_all => 'IO::Socket::SSL <2.007 not supported by Net::NNTP';
  15
  16 my $cert = 'certs/server-cert.pem';
  17 my $key = 'certs/server-key.pem';
  18 unless (-r $key && -r $cert) {
  19         plan skip_all =>
  20                 "certs/ missing for $0, run $^X ./create-certs.perl in certs/";
  21 }
  22
  23 use_ok 'PublicInbox::TLS';
  24 use_ok 'IO::Socket::SSL';
  25 require PublicInbox::InboxWritable;
  26 require PublicInbox::Eml;
  27 require PublicInbox::SearchIdx;
  28 our $need_zlib;
  29 eval { require Compress::Raw::Zlib } or
  30         $need_zlib = 'Compress::Raw::Zlib missing';
  31 my $version = 2; # v2 needs newer git
  32 require_git('2.6') if $version >= 2;
  33 my ($tmpdir, $for_destroy) = tmpdir();
  34 my $err = "$tmpdir/stderr.log";
  35 my $out = "$tmpdir/stdout.log";
  36 my $inboxdir = "$tmpdir";
  37 my $pi_config = "$tmpdir/pi_config";
  38 my $group = 'test-nntpd-tls';
  39 my $addr = $group . '@example.com';
  40 my $starttls = tcp_server();
  41 my $nntps = tcp_server();
  42 my $ibx = PublicInbox::Inbox->new({
  43         inboxdir => $inboxdir,
  44         name => 'nntpd-tls',
  45         version => $version,
  46         -primary_address => $addr,
  47         indexlevel => 'basic',
  48 });
  49 $ibx = PublicInbox::InboxWritable->new($ibx, {nproc=>1});
  50 $ibx->init_inbox(0);
  51 {
  52         open my $fh, '>', $pi_config or die "open: $!\n";
  53         print $fh <<EOF
  54 [publicinbox "nntpd-tls"]
  55         inboxdir = $inboxdir
  56         address = $addr
  57         indexlevel = basic
  58         newsgroup = $group
  59 EOF
  60         ;
  61         close $fh or die "close: $!\n";
  62 }
  63
  64 {
  65         my $im = $ibx->importer(0);
  66         my $mime = eml_load 't/data/0001.patch';
  67         ok($im->add($mime), 'message added');
  68         $im->done;
  69         if ($version == 1) {
  70                 my $s = PublicInbox::SearchIdx->new($ibx, 1);
  71                 $s->index_sync;
  72         }
  73 }
  74
  75 my $nntps_addr = $nntps->sockhost . ':' . $nntps->sockport;
  76 my $starttls_addr = $starttls->sockhost . ':' . $starttls->sockport;
  77 my $env = { PI_CONFIG => $pi_config };
  78 my $td;
  79
  80 for my $args (
  81         [ "--cert=$cert", "--key=$key",
  82                 "-lnntps://$nntps_addr",
  83                 "-lnntp://$starttls_addr" ],
  84 ) {
  85         for ($out, $err) {
  86                 open my $fh, '>', $_ or die "truncate: $!";
  87         }
  88         my $cmd = [ '-nntpd', '-W0', @$args, "--stdout=$out", "--stderr=$err" ];
  89         $td = start_script($cmd, $env, { 3 => $starttls, 4 => $nntps });
  90         my %o = (
  91                 SSL_hostname => 'server.local',
  92                 SSL_verifycn_name => 'server.local',
  93                 SSL_verify_mode => SSL_VERIFY_PEER(),
  94                 SSL_ca_file => 'certs/test-ca.pem',
  95         );
  96         my $expect = { $group => [qw(1 1 n)] };
  97
  98         # start negotiating a slow TLS connection
  99         my $slow = tcp_connect($nntps, Blocking => 0);
 100         $slow = IO::Socket::SSL->start_SSL($slow, SSL_startHandshake => 0, %o);
 101         my $slow_done = $slow->connect_SSL;
 102         my @poll;
 103         if ($slow_done) {
 104                 diag('W: connect_SSL early OK, slow client test invalid');
 105                 use PublicInbox::Syscall qw(EPOLLIN EPOLLOUT);
 106                 @poll = (fileno($slow), EPOLLIN | EPOLLOUT);
 107         } else {
 108                 @poll = (fileno($slow), PublicInbox::TLS::epollbit());
 109         }
 110         # we should call connect_SSL much later...
 111
 112         # NNTPS
 113         my $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 114         my $list = $c->list;
 115         is_deeply($list, $expect, 'NNTPS LIST works');
 116         unlike(get_capa($c), qr/\bSTARTTLS\r\n/,
 117                 'STARTTLS not advertised for NNTPS');
 118         is($c->command('QUIT')->response(), Net::Cmd::CMD_OK(), 'QUIT works');
 119         is(0, sysread($c, my $buf, 1), 'got EOF after QUIT');
 120
 121         # STARTTLS
 122         $c = Net::NNTP->new($starttls_addr, %o);
 123         $list = $c->list;
 124         is_deeply($list, $expect, 'plain LIST works');
 125         ok($c->starttls, 'STARTTLS succeeds');
 126         is($c->code, 382, 'got 382 for STARTTLS');
 127         $list = $c->list;
 128         is_deeply($list, $expect, 'LIST works after STARTTLS');
 129         unlike(get_capa($c), qr/\bSTARTTLS\r\n/,
 130                 'STARTTLS not advertised after STARTTLS');
 131
 132         # Net::NNTP won't let us do dumb things, but we need to test
 133         # dumb things, so use Net::Cmd directly:
 134         my $n = $c->command('STARTTLS')->response();
 135         is($n, Net::Cmd::CMD_ERROR(), 'error attempting STARTTLS again');
 136         is($c->code, 502, '502 according to RFC 4642 sec#2.2.1');
 137
 138         # STARTTLS with bad hostname
 139         $o{SSL_hostname} = $o{SSL_verifycn_name} = 'server.invalid';
 140         $c = Net::NNTP->new($starttls_addr, %o);
 141         like(get_capa($c), qr/\bSTARTTLS\r\n/, 'STARTTLS advertised');
 142         $list = $c->list;
 143         is_deeply($list, $expect, 'plain LIST works again');
 144         ok(!$c->starttls, 'STARTTLS fails with bad hostname');
 145         $c = Net::NNTP->new($starttls_addr, %o);
 146         $list = $c->list;
 147         is_deeply($list, $expect, 'not broken after bad negotiation');
 148
 149         # NNTPS with bad hostname
 150         $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 151         is($c, undef, 'NNTPS fails with bad hostname');
 152         $o{SSL_hostname} = $o{SSL_verifycn_name} = 'server.local';
 153         $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 154         ok($c, 'NNTPS succeeds again with valid hostname');
 155
 156         # slow TLS connection did not block the other fast clients while
 157         # connecting, finish it off:
 158         until ($slow_done) {
 159                 IO::Poll::_poll(-1, @poll);
 160                 $slow_done = $slow->connect_SSL and last;
 161                 @poll = (fileno($slow), PublicInbox::TLS::epollbit());
 162         }
 163         $slow->blocking(1);
 164         ok(sysread($slow, my $greet, 4096) > 0, 'slow got greeting');
 165         like($greet, qr/\A201 /, 'got expected greeting');
 166         is(syswrite($slow, "QUIT\r\n"), 6, 'slow wrote QUIT');
 167         ok(sysread($slow, my $end, 4096) > 0, 'got EOF');
 168         is(sysread($slow, my $eof, 4096), 0, 'got EOF');
 169         $slow = undef;
 170
 171         SKIP: {
 172                 skip 'TCP_DEFER_ACCEPT is Linux-only', 2 if $^O ne 'linux';
 173                 my $var = eval { Socket::TCP_DEFER_ACCEPT() } // 9;
 174                 defined(my $x = getsockopt($nntps, IPPROTO_TCP, $var)) or die;
 175                 ok(unpack('i', $x) > 0, 'TCP_DEFER_ACCEPT set on NNTPS');
 176                 defined($x = getsockopt($starttls, IPPROTO_TCP, $var)) or die;
 177                 is(unpack('i', $x), 0, 'TCP_DEFER_ACCEPT is 0 on plain NNTP');
 178         };
 179         SKIP: {
 180                 skip 'SO_ACCEPTFILTER is FreeBSD-only', 2 if $^O ne 'freebsd';
 181                 if (system('kldstat -m accf_data >/dev/null')) {
 182                         skip 'accf_data not loaded? kldload accf_data', 2;
 183                 }
 184                 require PublicInbox::Daemon;
 185                 my $var = PublicInbox::Daemon::SO_ACCEPTFILTER();
 186                 my $x = getsockopt($nntps, SOL_SOCKET, $var);
 187                 like($x, qr/\Adataready\0+\z/, 'got dataready accf for NNTPS');
 188                 $x = getsockopt($starttls, IPPROTO_TCP, $var);
 189                 is($x, undef, 'no BSD accept filter for plain NNTP');
 190         };
 191
 192         $c = undef;
 193         $td->kill;
 194         $td->join;
 195         is($?, 0, 'no error in exited process');
 196         my $eout = eval {
 197                 open my $fh, '<', $err or die "open $err failed: $!";
 198                 local $/;
 199                 <$fh>;
 200         };
 201         unlike($eout, qr/wide/i, 'no Wide character warnings');
 202 }
 203 done_testing();
 204
 205 sub get_capa {
 206         my ($sock) = @_;
 207         syswrite($sock, "CAPABILITIES\r\n");
 208         my $capa = '';
 209         do {
 210                 my $r = sysread($sock, $capa, 8192, length($capa));
 211                 die "unexpected: $!" unless defined($r);
 212                 die 'unexpected EOF' if $r == 0;
 213         } until $capa =~ /\.\r\n\z/;
 214
 215         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 216         if ($need_zlib) {
 217                 unlike($capa, $deflate_capa,
 218                         'COMPRESS DEFLATE NOT advertised '.$need_zlib);
 219         } else {
 220                 like($capa, $deflate_capa, 'COMPRESS DEFLATE advertised');
 221         }
 222         $capa;
 223 }
 224
 225 1;