t/nntpd-tls.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use File::Temp qw(tempdir);
   7 use Socket qw(SOCK_STREAM IPPROTO_TCP SOL_SOCKET);
   8 # IO::Poll and Net::NNTP are part of the standard library, but
   9 # distros may split them off...
  10 foreach my $mod (qw(DBD::SQLite IO::Socket::SSL Net::NNTP IO::Poll)) {
  11         eval "require $mod";
  12         plan skip_all => "$mod missing for $0" if $@;
  13 }
  14 Net::NNTP->can('starttls') or
  15         plan skip_all => 'Net::NNTP does not support TLS';
  16 IO::Socket::SSL->VERSION(2.007) or
  17         plan skip_all => 'IO::Socket::SSL <2.007 not supported by Net::NNTP';
  18
  19 my $cert = 'certs/server-cert.pem';
  20 my $key = 'certs/server-key.pem';
  21 unless (-r $key && -r $cert) {
  22         plan skip_all =>
  23                 "certs/ missing for $0, run $^X ./create-certs.perl in certs/";
  24 }
  25
  26 use_ok 'PublicInbox::TLS';
  27 use_ok 'IO::Socket::SSL';
  28 require './t/common.perl';
  29 require PublicInbox::InboxWritable;
  30 require PublicInbox::MIME;
  31 require PublicInbox::SearchIdx;
  32 my $need_zlib;
  33 eval { require Compress::Raw::Zlib } or
  34         $need_zlib = 'Compress::Raw::Zlib missing';
  35 my $version = 2; # v2 needs newer git
  36 require_git('2.6') if $version >= 2;
  37 my $tmpdir = tempdir('pi-nntpd-tls-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  38 my $err = "$tmpdir/stderr.log";
  39 my $out = "$tmpdir/stdout.log";
  40 my $inboxdir = "$tmpdir";
  41 my $pi_config = "$tmpdir/pi_config";
  42 my $group = 'test-nntpd-tls';
  43 my $addr = $group . '@example.com';
  44 my $starttls = tcp_server();
  45 my $nntps = tcp_server();
  46 my $ibx = PublicInbox::Inbox->new({
  47         inboxdir => $inboxdir,
  48         name => 'nntpd-tls',
  49         version => $version,
  50         -primary_address => $addr,
  51         indexlevel => 'basic',
  52 });
  53 $ibx = PublicInbox::InboxWritable->new($ibx, {nproc=>1});
  54 $ibx->init_inbox(0);
  55 {
  56         open my $fh, '>', $pi_config or die "open: $!\n";
  57         print $fh <<EOF
  58 [publicinbox "nntpd-tls"]
  59         inboxdir = $inboxdir
  60         address = $addr
  61         indexlevel = basic
  62         newsgroup = $group
  63 EOF
  64         ;
  65         close $fh or die "close: $!\n";
  66 }
  67
  68 {
  69         my $im = $ibx->importer(0);
  70         my $mime = PublicInbox::MIME->new(do {
  71                 open my $fh, '<', 't/data/0001.patch' or die;
  72                 local $/;
  73                 <$fh>
  74         });
  75         ok($im->add($mime), 'message added');
  76         $im->done;
  77         if ($version == 1) {
  78                 my $s = PublicInbox::SearchIdx->new($ibx, 1);
  79                 $s->index_sync;
  80         }
  81 }
  82
  83 my $nntps_addr = $nntps->sockhost . ':' . $nntps->sockport;
  84 my $starttls_addr = $starttls->sockhost . ':' . $starttls->sockport;
  85 my $env = { PI_CONFIG => $pi_config };
  86 my $td;
  87
  88 for my $args (
  89         [ "--cert=$cert", "--key=$key",
  90                 "-lnntps://$nntps_addr",
  91                 "-lnntp://$starttls_addr" ],
  92 ) {
  93         for ($out, $err) {
  94                 open my $fh, '>', $_ or die "truncate: $!";
  95         }
  96         my $cmd = [ '-nntpd', '-W0', @$args, "--stdout=$out", "--stderr=$err" ];
  97         $td = start_script($cmd, $env, { 3 => $starttls, 4 => $nntps });
  98         my %o = (
  99                 SSL_hostname => 'server.local',
 100                 SSL_verifycn_name => 'server.local',
 101                 SSL_verify_mode => SSL_VERIFY_PEER(),
 102                 SSL_ca_file => 'certs/test-ca.pem',
 103         );
 104         my $expect = { $group => [qw(1 1 n)] };
 105
 106         # start negotiating a slow TLS connection
 107         my $slow = tcp_connect($nntps, Blocking => 0);
 108         $slow = IO::Socket::SSL->start_SSL($slow, SSL_startHandshake => 0, %o);
 109         my $slow_done = $slow->connect_SSL;
 110         my @poll;
 111         if ($slow_done) {
 112                 diag('W: connect_SSL early OK, slow client test invalid');
 113                 use PublicInbox::Syscall qw(EPOLLIN EPOLLOUT);
 114                 @poll = (fileno($slow), EPOLLIN | EPOLLOUT);
 115         } else {
 116                 @poll = (fileno($slow), PublicInbox::TLS::epollbit());
 117         }
 118         # we should call connect_SSL much later...
 119
 120         # NNTPS
 121         my $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 122         my $list = $c->list;
 123         is_deeply($list, $expect, 'NNTPS LIST works');
 124         unlike(get_capa($c), qr/\bSTARTTLS\r\n/,
 125                 'STARTTLS not advertised for NNTPS');
 126         is($c->command('QUIT')->response(), Net::Cmd::CMD_OK(), 'QUIT works');
 127         is(0, sysread($c, my $buf, 1), 'got EOF after QUIT');
 128
 129         # STARTTLS
 130         $c = Net::NNTP->new($starttls_addr, %o);
 131         $list = $c->list;
 132         is_deeply($list, $expect, 'plain LIST works');
 133         ok($c->starttls, 'STARTTLS succeeds');
 134         is($c->code, 382, 'got 382 for STARTTLS');
 135         $list = $c->list;
 136         is_deeply($list, $expect, 'LIST works after STARTTLS');
 137         unlike(get_capa($c), qr/\bSTARTTLS\r\n/,
 138                 'STARTTLS not advertised after STARTTLS');
 139
 140         # Net::NNTP won't let us do dumb things, but we need to test
 141         # dumb things, so use Net::Cmd directly:
 142         my $n = $c->command('STARTTLS')->response();
 143         is($n, Net::Cmd::CMD_ERROR(), 'error attempting STARTTLS again');
 144         is($c->code, 502, '502 according to RFC 4642 sec#2.2.1');
 145
 146         # STARTTLS with bad hostname
 147         $o{SSL_hostname} = $o{SSL_verifycn_name} = 'server.invalid';
 148         $c = Net::NNTP->new($starttls_addr, %o);
 149         like(get_capa($c), qr/\bSTARTTLS\r\n/, 'STARTTLS advertised');
 150         $list = $c->list;
 151         is_deeply($list, $expect, 'plain LIST works again');
 152         ok(!$c->starttls, 'STARTTLS fails with bad hostname');
 153         $c = Net::NNTP->new($starttls_addr, %o);
 154         $list = $c->list;
 155         is_deeply($list, $expect, 'not broken after bad negotiation');
 156
 157         # NNTPS with bad hostname
 158         $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 159         is($c, undef, 'NNTPS fails with bad hostname');
 160         $o{SSL_hostname} = $o{SSL_verifycn_name} = 'server.local';
 161         $c = Net::NNTP->new($nntps_addr, %o, SSL => 1);
 162         ok($c, 'NNTPS succeeds again with valid hostname');
 163
 164         # slow TLS connection did not block the other fast clients while
 165         # connecting, finish it off:
 166         until ($slow_done) {
 167                 IO::Poll::_poll(-1, @poll);
 168                 $slow_done = $slow->connect_SSL and last;
 169                 @poll = (fileno($slow), PublicInbox::TLS::epollbit());
 170         }
 171         $slow->blocking(1);
 172         ok(sysread($slow, my $greet, 4096) > 0, 'slow got greeting');
 173         like($greet, qr/\A201 /, 'got expected greeting');
 174         is(syswrite($slow, "QUIT\r\n"), 6, 'slow wrote QUIT');
 175         ok(sysread($slow, my $end, 4096) > 0, 'got EOF');
 176         is(sysread($slow, my $eof, 4096), 0, 'got EOF');
 177         $slow = undef;
 178
 179         SKIP: {
 180                 skip 'TCP_DEFER_ACCEPT is Linux-only', 2 if $^O ne 'linux';
 181                 my $var = Socket::TCP_DEFER_ACCEPT();
 182                 defined(my $x = getsockopt($nntps, IPPROTO_TCP, $var)) or die;
 183                 ok(unpack('i', $x) > 0, 'TCP_DEFER_ACCEPT set on NNTPS');
 184                 defined($x = getsockopt($starttls, IPPROTO_TCP, $var)) or die;
 185                 is(unpack('i', $x), 0, 'TCP_DEFER_ACCEPT is 0 on plain NNTP');
 186         };
 187         SKIP: {
 188                 skip 'SO_ACCEPTFILTER is FreeBSD-only', 2 if $^O ne 'freebsd';
 189                 if (system('kldstat -m accf_data >/dev/null')) {
 190                         skip 'accf_data not loaded? kldload accf_data', 2;
 191                 }
 192                 require PublicInbox::Daemon;
 193                 my $var = PublicInbox::Daemon::SO_ACCEPTFILTER();
 194                 my $x = getsockopt($nntps, SOL_SOCKET, $var);
 195                 like($x, qr/\Adataready\0+\z/, 'got dataready accf for NNTPS');
 196                 $x = getsockopt($starttls, IPPROTO_TCP, $var);
 197                 is($x, undef, 'no BSD accept filter for plain NNTP');
 198         };
 199
 200         $c = undef;
 201         $td->kill;
 202         $td->join;
 203         is($?, 0, 'no error in exited process');
 204         my $eout = eval {
 205                 open my $fh, '<', $err or die "open $err failed: $!";
 206                 local $/;
 207                 <$fh>;
 208         };
 209         unlike($eout, qr/wide/i, 'no Wide character warnings');
 210 }
 211 done_testing();
 212
 213 sub get_capa {
 214         my ($sock) = @_;
 215         syswrite($sock, "CAPABILITIES\r\n");
 216         my $capa = '';
 217         do {
 218                 my $r = sysread($sock, $capa, 8192, length($capa));
 219                 die "unexpected: $!" unless defined($r);
 220                 die 'unexpected EOF' if $r == 0;
 221         } until $capa =~ /\.\r\n\z/;
 222
 223         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 224         if ($need_zlib) {
 225                 unlike($capa, $deflate_capa,
 226                         'COMPRESS DEFLATE NOT advertised '.$need_zlib);
 227         } else {
 228                 like($capa, $deflate_capa, 'COMPRESS DEFLATE advertised');
 229         }
 230         $capa;
 231 }
 232
 233 1;