t/nntpd.t

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 foreach my $mod (qw(DBD::SQLite Search::Xapian Danga::Socket)) {
   7         eval "require $mod";
   8         plan skip_all => "$mod missing for nntpd.t" if $@;
   9 }
  10 require PublicInbox::SearchIdx;
  11 require PublicInbox::Msgmap;
  12 use Cwd;
  13 use Email::Simple;
  14 use IO::Socket;
  15 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
  16 use Socket qw(SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
  17 use File::Temp qw/tempdir/;
  18 use Net::NNTP;
  19
  20 my $tmpdir = tempdir('pi-nntpd-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  21 my $home = "$tmpdir/pi-home";
  22 my $err = "$tmpdir/stderr.log";
  23 my $out = "$tmpdir/stdout.log";
  24 my $mainrepo = "$tmpdir/main.git";
  25 my $group = 'test-nntpd';
  26 my $addr = $group . '@example.com';
  27 my $nntpd = 'blib/script/public-inbox-nntpd';
  28 my $init = 'blib/script/public-inbox-init';
  29 use_ok 'PublicInbox::Import';
  30 use_ok 'PublicInbox::Inbox';
  31 use_ok 'PublicInbox::Git';
  32 use_ok 'PublicInbox::V2Writable';
  33
  34 # XXX FIXME: make it easier to test both versions
  35 my $version = int($ENV{PI_VERSION} || 1);
  36 my %opts = (
  37         LocalAddr => '127.0.0.1',
  38         ReuseAddr => 1,
  39         Proto => 'tcp',
  40         Type => SOCK_STREAM,
  41         Listen => 1024,
  42 );
  43 my $sock = IO::Socket::INET->new(%opts);
  44 my $pid;
  45 my $len;
  46 END { kill 'TERM', $pid if defined $pid };
  47
  48 my $ibx = {
  49         mainrepo => $mainrepo,
  50         name => $group,
  51         version => $version,
  52         -primary_address => $addr,
  53 };
  54 $ibx = PublicInbox::Inbox->new($ibx);
  55 {
  56         local $ENV{HOME} = $home;
  57         my @cmd = ($init, $group, $mainrepo, 'http://example.com/', $addr);
  58         push @cmd, "-V$version";
  59         is(system(@cmd), 0, 'init OK');
  60         is(system(qw(git config), "--file=$home/.public-inbox/config",
  61                         "publicinbox.$group.newsgroup", $group),
  62                 0, 'enabled newsgroup');
  63         my $len;
  64
  65         my $im;
  66         if ($version == 2) {
  67                 $im = PublicInbox::V2Writable->new($ibx);
  68         } elsif ($version == 1) {
  69                 my $git = PublicInbox::Git->new($mainrepo);
  70                 $im = PublicInbox::Import->new($git, 'test', $addr);
  71         } else {
  72                 die "unsupported version: $version";
  73         }
  74
  75         # ensure successful message delivery
  76         {
  77                 my $mime = Email::MIME->new(<<EOF);
  78 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  79 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  80 Cc: $addr
  81 Message-Id: <nntp\@example.com>
  82 Content-Type: text/plain; charset=utf-8
  83 Subject: Testing for =?utf-8?Q?El=C3=A9anor?=
  84 Date: Thu, 01 Jan 1970 06:06:06 +0000
  85 Content-Transfer-Encoding: 8bit
  86
  87 This is a test message for El\xc3\xa9anor
  88 EOF
  89                 my $list_id = $addr;
  90                 $list_id =~ s/@/./;
  91                 $mime->header_set('List-Id', "<$list_id>");
  92                 $len = length($mime->as_string);
  93                 $im->add($mime);
  94                 $im->done;
  95                 if ($version == 1) {
  96                         my $s = PublicInbox::SearchIdx->new($mainrepo, 1);
  97                         $s->index_sync;
  98                 }
  99         }
 100
 101         ok($sock, 'sock created');
 102         $! = 0;
 103         my $fl = fcntl($sock, F_GETFD, 0);
 104         ok(! $!, 'no error from fcntl(F_GETFD)');
 105         is($fl, FD_CLOEXEC, 'cloexec set by default (Perl behavior)');
 106         $pid = fork;
 107         if ($pid == 0) {
 108                 use POSIX qw(dup2);
 109                 # pretend to be systemd
 110                 fcntl($sock, F_SETFD, $fl &= ~FD_CLOEXEC);
 111                 dup2(fileno($sock), 3) or die "dup2 failed: $!\n";
 112                 $ENV{LISTEN_PID} = $$;
 113                 $ENV{LISTEN_FDS} = 1;
 114                 exec $nntpd, "--stdout=$out", "--stderr=$err";
 115                 die "FAIL: $!\n";
 116         }
 117         ok(defined $pid, 'forked nntpd process successfully');
 118         $! = 0;
 119         fcntl($sock, F_SETFD, $fl |= FD_CLOEXEC);
 120         ok(! $!, 'no error from fcntl(F_SETFD)');
 121         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 122         my $n = Net::NNTP->new($host_port);
 123         my $list = $n->list;
 124         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
 125         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
 126         is_deeply($n->listgroup($group), [1], 'listgroup OK');
 127
 128         %opts = (
 129                 PeerAddr => $host_port,
 130                 Proto => 'tcp',
 131                 Type => SOCK_STREAM,
 132                 Timeout => 1,
 133         );
 134         my $mid = '<nntp@example.com>';
 135         my %xhdr = (
 136                 'message-id' => $mid,
 137                 subject => "Testing for El\xc3\xa9anor",
 138                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 139                 'from' => "El\xc3\xa9anor <me\@example.com>",
 140                 'to' => "El\xc3\xa9anor <you\@example.com>",
 141                 'cc' => $addr,
 142                 'xref' => "example.com $group:1"
 143         );
 144
 145         my $s = IO::Socket::INET->new(%opts);
 146         sysread($s, my $buf, 4096);
 147         is($buf, "201 server ready - post via email\r\n", 'got greeting');
 148         $s->autoflush(1);
 149
 150         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 151         ok(syswrite($s, "\r\n"), 'wrote nothing');
 152         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 153         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 154
 155         $s = IO::Socket::INET->new(%opts);
 156         sysread($s, $buf, 4096);
 157         is($buf, "201 server ready - post via email\r\n", 'got greeting');
 158         $s->autoflush(1);
 159
 160         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 161         $buf = read_til_dot($s);
 162         like($buf, qr/\A231 list of /, 'newgroups OK');
 163
 164         while (my ($k, $v) = each %xhdr) {
 165                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 166                           "XHDR $k by message-id works");
 167                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 168                           "$k by article number works");
 169                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 170                           "$k by article range works");
 171                 $buf = '';
 172                 syswrite($s, "HDR $k $mid\r\n");
 173                 $buf = read_til_dot($s);
 174                 my @r = split("\r\n", $buf);
 175                 like($r[0], qr/\A225 /, '225 response for HDR');
 176                 is($r[1], "0 $v", 'got expected response for HDR');
 177         }
 178
 179         {
 180                 my $nogroup = Net::NNTP->new($host_port);
 181                 while (my ($k, $v) = each %xhdr) {
 182                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 183                                   "$k by message-id works without group");
 184                 }
 185         }
 186
 187         is_deeply($n->xover('1-'), {
 188                 '1' => ["Testing for El\xc3\xa9anor",
 189                         "El\xc3\xa9anor <me\@example.com>",
 190                         'Thu, 01 Jan 1970 06:06:06 +0000',
 191                         '<nntp@example.com>',
 192                         '',
 193                         $len,
 194                         '1' ] }, "XOVER range works");
 195
 196         is_deeply($n->xover('1'), {
 197                 '1' => ["Testing for El\xc3\xa9anor",
 198                         "El\xc3\xa9anor <me\@example.com>",
 199                         'Thu, 01 Jan 1970 06:06:06 +0000',
 200                         '<nntp@example.com>',
 201                         '',
 202                         $len,
 203                         '1' ] }, "XOVER by article works");
 204
 205         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 206         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 207         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 208                 'body really matches');
 209         my $art = $n->article(1);
 210         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 211         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 212         is($n->article(999), undef, 'non-existent num');
 213         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 214
 215         {
 216                 syswrite($s, "OVER $mid\r\n");
 217                 $buf = read_til_dot($s);
 218                 my @r = split("\r\n", $buf);
 219                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 220                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 221                         "El\xc3\xa9anor <me\@example.com>\t" .
 222                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 223                         "$mid\t\t$len\t1", 'OVER by Message-ID works');
 224                 is($r[2], '.', 'correctly terminated response');
 225         }
 226
 227         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 228                  'XHDR Cc 1- works');
 229         is_deeply($n->xhdr(qw(References 1-)), { 1 => '' },
 230                  'XHDR References 1- works (empty string)');
 231         is_deeply($n->xhdr(qw(list-id 1-)), {},
 232                  'XHDR on invalid header returns empty');
 233
 234         my $mids = $n->newnews(0, '*');
 235         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 236         {
 237                 my $t0 = time;
 238                 my $date = $n->date;
 239                 my $t1 = time;
 240                 ok($date >= $t0, 'valid date after start');
 241                 ok($date <= $t1, 'valid date before stop');
 242         }
 243
 244         {
 245                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 246                 syswrite($s, 'HDR List-id 1-');
 247                 select(undef, undef, undef, 0.15);
 248                 ok(kill('TERM', $pid), 'killed nntpd');
 249                 select(undef, undef, undef, 0.15);
 250                 syswrite($s, "\r\n");
 251                 $buf = '';
 252                 do {
 253                         sysread($s, $buf, 4096, length($buf));
 254                 } until ($buf =~ /\r\n\z/);
 255                 my @r = split("\r\n", $buf);
 256                 like($r[0], qr/^5\d\d /,
 257                         'got 5xx response for unoptimized HDR');
 258                 is(scalar @r, 1, 'only one response line');
 259         }
 260
 261         $n = $s = undef;
 262         is($pid, waitpid($pid, 0), 'nntpd exited successfully');
 263         my $eout = eval {
 264                 local $/;
 265                 open my $fh, '<', $err or die "open $err failed: $!";
 266                 <$fh>;
 267         };
 268         is($?, 0, 'no error in exited process');
 269         unlike($eout, qr/wide/i, 'no Wide character warnings');
 270 }
 271
 272 done_testing();
 273
 274 sub read_til_dot {
 275         my ($s) = @_;
 276         my $buf = '';
 277         do {
 278                 sysread($s, $buf, 4096, length($buf));
 279         } until ($buf =~ /\r\n\.\r\n\z/);
 280         $buf;
 281 }
 282
 283 1;