t/nntpd-validate.t

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Integration test to validate compression.
   5 use strict;
   6 use warnings;
   7 use Test::More;
   8 use Symbol qw(gensym);
   9 use Time::HiRes qw(clock_gettime CLOCK_MONOTONIC);
  10 use POSIX qw(_exit);
  11 my $inbox_dir = $ENV{GIANT_INBOX_DIR};
  12 plan skip_all => "GIANT_INBOX_DIR not defined for $0" unless $inbox_dir;
  13 my $mid = $ENV{TEST_MID};
  14
  15 # Net::NNTP is part of the standard library, but distros may split it off...
  16 foreach my $mod (qw(DBD::SQLite Net::NNTP Compress::Raw::Zlib)) {
  17         eval "require $mod";
  18         plan skip_all => "$mod missing for $0" if $@;
  19 }
  20
  21 my $test_compress = Net::NNTP->can('compress');
  22 if (!$test_compress) {
  23         diag 'Your Net::NNTP does not yet support compression';
  24         diag 'See: https://rt.cpan.org/Ticket/Display.html?id=129967';
  25 }
  26 my $test_tls = $ENV{TEST_SKIP_TLS} ? 0 : eval { require IO::Socket::SSL };
  27 my $cert = 'certs/server-cert.pem';
  28 my $key = 'certs/server-key.pem';
  29 if ($test_tls && !-r $key || !-r $cert) {
  30         plan skip_all => "certs/ missing for $0, run $^X ./certs/create-certs.perl";
  31 }
  32 require './t/common.perl';
  33 my ($tmpdir, $ftd) = tmpdir();
  34 $File::Temp::KEEP_ALL = !!$ENV{TEST_KEEP_TMP};
  35 my (%OPT, $td, $host_port, $group);
  36 my $batch = 1000;
  37 if (($ENV{NNTP_TEST_URL} // '') =~ m!\Anntp://([^/]+)/([^/]+)\z!) {
  38         ($host_port, $group) = ($1, $2);
  39         $host_port .= ":119" unless index($host_port, ':') > 0;
  40 } else {
  41         make_local_server();
  42 }
  43 my $test_article = $ENV{TEST_ARTICLE} // 0;
  44 my $test_xover = $ENV{TEST_XOVER} // 1;
  45
  46 if ($test_tls) {
  47         my $nntp = Net::NNTP->new($host_port, %OPT);
  48         ok($nntp->starttls, 'STARTTLS works');
  49         ok($nntp->compress, 'COMPRESS works') if $test_compress;
  50         ok($nntp->quit, 'QUIT after starttls OK');
  51 }
  52 if ($test_compress) {
  53         my $nntp = Net::NNTP->new($host_port, %OPT);
  54         ok($nntp->compress, 'COMPRESS works');
  55         ok($nntp->quit, 'QUIT after compress OK');
  56 }
  57
  58 sub do_get_all {
  59         my ($methods) = @_;
  60         my $desc = join(',', @$methods);
  61         my $t0 = clock_gettime(CLOCK_MONOTONIC);
  62         my $dig = Digest::SHA->new(1);
  63         my $digfh = gensym;
  64         my $tmpfh;
  65         if ($File::Temp::KEEP_ALL) {
  66                 open $tmpfh, '>', "$tmpdir/$desc.raw" or die $!;
  67         }
  68         my $tmp = { dig => $dig, tmpfh => $tmpfh };
  69         tie *$digfh, 'DigestPipe', $tmp;
  70         my $nntp = Net::NNTP->new($host_port, %OPT);
  71         $nntp->article("<$mid>", $digfh) if $mid;
  72         foreach my $m (@$methods) {
  73                 my $res = $nntp->$m;
  74                 print STDERR "# $m got $res ($desc)\n" if !$res;
  75         }
  76         $nntp->article("<$mid>", $digfh) if $mid;
  77         my ($num, $first, $last) = $nntp->group($group);
  78         unless (defined $num && defined $first && defined $last) {
  79                 warn "Invalid group\n";
  80                 return undef;
  81         }
  82         my $i;
  83         for ($i = $first; $i < $last; $i += $batch) {
  84                 my $j = $i + $batch - 1;
  85                 $j = $last if $j > $last;
  86                 if ($test_xover) {
  87                         my $xover = $nntp->xover("$i-$j");
  88                         for my $n (sort { $a <=> $b } keys %$xover) {
  89                                 my $line = join("\t", @{$xover->{$n}});
  90                                 $line =~ tr/\r//d;
  91                                 $dig->add("$n\t".$line);
  92                         }
  93                 }
  94                 if ($test_article) {
  95                         for my $n ($i..$j) {
  96                                 $nntp->article($n, $digfh) and next;
  97                                 next if $nntp->code == 423;
  98                                 my $res = $nntp->code.' '.  $nntp->message;
  99
 100                                 $res =~ tr/\r\n//d;
 101                                 print STDERR "# Article $n ($desc): $res\n";
 102                         }
 103                 }
 104         }
 105
 106         # hacky bytes_read thing added to Net::NNTP for testing:
 107         my $bytes_read = '';
 108         if ($nntp->can('bytes_read')) {
 109                 $bytes_read .= ' '.$nntp->bytes_read.'b';
 110         }
 111         my $q = $nntp->quit;
 112         print STDERR "# quit failed: ".$nntp->code."\n" if !$q;
 113         my $elapsed = sprintf('%0.3f', clock_gettime(CLOCK_MONOTONIC) - $t0);
 114         my $res = $dig->hexdigest;
 115         print STDERR "# $desc - $res (${elapsed}s)$bytes_read\n";
 116         $res;
 117 }
 118 my @tests = ([]);
 119 push @tests, [ 'compress' ] if $test_compress;
 120 push @tests, [ 'starttls' ] if $test_tls;
 121 push @tests, [ 'starttls', 'compress' ] if $test_tls && $test_compress;
 122 my (@keys, %thr, %res);
 123 for my $m (@tests) {
 124         my $key = join(',', @$m);
 125         push @keys, $key;
 126         pipe(my ($r, $w)) or die;
 127         my $pid = fork;
 128         if ($pid == 0) {
 129                 close $r or die;
 130                 my $res = do_get_all($m);
 131                 print $w $res or die;
 132                 $w->flush;
 133                 _exit(0);
 134         }
 135         close $w or die;
 136         $thr{$key} = [ $pid, $r ];
 137 }
 138 for my $key (@keys) {
 139         my ($pid, $r) = @{delete $thr{$key}};
 140         local $/;
 141         $res{$key} = <$r>;
 142         defined $res{$key} or die "nothing for $key";
 143         my $w = waitpid($pid, 0);
 144         defined($w) or die;
 145         $w == $pid or die "waitpid($pid) != $w)";
 146         is($?, 0, "`$key' exited successfully")
 147 }
 148
 149 my $plain = $res{''};
 150 ok($plain, "plain got $plain");
 151 is($res{$_}, $plain, "$_ matches '' result") for @keys;
 152
 153 done_testing();
 154
 155 sub make_local_server {
 156         require PublicInbox::Inbox;
 157         $group = 'inbox.test.perf.nntpd';
 158         my $ibx = { inboxdir => $inbox_dir, newsgroup => $group };
 159         $ibx = PublicInbox::Inbox->new($ibx);
 160         my $pi_config = "$tmpdir/config";
 161         {
 162                 open my $fh, '>', $pi_config or die "open($pi_config): $!";
 163                 print $fh <<"" or die "print $pi_config: $!";
 164 [publicinbox "test"]
 165         newsgroup = $group
 166         inboxdir = $inbox_dir
 167         address = test\@example.com
 168
 169                 close $fh or die "close($pi_config): $!";
 170         }
 171         my ($out, $err) = ("$tmpdir/out", "$tmpdir/err");
 172         for ($out, $err) {
 173                 open my $fh, '>', $_ or die "truncate: $!";
 174         }
 175         my $sock = tcp_server();
 176         ok($sock, 'sock created');
 177         $host_port = $sock->sockhost . ':' . $sock->sockport;
 178
 179         # not using multiple workers, here, since we want to increase
 180         # the chance of tripping concurrency bugs within PublicInbox/NNTP*.pm
 181         my $cmd = [ '-nntpd', "--stdout=$out", "--stderr=$err", '-W0' ];
 182         push @$cmd, "-lnntp://$host_port";
 183         if ($test_tls) {
 184                 push @$cmd, "--cert=$cert", "--key=$key";
 185                 %OPT = (
 186                         SSL_hostname => 'server.local',
 187                         SSL_verifycn_name => 'server.local',
 188                         SSL_verify_mode => IO::Socket::SSL::SSL_VERIFY_PEER(),
 189                         SSL_ca_file => 'certs/test-ca.pem',
 190                 );
 191         }
 192         print STDERR "# CMD ". join(' ', @$cmd). "\n";
 193         my $env = { PI_CONFIG => $pi_config };
 194         $td = start_script($cmd, $env, { 3 => $sock });
 195 }
 196
 197 package DigestPipe;
 198 use strict;
 199 use warnings;
 200
 201 sub TIEHANDLE {
 202         my ($class, $self) = @_;
 203         bless $self, $class;
 204 }
 205
 206 sub PRINT {
 207         my $self = shift;
 208         my $data = join('', @_);
 209         # Net::NNTP emit different line-endings depending on TLS or not...:
 210         $data =~ tr/\r//d;
 211         $self->{dig}->add($data);
 212         if (my $tmpfh = $self->{tmpfh}) {
 213                 print $tmpfh $data;
 214         }
 215         1;
 216 }
 217 1;