t/nntpd.t

   1 #!perl -w
   2 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Spawn qw(which);
   8 require_mods(qw(DBD::SQLite));
   9 use PublicInbox::Eml;
  10 use Socket qw(IPPROTO_TCP TCP_NODELAY);
  11 use Net::NNTP;
  12 use Sys::Hostname;
  13 use POSIX qw(_exit);
  14 use Digest::SHA;
  15
  16 # t/nntpd-v2.t wraps this for v2
  17 my $version = $ENV{PI_TEST_VERSION} || 1;
  18 require_git('2.6') if $version == 2;
  19 use_ok 'PublicInbox::Msgmap';
  20 my $lsof = which('lsof');
  21 my $fast_idle = eval { require Linux::Inotify2; 1 } //
  22                 eval { require IO::KQueue; 1 };
  23
  24 my ($tmpdir, $for_destroy) = tmpdir();
  25 my $home = "$tmpdir/pi-home";
  26 my $err = "$tmpdir/stderr.log";
  27 my $out = "$tmpdir/stdout.log";
  28 my $inboxdir = "$tmpdir/inbox";
  29 my $group = 'test-nntpd';
  30 my $addr = $group . '@example.com';
  31 my $sock = tcp_server();
  32 my $host_port = tcp_host_port($sock);
  33 my $td;
  34
  35 my $eml = PublicInbox::Eml->new(<<EOF);
  36 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  37 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  38 Cc: $addr
  39 Message-Id: <nntp\@example.com>
  40 Content-Type: text/plain; charset=utf-8
  41 Subject: Testing for    =?utf-8?Q?El=C3=A9anor?=
  42 Date: Thu, 01 Jan 1970 06:06:06 +0000
  43 Content-Transfer-Encoding: 8bit
  44 References: <ref        tab     squeezed>
  45
  46 This is a test message for El\xc3\xa9anor
  47 EOF
  48 my $list_id = $addr;
  49 $list_id =~ s/@/./;
  50 $eml->header_set('List-Id', "<$list_id>");
  51 my $str = $eml->as_string;
  52 $str =~ s/(?<!\r)\n/\r\n/sg;
  53 my $len = length($str);
  54 undef $str;
  55
  56 my $ibx = create_inbox "v$version", version => $version, indexlevel => 'basic',
  57                         tmpdir => $inboxdir, sub {
  58         my ($im, $ibx) = @_;
  59         $im->add($eml) or BAIL_OUT;
  60 };
  61 undef $eml;
  62 my $other = create_inbox "other$version", version => $version,
  63                 indexlevel => 'basic', sub {
  64         my ($im) = @_;
  65         $im->add(eml_load 't/utf8.eml') or BAIL_OUT;
  66 };
  67
  68 local $ENV{HOME} = $home;
  69 mkdir $home or BAIL_OUT $!;
  70 mkdir "$home/.public-inbox" or BAIL_OUT $!;
  71 open my $cfgfh, '>', "$home/.public-inbox/config" or BAIL_OUT $!;
  72 print $cfgfh <<EOF or BAIL_OUT;
  73 [publicinbox "$group"]
  74         inboxdir = $inboxdir
  75         url = http://example.com/abc
  76         address = $addr
  77         indexlevel = basic
  78         newsgroup = $group
  79 [publicinbox "xyz"]
  80         inboxdir = $other->{inboxdir}
  81         url = http://example.com/xyz
  82         address = e\@example.com
  83         indexlevel = basic
  84         newsgroup = x.y.z
  85 [publicinboxMda]
  86         spamcheck = none
  87 EOF
  88 close $cfgfh or BAIL_OUT;
  89
  90 {
  91         my $cmd = [ '-nntpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  92         $td = start_script($cmd, undef, { 3 => $sock });
  93         my $n = Net::NNTP->new($host_port);
  94         my $list = $n->list;
  95         ok(delete $list->{'x.y.z'}, 'deleted x.y.z group');
  96         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
  97         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
  98         is_deeply($n->listgroup($group), [1], 'listgroup OK');
  99         # TODO: Net::NNTP::listgroup does not support range at the moment
 100
 101         {
 102                 my $expect = [ qw(Subject: From: Date: Message-ID:
 103                                 References: Bytes: Lines: Xref:full) ];
 104                 is_deeply($n->overview_fmt, $expect,
 105                         'RFC3977 8.4.2 compliant LIST OVERVIEW.FMT');
 106         }
 107         SKIP: {
 108                 $n->can('starttls') or
 109                         skip('Net::NNTP too old to support STARTTLS', 2);
 110                 require_mods('IO::Socket::SSL', 2);
 111                 ok(!$n->starttls, 'STARTTLS fails when unconfigured');
 112                 is($n->code, 580, 'got 580 code on server w/o TLS');
 113         };
 114
 115         my $mid = '<nntp@example.com>';
 116         my %xhdr = (
 117                 'message-id' => $mid,
 118                 subject => "Testing for El\xc3\xa9anor",
 119                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 120                 'from' => "El\xc3\xa9anor <me\@example.com>",
 121                 'to' => "El\xc3\xa9anor <you\@example.com>",
 122                 'cc' => $addr,
 123                 'xref' => hostname . " $group:1",
 124                 'references' => '<reftabsqueezed>',
 125         );
 126
 127         my $s = tcp_connect($sock);
 128         sysread($s, my $buf, 4096);
 129         is($buf, "201 " . hostname . " ready - post via email\r\n",
 130                 'got greeting');
 131
 132         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 133         ok(syswrite($s, "\r\n"), 'wrote nothing');
 134         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 135         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 136
 137         $s = tcp_connect($sock);
 138         sysread($s, $buf, 4096);
 139         is($buf, "201 " . hostname . " ready - post via email\r\n",
 140                 'got greeting');
 141
 142         syswrite($s, "CAPABILITIES\r\n");
 143         $buf = read_til_dot($s);
 144         like($buf, qr/\r\nVERSION 2\r\n/s, 'CAPABILITIES works');
 145         unlike($buf, qr/STARTTLS/s, 'STARTTLS not advertised');
 146         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 147         if (eval { require Compress::Raw::Zlib }) {
 148                 like($buf, $deflate_capa, 'DEFLATE advertised');
 149         } else {
 150                 unlike($buf, $deflate_capa,
 151                         'DEFLATE not advertised (Compress::Raw::Zlib missing)');
 152         }
 153
 154         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 155         $buf = read_til_dot($s);
 156         like($buf, qr/\A231 list of /, 'newgroups OK');
 157
 158         while (my ($k, $v) = each %xhdr) {
 159                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 160                           "XHDR $k by message-id works");
 161                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 162                           "$k by article number works");
 163                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 164                           "$k by article range works");
 165                 $buf = '';
 166                 syswrite($s, "HDR $k $mid\r\n");
 167                 $buf = read_til_dot($s);
 168                 my @r = split("\r\n", $buf);
 169                 like($r[0], qr/\A225 /, '225 response for HDR');
 170                 is($r[1], "0 $v", 'got expected response for HDR');
 171         }
 172
 173         {
 174                 my $nogroup = Net::NNTP->new($host_port);
 175                 while (my ($k, $v) = each %xhdr) {
 176                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 177                                   "$k by message-id works without group");
 178                 }
 179         }
 180
 181         is_deeply($n->xover('1-'), {
 182                 '1' => ["Testing for El\xc3\xa9anor",
 183                         "El\xc3\xa9anor <me\@example.com>",
 184                         'Thu, 01 Jan 1970 06:06:06 +0000',
 185                         '<nntp@example.com>',
 186                         '<reftabsqueezed>',
 187                         $len,
 188                         '1',
 189                         'Xref: '. hostname . ' test-nntpd:1'] },
 190                 "XOVER range works");
 191
 192         is_deeply($n->xover('1'), {
 193                 '1' => ["Testing for El\xc3\xa9anor",
 194                         "El\xc3\xa9anor <me\@example.com>",
 195                         'Thu, 01 Jan 1970 06:06:06 +0000',
 196                         '<nntp@example.com>',
 197                         '<reftabsqueezed>',
 198                         $len,
 199                         '1',
 200                         'Xref: '. hostname . ' test-nntpd:1'] },
 201                 "XOVER by article works");
 202
 203         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 204         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 205         is_deeply($n->nntpstat(1), '<nntp@example.com>', 'STAT');
 206         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 207                 'body really matches');
 208         my $art = $n->article(1);
 209         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 210         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 211         is($n->article(999), undef, 'non-existent num');
 212         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 213
 214         {
 215                 syswrite($s, "OVER $mid\r\n");
 216                 $buf = read_til_dot($s);
 217                 my @r = split("\r\n", $buf);
 218                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 219                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 220                         "El\xc3\xa9anor <me\@example.com>\t" .
 221                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 222                         "$mid\t<reftabsqueezed>\t$len\t1" .
 223                         "\tXref: " . hostname . " test-nntpd:0",
 224                         'OVER by Message-ID works');
 225                 is($r[2], '.', 'correctly terminated response');
 226         }
 227
 228         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 229                  'XHDR Cc 1- works');
 230         is_deeply($n->xhdr(qw(References 1-)), { 1 => '<reftabsqueezed>' },
 231                  'XHDR References 1- works)');
 232         is_deeply($n->xhdr(qw(list-id 1-)), {},
 233                  'XHDR on invalid header returns empty');
 234
 235         my $mids = $n->newnews(0, $group);
 236         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 237         {
 238                 my $t0 = time;
 239                 my $date = $n->date;
 240                 my $t1 = time;
 241                 ok($date >= $t0, 'valid date after start');
 242                 ok($date <= $t1, 'valid date before stop');
 243         }
 244         if ('leafnode interop') {
 245                 my $for_leafnode = PublicInbox::Eml->new(<<"");
 246 From: longheader\@example.com
 247 To: $addr
 248 Subject: none
 249 Date: Fri, 02 Oct 1993 00:00:00 +0000
 250
 251                 my $long_hdr = 'for-leafnode-'.('y'x200).'@example.com';
 252                 $for_leafnode->header_set('Message-ID', "<$long_hdr>");
 253                 my $im = $ibx->importer(0);
 254                 $im->add($for_leafnode);
 255                 $im->done;
 256                 my $hdr = $n->head("<$long_hdr>");
 257                 my $expect = qr/\AMessage-ID: /i . qr/\Q<$long_hdr>\E/;
 258                 ok(scalar(grep(/$expect/, @$hdr)), 'Message-ID not folded');
 259                 ok(scalar(grep(/^Path:/, @$hdr)), 'Path: header found');
 260
 261                 # it's possible for v2 messages to have 2+ Message-IDs,
 262                 # but leafnode can't handle it
 263                 if ($version != 1) {
 264                         my @mids = ("<$long_hdr>", '<2mid@wtf>');
 265                         $for_leafnode->header_set('Message-ID', @mids);
 266                         $for_leafnode->body_set('not-a-dupe');
 267                         my $warn = '';
 268                         local $SIG{__WARN__} = sub { $warn .= join('', @_) };
 269                         $im->add($for_leafnode);
 270                         $im->done;
 271                         like($warn, qr/reused/, 'warned for reused MID');
 272                         $hdr = $n->head('<2mid@wtf>');
 273                         my @hmids = grep(/\AMessage-ID: /i, @$hdr);
 274                         is(scalar(@hmids), 1, 'Single Message-ID in header');
 275                         like($hmids[0], qr/: <2mid\@wtf>/, 'got expected mid');
 276                 }
 277         }
 278
 279         ok($n->article('<testmessage@example.com>'),
 280                 'cross newsgroup ARTICLE by Message-ID');
 281         ok($n->body('<testmessage@example.com>'),
 282                 'cross newsgroup BODY by Message-ID');
 283         ok($n->head('<testmessage@example.com>'),
 284                 'cross newsgroup HEAD by Message-ID');
 285         is($n->xpath('<testmessage@example.com>'), 'x.y.z/1', 'xpath hit');
 286         is($n->xpath('<non-existent@example.com>'), undef, 'xpath miss');
 287
 288         # pipelined requests:
 289         {
 290                 my $nreq = 90;
 291                 my $nart = 2;
 292                 syswrite($s, "GROUP $group\r\n");
 293                 my $res = <$s>;
 294                 my $rdr = fork;
 295                 if ($rdr == 0) {
 296                         for (1..$nreq) {
 297                                 <$s> =~ /\A224 / or _exit(1);
 298                                 <$s> =~ /\A1/ or _exit(2);
 299                                 <$s> eq ".\r\n" or _exit(3);
 300                         }
 301                         my %sums;
 302                         for (1..$nart) {
 303                                 <$s> =~ /\A220 / or _exit(4);
 304                                 my $dig = Digest::SHA->new(1);
 305                                 while (my $l = <$s>) {
 306                                         last if $l eq ".\r\n";
 307                                         $dig->add($l);
 308                                 }
 309                                 $dig = $dig->hexdigest;
 310                                 $sums{$dig}++;
 311                         }
 312                         if ($nart) {
 313                                 scalar(keys(%sums)) == 1 or _exit(5);
 314                                 (values(%sums))[0] == $nart or _exit(6);
 315                         }
 316                         _exit(0);
 317                 }
 318                 for (1..$nreq) {
 319                         syswrite($s, "XOVER 1\r\n");
 320                 }
 321                 syswrite($s, "ARTICLE 1\r\n" x $nart);
 322                 is($rdr, waitpid($rdr, 0), 'reader done');
 323                 is($? >> 8, 0, 'no errors');
 324         }
 325         my $noerr = { 2 => \(my $null) };
 326         SKIP: {
 327                 if ($INC{'Search/Xapian.pm'} && ($ENV{TEST_RUN_MODE}//2)) {
 328                         skip 'Search/Xapian.pm pre-loaded (by t/run.perl?)', 1;
 329                 }
 330                 $lsof or skip 'lsof missing', 1;
 331                 my @of = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 332                 skip('lsof broken', 1) if (!scalar(@of) || $?);
 333                 my @xap = grep m!Search/Xapian!, @of;
 334                 is_deeply(\@xap, [], 'Xapian not loaded in nntpd');
 335         }
 336         # -compact requires Xapian
 337         SKIP: {
 338                 require_mods('Search::Xapian', 2);
 339                 have_xapian_compact or skip 'xapian-compact missing', 2;
 340                 is(xsys(qw(git config), "--file=$home/.public-inbox/config",
 341                                 "publicinbox.$group.indexlevel", 'medium'),
 342                         0, 'upgraded indexlevel');
 343                 my $ex = eml_load('t/data/0001.patch');
 344                 is($n->article($ex->header('Message-ID')), undef,
 345                         'article did not exist');
 346                 my $im = $ibx->importer(0);
 347                 $im->add($ex);
 348                 $im->done;
 349                 {
 350                         my $f = $ibx->mm->{dbh}->sqlite_db_filename;
 351                         my $tmp = "$tmpdir/tmp.sqlite3";
 352                         $ibx->mm->{dbh}->sqlite_backup_to_file($tmp);
 353                         delete $ibx->{mm};
 354                         rename($tmp, $f) or BAIL_OUT "rename($tmp, $f): $!";
 355                 }
 356                 ok(run_script([qw(-index -c -j0 --reindex), $ibx->{inboxdir}],
 357                                 undef, $noerr), '-compacted');
 358                 select(undef, undef, undef, $fast_idle ? 0.1 : 2.1);
 359                 $art = $n->article($ex->header('Message-ID'));
 360                 ok($art, 'new article retrieved after compact');
 361                 $lsof or skip 'lsof missing', 1;
 362                 ($^O =~ /\A(?:linux)\z/) or
 363                         skip "lsof /(deleted)/ check untested on $^O", 1;
 364                 my @lsof = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 365                 my $d = [ grep(/\(deleted\)/, @lsof) ];
 366                 is_deeply($d, [], 'no deleted files') or diag explain($d);
 367         };
 368         SKIP: { test_watch($tmpdir, $host_port, $group) };
 369         {
 370                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 371                 syswrite($s, 'HDR List-id 1-');
 372                 select(undef, undef, undef, 0.15);
 373                 ok($td->kill, 'killed nntpd');
 374                 select(undef, undef, undef, 0.15);
 375                 syswrite($s, "\r\n");
 376                 $buf = '';
 377                 do {
 378                         sysread($s, $buf, 4096, length($buf));
 379                 } until ($buf =~ /\r\n\z/);
 380                 my @r = split("\r\n", $buf);
 381                 like($r[0], qr/^5\d\d /,
 382                         'got 5xx response for unoptimized HDR');
 383                 is(scalar @r, 1, 'only one response line');
 384         }
 385         $n = $s = undef;
 386         $td->join;
 387         is($?, 0, 'no error in exited process');
 388         my $eout = do {
 389                 open my $fh, '<', $err or die "open $err failed: $!";
 390                 local $/;
 391                 <$fh>;
 392         };
 393         unlike($eout, qr/wide/i, 'no Wide character warnings');
 394 }
 395
 396 $td = undef;
 397 done_testing();
 398
 399 sub read_til_dot {
 400         my ($s) = @_;
 401         my $buf = '';
 402         do {
 403                 sysread($s, $buf, 4096, length($buf));
 404         } until ($buf =~ /\r\n\.\r\n\z/);
 405         $buf;
 406 }
 407
 408 sub test_watch {
 409         my ($tmpdir, $host_port, $group) = @_;
 410         use_ok 'PublicInbox::Watch';
 411         use_ok 'PublicInbox::InboxIdle';
 412         use_ok 'PublicInbox::Config';
 413         require_git('1.8.5', 1) or skip('git 1.8.5+ needed for --urlmatch', 4);
 414         my $old_env = { HOME => $ENV{HOME} };
 415         my $home = "$tmpdir/watch_home";
 416         mkdir $home or BAIL_OUT $!;
 417         mkdir "$home/.public-inbox" or BAIL_OUT $!;
 418         local $ENV{HOME} = $home;
 419         my $name = 'watchnntp';
 420         my $addr = "i1\@example.com";
 421         my $url = "http://example.com/i1";
 422         my $inboxdir = "$tmpdir/watchnntp";
 423         my $cmd = ['-init', '-V1', '-Lbasic', $name, $inboxdir, $url, $addr];
 424         my $nntpurl = "nntp://$host_port/$group";
 425         run_script($cmd) or BAIL_OUT("init $name");
 426         xsys(qw(git config), "--file=$home/.public-inbox/config",
 427                         "publicinbox.$name.watch",
 428                         $nntpurl) == 0 or BAIL_OUT "git config $?";
 429         # try again with polling
 430         xsys(qw(git config), "--file=$home/.public-inbox/config",
 431                 'nntp.PollInterval', 0.11) == 0
 432                 or BAIL_OUT "git config $?";
 433         my $cfg = PublicInbox::Config->new;
 434         PublicInbox::DS->Reset;
 435         my $ii = PublicInbox::InboxIdle->new($cfg);
 436         my $cb = sub { PublicInbox::DS->SetPostLoopCallback(sub {}) };
 437         my $obj = bless \$cb, 'PublicInbox::TestCommon::InboxWakeup';
 438         $cfg->each_inbox(sub { $_[0]->subscribe_unlock('ident', $obj) });
 439         my $watcherr = "$tmpdir/watcherr";
 440         open my $err_wr, '>', $watcherr or BAIL_OUT $!;
 441         open my $err, '<', $watcherr or BAIL_OUT $!;
 442         my $w = start_script(['-watch'], undef, { 2 => $err_wr });
 443
 444         diag 'waiting for initial fetch...';
 445         PublicInbox::DS->EventLoop;
 446         diag 'inbox unlocked on initial fetch';
 447         $w->kill;
 448         $w->join;
 449         is($?, 0, 'no error in exited -watch process');
 450         $cfg->each_inbox(sub { shift->unsubscribe_unlock('ident') });
 451         $ii->close;
 452         PublicInbox::DS->Reset;
 453         my @err = grep(!/^(?:I:|#)/, <$err>);
 454         is(@err, 0, 'no warnings/errors from -watch'.join(' ', @err));
 455         my @ls = xqx(['git', "--git-dir=$inboxdir", qw(ls-tree -r HEAD)]);
 456         isnt(scalar(@ls), 0, 'imported something');
 457 }
 458
 459 1;