t/nntpd.t

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Spawn qw(which);
   8 require_mods(qw(DBD::SQLite));
   9 require PublicInbox::InboxWritable;
  10 use PublicInbox::Eml;
  11 use IO::Socket;
  12 use Socket qw(IPPROTO_TCP TCP_NODELAY);
  13 use Net::NNTP;
  14 use Sys::Hostname;
  15 use POSIX qw(_exit);
  16 use Digest::SHA;
  17 use_ok 'PublicInbox::Msgmap';
  18
  19 # t/nntpd-v2.t wraps this for v2
  20 my $version = $ENV{PI_TEST_VERSION} || 1;
  21 require_git('2.6') if $version == 2;
  22 my $lsof = which('lsof');
  23 my $fast_idle = eval { require Linux::Inotify2; 1 } //
  24                 eval { require IO::KQueue; 1 };
  25
  26 my ($tmpdir, $for_destroy) = tmpdir();
  27 my $home = "$tmpdir/pi-home";
  28 my $err = "$tmpdir/stderr.log";
  29 my $out = "$tmpdir/stdout.log";
  30 my $inboxdir = "$tmpdir/main.git";
  31 my $group = 'test-nntpd';
  32 my $addr = $group . '@example.com';
  33
  34 my %opts;
  35 my $sock = tcp_server();
  36 my $td;
  37 my $len;
  38
  39 my $ibx = {
  40         inboxdir => $inboxdir,
  41         name => $group,
  42         version => $version,
  43         -primary_address => $addr,
  44         indexlevel => 'basic',
  45 };
  46 $ibx = PublicInbox::Inbox->new($ibx);
  47 {
  48         local $ENV{HOME} = $home;
  49         my @cmd = ('-init', $group, $inboxdir, 'http://example.com/', $addr,
  50                 "-V$version", '-Lbasic', '--newsgroup', $group);
  51         ok(run_script(\@cmd), 'init OK');
  52
  53         my $len;
  54         $ibx = PublicInbox::InboxWritable->new($ibx);
  55         my $im = $ibx->importer(0);
  56
  57         # ensure successful message delivery
  58         {
  59                 my $mime = PublicInbox::Eml->new(<<EOF);
  60 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  61 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  62 Cc: $addr
  63 Message-Id: <nntp\@example.com>
  64 Content-Type: text/plain; charset=utf-8
  65 Subject: Testing for    =?utf-8?Q?El=C3=A9anor?=
  66 Date: Thu, 01 Jan 1970 06:06:06 +0000
  67 Content-Transfer-Encoding: 8bit
  68 References: <ref        tab     squeezed>
  69
  70 This is a test message for El\xc3\xa9anor
  71 EOF
  72                 my $list_id = $addr;
  73                 $list_id =~ s/@/./;
  74                 $mime->header_set('List-Id', "<$list_id>");
  75                 my $str = $mime->as_string;
  76                 $str =~ s/(?<!\r)\n/\r\n/sg;
  77                 $len = length($str);
  78                 undef $str;
  79                 $im->add($mime);
  80                 $im->done;
  81                 if ($version == 1) {
  82                         ok(run_script(['-index', $ibx->{inboxdir}]),
  83                                 'indexed v1');
  84                 }
  85         }
  86
  87         ok($sock, 'sock created');
  88         my $cmd = [ '-nntpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  89         $td = start_script($cmd, undef, { 3 => $sock });
  90         my $host_port = $sock->sockhost . ':' . $sock->sockport;
  91         my $n = Net::NNTP->new($host_port);
  92         my $list = $n->list;
  93         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
  94         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
  95         is_deeply($n->listgroup($group), [1], 'listgroup OK');
  96         # TODO: Net::NNTP::listgroup does not support range at the moment
  97
  98         {
  99                 my $expect = [ qw(Subject: From: Date: Message-ID:
 100                                 References: Bytes: Lines: Xref:full) ];
 101                 is_deeply($n->overview_fmt, $expect,
 102                         'RFC3977 8.4.2 compliant LIST OVERVIEW.FMT');
 103         }
 104         SKIP: {
 105                 $n->can('starttls') or
 106                         skip('Net::NNTP too old to support STARTTLS', 2);
 107                 require_mods('IO::Socket::SSL', 2);
 108                 ok(!$n->starttls, 'STARTTLS fails when unconfigured');
 109                 is($n->code, 580, 'got 580 code on server w/o TLS');
 110         };
 111
 112         my $mid = '<nntp@example.com>';
 113         my %xhdr = (
 114                 'message-id' => $mid,
 115                 subject => "Testing for El\xc3\xa9anor",
 116                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 117                 'from' => "El\xc3\xa9anor <me\@example.com>",
 118                 'to' => "El\xc3\xa9anor <you\@example.com>",
 119                 'cc' => $addr,
 120                 'xref' => hostname . " $group:1",
 121                 'references' => '<reftabsqueezed>',
 122         );
 123
 124         my $s = tcp_connect($sock);
 125         sysread($s, my $buf, 4096);
 126         is($buf, "201 " . hostname . " ready - post via email\r\n",
 127                 'got greeting');
 128
 129         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 130         ok(syswrite($s, "\r\n"), 'wrote nothing');
 131         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 132         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 133
 134         $s = tcp_connect($sock);
 135         sysread($s, $buf, 4096);
 136         is($buf, "201 " . hostname . " ready - post via email\r\n",
 137                 'got greeting');
 138
 139         syswrite($s, "CAPABILITIES\r\n");
 140         $buf = read_til_dot($s);
 141         like($buf, qr/\r\nVERSION 2\r\n/s, 'CAPABILITIES works');
 142         unlike($buf, qr/STARTTLS/s, 'STARTTLS not advertised');
 143         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 144         if (eval { require Compress::Raw::Zlib }) {
 145                 like($buf, $deflate_capa, 'DEFLATE advertised');
 146         } else {
 147                 unlike($buf, $deflate_capa,
 148                         'DEFLATE not advertised (Compress::Raw::Zlib missing)');
 149         }
 150
 151         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 152         $buf = read_til_dot($s);
 153         like($buf, qr/\A231 list of /, 'newgroups OK');
 154
 155         while (my ($k, $v) = each %xhdr) {
 156                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 157                           "XHDR $k by message-id works");
 158                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 159                           "$k by article number works");
 160                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 161                           "$k by article range works");
 162                 $buf = '';
 163                 syswrite($s, "HDR $k $mid\r\n");
 164                 $buf = read_til_dot($s);
 165                 my @r = split("\r\n", $buf);
 166                 like($r[0], qr/\A225 /, '225 response for HDR');
 167                 is($r[1], "0 $v", 'got expected response for HDR');
 168         }
 169
 170         {
 171                 my $nogroup = Net::NNTP->new($host_port);
 172                 while (my ($k, $v) = each %xhdr) {
 173                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 174                                   "$k by message-id works without group");
 175                 }
 176         }
 177
 178         is_deeply($n->xover('1-'), {
 179                 '1' => ["Testing for El\xc3\xa9anor",
 180                         "El\xc3\xa9anor <me\@example.com>",
 181                         'Thu, 01 Jan 1970 06:06:06 +0000',
 182                         '<nntp@example.com>',
 183                         '<reftabsqueezed>',
 184                         $len,
 185                         '1',
 186                         'Xref: '. hostname . ' test-nntpd:1'] },
 187                 "XOVER range works");
 188
 189         is_deeply($n->xover('1'), {
 190                 '1' => ["Testing for El\xc3\xa9anor",
 191                         "El\xc3\xa9anor <me\@example.com>",
 192                         'Thu, 01 Jan 1970 06:06:06 +0000',
 193                         '<nntp@example.com>',
 194                         '<reftabsqueezed>',
 195                         $len,
 196                         '1',
 197                         'Xref: '. hostname . ' test-nntpd:1'] },
 198                 "XOVER by article works");
 199
 200         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 201         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 202         is_deeply($n->nntpstat(1), '<nntp@example.com>', 'STAT');
 203         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 204                 'body really matches');
 205         my $art = $n->article(1);
 206         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 207         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 208         is($n->article(999), undef, 'non-existent num');
 209         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 210
 211         {
 212                 syswrite($s, "OVER $mid\r\n");
 213                 $buf = read_til_dot($s);
 214                 my @r = split("\r\n", $buf);
 215                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 216                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 217                         "El\xc3\xa9anor <me\@example.com>\t" .
 218                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 219                         "$mid\t<reftabsqueezed>\t$len\t1" .
 220                         "\tXref: " . hostname . " test-nntpd:0",
 221                         'OVER by Message-ID works');
 222                 is($r[2], '.', 'correctly terminated response');
 223         }
 224
 225         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 226                  'XHDR Cc 1- works');
 227         is_deeply($n->xhdr(qw(References 1-)), { 1 => '<reftabsqueezed>' },
 228                  'XHDR References 1- works)');
 229         is_deeply($n->xhdr(qw(list-id 1-)), {},
 230                  'XHDR on invalid header returns empty');
 231
 232         my $mids = $n->newnews(0, '*');
 233         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 234         {
 235                 my $t0 = time;
 236                 my $date = $n->date;
 237                 my $t1 = time;
 238                 ok($date >= $t0, 'valid date after start');
 239                 ok($date <= $t1, 'valid date before stop');
 240         }
 241         if ('leafnode interop') {
 242                 my $for_leafnode = PublicInbox::Eml->new(<<"");
 243 From: longheader\@example.com
 244 To: $addr
 245 Subject: none
 246 Date: Fri, 02 Oct 1993 00:00:00 +0000
 247
 248                 my $long_hdr = 'for-leafnode-'.('y'x200).'@example.com';
 249                 $for_leafnode->header_set('Message-ID', "<$long_hdr>");
 250                 $im->add($for_leafnode);
 251                 $im->done;
 252                 if ($version == 1) {
 253                         ok(run_script(['-index', $ibx->{inboxdir}]),
 254                                 'indexed v1');
 255                 }
 256                 my $hdr = $n->head("<$long_hdr>");
 257                 my $expect = qr/\AMessage-ID: /i . qr/\Q<$long_hdr>\E/;
 258                 ok(scalar(grep(/$expect/, @$hdr)), 'Message-ID not folded');
 259                 ok(scalar(grep(/^Path:/, @$hdr)), 'Path: header found');
 260
 261                 # it's possible for v2 messages to have 2+ Message-IDs,
 262                 # but leafnode can't handle it
 263                 if ($version != 1) {
 264                         my @mids = ("<$long_hdr>", '<2mid@wtf>');
 265                         $for_leafnode->header_set('Message-ID', @mids);
 266                         $for_leafnode->body_set('not-a-dupe');
 267                         my $warn = '';
 268                         local $SIG{__WARN__} = sub { $warn .= join('', @_) };
 269                         $im->add($for_leafnode);
 270                         $im->done;
 271                         like($warn, qr/reused/, 'warned for reused MID');
 272                         $hdr = $n->head('<2mid@wtf>');
 273                         my @hmids = grep(/\AMessage-ID: /i, @$hdr);
 274                         is(scalar(@hmids), 1, 'Single Message-ID in header');
 275                         like($hmids[0], qr/: <2mid\@wtf>/, 'got expected mid');
 276                 }
 277         }
 278
 279         # pipelined requests:
 280         {
 281                 my $nreq = 90;
 282                 my $nart = 2;
 283                 syswrite($s, "GROUP $group\r\n");
 284                 my $res = <$s>;
 285                 my $rdr = fork;
 286                 if ($rdr == 0) {
 287                         for (1..$nreq) {
 288                                 <$s> =~ /\A224 / or _exit(1);
 289                                 <$s> =~ /\A1/ or _exit(2);
 290                                 <$s> eq ".\r\n" or _exit(3);
 291                         }
 292                         my %sums;
 293                         for (1..$nart) {
 294                                 <$s> =~ /\A220 / or _exit(4);
 295                                 my $dig = Digest::SHA->new(1);
 296                                 while (my $l = <$s>) {
 297                                         last if $l eq ".\r\n";
 298                                         $dig->add($l);
 299                                 }
 300                                 $dig = $dig->hexdigest;
 301                                 $sums{$dig}++;
 302                         }
 303                         if ($nart) {
 304                                 scalar(keys(%sums)) == 1 or _exit(5);
 305                                 (values(%sums))[0] == $nart or _exit(6);
 306                         }
 307                         _exit(0);
 308                 }
 309                 for (1..$nreq) {
 310                         syswrite($s, "XOVER 1\r\n");
 311                 }
 312                 syswrite($s, "ARTICLE 1\r\n" x $nart);
 313                 is($rdr, waitpid($rdr, 0), 'reader done');
 314                 is($? >> 8, 0, 'no errors');
 315         }
 316         my $noerr = { 2 => \(my $null) };
 317         SKIP: {
 318                 if ($INC{'Search/Xapian.pm'} && ($ENV{TEST_RUN_MODE}//2)) {
 319                         skip 'Search/Xapian.pm pre-loaded (by t/run.perl?)', 1;
 320                 }
 321                 $lsof or skip 'lsof missing', 1;
 322                 my @of = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 323                 skip('lsof broken', 1) if (!scalar(@of) || $?);
 324                 my @xap = grep m!Search/Xapian!, @of;
 325                 is_deeply(\@xap, [], 'Xapian not loaded in nntpd');
 326         }
 327         # -compact requires Xapian
 328         SKIP: {
 329                 require_mods('Search::Xapian', 2);
 330                 which('xapian-compact') or skip 'xapian-compact missing', 2;
 331                 is(xsys(qw(git config), "--file=$home/.public-inbox/config",
 332                                 "publicinbox.$group.indexlevel", 'medium'),
 333                         0, 'upgraded indexlevel');
 334                 my $ex = eml_load('t/data/0001.patch');
 335                 is($n->article($ex->header('Message-ID')), undef,
 336                         'article did not exist');
 337                 $im->add($ex);
 338                 $im->done;
 339                 {
 340                         my $f = $ibx->mm->{dbh}->sqlite_db_filename;
 341                         my $tmp = "$tmpdir/tmp.sqlite3";
 342                         $ibx->mm->{dbh}->sqlite_backup_to_file($tmp);
 343                         delete $ibx->{mm};
 344                         rename($tmp, $f) or BAIL_OUT "rename($tmp, $f): $!";
 345                 }
 346                 ok(run_script([qw(-index -c -j0 --reindex), $ibx->{inboxdir}],
 347                                 undef, $noerr), '-compacted');
 348                 select(undef, undef, undef, $fast_idle ? 0.1 : 2.1);
 349                 $art = $n->article($ex->header('Message-ID'));
 350                 ok($art, 'new article retrieved after compact');
 351                 $lsof or skip 'lsof missing', 1;
 352                 ($^O =~ /\A(?:linux)\z/) or
 353                         skip "lsof /(deleted)/ check untested on $^O", 1;
 354                 my @of = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 355                 is(scalar(grep(/\(deleted\)/, @of)), 0, 'no deleted files');
 356         };
 357         SKIP: { test_watch($tmpdir, $sock, $group) };
 358         {
 359                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 360                 syswrite($s, 'HDR List-id 1-');
 361                 select(undef, undef, undef, 0.15);
 362                 ok($td->kill, 'killed nntpd');
 363                 select(undef, undef, undef, 0.15);
 364                 syswrite($s, "\r\n");
 365                 $buf = '';
 366                 do {
 367                         sysread($s, $buf, 4096, length($buf));
 368                 } until ($buf =~ /\r\n\z/);
 369                 my @r = split("\r\n", $buf);
 370                 like($r[0], qr/^5\d\d /,
 371                         'got 5xx response for unoptimized HDR');
 372                 is(scalar @r, 1, 'only one response line');
 373         }
 374         $n = $s = undef;
 375         $td->join;
 376         is($?, 0, 'no error in exited process');
 377         my $eout = do {
 378                 open my $fh, '<', $err or die "open $err failed: $!";
 379                 local $/;
 380                 <$fh>;
 381         };
 382         unlike($eout, qr/wide/i, 'no Wide character warnings');
 383 }
 384
 385 $td = undef;
 386 done_testing();
 387
 388 sub read_til_dot {
 389         my ($s) = @_;
 390         my $buf = '';
 391         do {
 392                 sysread($s, $buf, 4096, length($buf));
 393         } until ($buf =~ /\r\n\.\r\n\z/);
 394         $buf;
 395 }
 396
 397 sub test_watch {
 398         my ($tmpdir, $sock, $group) = @_;
 399         use_ok 'PublicInbox::WatchMaildir';
 400         use_ok 'PublicInbox::InboxIdle';
 401         use_ok 'PublicInbox::Config';
 402         require_git('1.8.5', 1) or skip('git 1.8.5+ needed for --urlmatch', 4);
 403         my $old_env = { HOME => $ENV{HOME} };
 404         my $home = "$tmpdir/watch_home";
 405         mkdir $home or BAIL_OUT $!;
 406         mkdir "$home/.public-inbox" or BAIL_OUT $!;
 407         local $ENV{HOME} = $home;
 408         my $name = 'watchnntp';
 409         my $addr = "i1\@example.com";
 410         my $url = "http://example.com/i1";
 411         my $inboxdir = "$tmpdir/watchnntp";
 412         my $cmd = ['-init', '-V1', '-Lbasic', $name, $inboxdir, $url, $addr];
 413         my ($ihost, $iport) = ($sock->sockhost, $sock->sockport);
 414         my $nntpurl = "nntp://$ihost:$iport/$group";
 415         run_script($cmd) or BAIL_OUT("init $name");
 416         xsys(qw(git config), "--file=$home/.public-inbox/config",
 417                         "publicinbox.$name.watch",
 418                         $nntpurl) == 0 or BAIL_OUT "git config $?";
 419         # try again with polling
 420         xsys(qw(git config), "--file=$home/.public-inbox/config",
 421                 'nntp.PollInterval', 0.11) == 0
 422                 or BAIL_OUT "git config $?";
 423         my $cfg = PublicInbox::Config->new;
 424         PublicInbox::DS->Reset;
 425         my $ii = PublicInbox::InboxIdle->new($cfg);
 426         my $cb = sub { PublicInbox::DS->SetPostLoopCallback(sub {}) };
 427         my $obj = bless \$cb, 'PublicInbox::TestCommon::InboxWakeup';
 428         $cfg->each_inbox(sub { $_[0]->subscribe_unlock('ident', $obj) });
 429         my $watcherr = "$tmpdir/watcherr";
 430         open my $err_wr, '>', $watcherr or BAIL_OUT $!;
 431         open my $err, '<', $watcherr or BAIL_OUT $!;
 432         my $w = start_script(['-watch'], undef, { 2 => $err_wr });
 433
 434         diag 'waiting for initial fetch...';
 435         PublicInbox::DS->EventLoop;
 436         diag 'inbox unlocked on initial fetch';
 437         $w->kill;
 438         $w->join;
 439         is($?, 0, 'no error in exited -watch process');
 440         $cfg->each_inbox(sub { shift->unsubscribe_unlock('ident') });
 441         $ii->close;
 442         PublicInbox::DS->Reset;
 443         my @err = grep(!/^I:/, <$err>);
 444         is(@err, 0, 'no warnings/errors from -watch'.join(' ', @err));
 445         my @ls = xqx(['git', "--git-dir=$inboxdir", qw(ls-tree -r HEAD)]);
 446         isnt(scalar(@ls), 0, 'imported something');
 447 }
 448
 449 1;