t/nntpd.t

   1 #!perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict; use v5.10.1; use PublicInbox::TestCommon;
   5 require_mods(qw(DBD::SQLite Net::NNTP));
   6 use PublicInbox::Eml;
   7 use Socket qw(IPPROTO_TCP TCP_NODELAY);
   8 use Sys::Hostname;
   9 use POSIX qw(_exit);
  10 use Digest::SHA;
  11
  12 # t/nntpd-v2.t wraps this for v2
  13 my $version = $ENV{PI_TEST_VERSION} || 1;
  14 require_git('2.6') if $version == 2;
  15 use_ok 'PublicInbox::Msgmap';
  16 my $lsof = require_cmd('lsof', 1);
  17 my $fast_idle = eval { require Linux::Inotify2; 1 } //
  18                 eval { require IO::KQueue; 1 };
  19
  20 my ($tmpdir, $for_destroy) = tmpdir();
  21 my $home = "$tmpdir/pi-home";
  22 my $err = "$tmpdir/stderr.log";
  23 my $out = "$tmpdir/stdout.log";
  24 my $inboxdir = "$tmpdir/inbox";
  25 my $group = 'test-nntpd';
  26 my $addr = $group . '@example.com';
  27 my $sock = tcp_server();
  28 my $host_port = tcp_host_port($sock);
  29 my $td;
  30
  31 my $eml = PublicInbox::Eml->new(<<EOF);
  32 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  33 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  34 Cc: $addr
  35 Message-Id: <nntp\@example.com>
  36 Content-Type: text/plain; charset=utf-8
  37 Subject: Testing for    =?utf-8?Q?El=C3=A9anor?=
  38 Date: Thu, 01 Jan 1970 06:06:06 +0000
  39 Content-Transfer-Encoding: 8bit
  40 References: <ref        tab     squeezed>
  41
  42 This is a test message for El\xc3\xa9anor
  43 EOF
  44 my $list_id = $addr;
  45 $list_id =~ s/@/./;
  46 $eml->header_set('List-Id', "<$list_id>");
  47 my $str = $eml->as_string;
  48 $str =~ s/(?<!\r)\n/\r\n/sg;
  49 my $len = length($str);
  50 undef $str;
  51
  52 my $ibx = create_inbox "v$version", version => $version, indexlevel => 'basic',
  53                         tmpdir => $inboxdir, sub {
  54         my ($im, $ibx) = @_;
  55         $im->add($eml) or BAIL_OUT;
  56 };
  57 undef $eml;
  58 my $other = create_inbox "other$version", version => $version,
  59                 indexlevel => 'basic', sub {
  60         my ($im) = @_;
  61         $im->add(eml_load 't/utf8.eml') or BAIL_OUT;
  62 };
  63
  64 local $ENV{HOME} = $home;
  65 mkdir $home or BAIL_OUT $!;
  66 mkdir "$home/.public-inbox" or BAIL_OUT $!;
  67 open my $cfgfh, '>', "$home/.public-inbox/config" or BAIL_OUT $!;
  68 print $cfgfh <<EOF or BAIL_OUT;
  69 [publicinbox "$group"]
  70         inboxdir = $inboxdir
  71         url = http://example.com/abc
  72         address = $addr
  73         indexlevel = basic
  74         newsgroup = $group
  75 [publicinbox "xyz"]
  76         inboxdir = $other->{inboxdir}
  77         url = http://example.com/xyz
  78         address = e\@example.com
  79         indexlevel = basic
  80         newsgroup = x.y.z
  81 [publicinboxMda]
  82         spamcheck = none
  83 EOF
  84 close $cfgfh or BAIL_OUT;
  85
  86 {
  87         my $cmd = [ '-nntpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  88         $td = start_script($cmd, undef, { 3 => $sock });
  89         my $n = Net::NNTP->new($host_port);
  90         my $list = $n->list;
  91         ok(delete $list->{'x.y.z'}, 'deleted x.y.z group');
  92         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
  93         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
  94         is_deeply($n->listgroup($group), [1], 'listgroup OK');
  95         # TODO: Net::NNTP::listgroup does not support range at the moment
  96
  97         {
  98                 my $expect = [ qw(Subject: From: Date: Message-ID:
  99                                 References: Bytes: Lines: Xref:full) ];
 100                 is_deeply($n->overview_fmt, $expect,
 101                         'RFC3977 8.4.2 compliant LIST OVERVIEW.FMT');
 102         }
 103         SKIP: {
 104                 $n->can('starttls') or
 105                         skip('Net::NNTP too old to support STARTTLS', 2);
 106                 require_mods('IO::Socket::SSL', 2);
 107                 ok(!$n->starttls, 'STARTTLS fails when unconfigured');
 108                 is($n->code, 580, 'got 580 code on server w/o TLS');
 109         };
 110
 111         my $mid = '<nntp@example.com>';
 112         my %xhdr = (
 113                 'message-id' => $mid,
 114                 subject => "Testing for El\xc3\xa9anor",
 115                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 116                 'from' => "El\xc3\xa9anor <me\@example.com>",
 117                 'to' => "El\xc3\xa9anor <you\@example.com>",
 118                 'cc' => $addr,
 119                 'xref' => hostname . " $group:1",
 120                 'references' => '<reftabsqueezed>',
 121         );
 122
 123         my $s = tcp_connect($sock);
 124         sysread($s, my $buf, 4096);
 125         is($buf, "201 " . hostname . " ready - post via email\r\n",
 126                 'got greeting');
 127
 128         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 129         ok(syswrite($s, "\r\n"), 'wrote nothing');
 130         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 131         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 132
 133         $s = tcp_connect($sock);
 134         sysread($s, $buf, 4096);
 135         is($buf, "201 " . hostname . " ready - post via email\r\n",
 136                 'got greeting');
 137
 138         syswrite($s, "CAPABILITIES\r\n");
 139         $buf = read_til_dot($s);
 140         like($buf, qr/\r\nVERSION 2\r\n/s, 'CAPABILITIES works');
 141         unlike($buf, qr/STARTTLS/s, 'STARTTLS not advertised');
 142         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 143         if (eval { require Compress::Raw::Zlib }) {
 144                 like($buf, $deflate_capa, 'DEFLATE advertised');
 145         } else {
 146                 unlike($buf, $deflate_capa,
 147                         'DEFLATE not advertised (Compress::Raw::Zlib missing)');
 148         }
 149
 150         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 151         $buf = read_til_dot($s);
 152         like($buf, qr/\A231 list of /, 'newgroups OK');
 153
 154         while (my ($k, $v) = each %xhdr) {
 155                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 156                           "XHDR $k by message-id works");
 157                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 158                           "$k by article number works");
 159                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 160                           "$k by article range works");
 161                 $buf = '';
 162                 syswrite($s, "HDR $k $mid\r\n");
 163                 $buf = read_til_dot($s);
 164                 my @r = split("\r\n", $buf);
 165                 like($r[0], qr/\A225 /, '225 response for HDR');
 166                 is($r[1], "0 $v", 'got expected response for HDR');
 167         }
 168
 169         {
 170                 my $nogroup = Net::NNTP->new($host_port);
 171                 while (my ($k, $v) = each %xhdr) {
 172                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 173                                   "$k by message-id works without group");
 174                 }
 175         }
 176
 177         is_deeply($n->xover('1-'), {
 178                 '1' => ["Testing for El\xc3\xa9anor",
 179                         "El\xc3\xa9anor <me\@example.com>",
 180                         'Thu, 01 Jan 1970 06:06:06 +0000',
 181                         '<nntp@example.com>',
 182                         '<reftabsqueezed>',
 183                         $len,
 184                         '1',
 185                         'Xref: '. hostname . ' test-nntpd:1'] },
 186                 "XOVER range works");
 187
 188         is_deeply($n->xover('1'), {
 189                 '1' => ["Testing for El\xc3\xa9anor",
 190                         "El\xc3\xa9anor <me\@example.com>",
 191                         'Thu, 01 Jan 1970 06:06:06 +0000',
 192                         '<nntp@example.com>',
 193                         '<reftabsqueezed>',
 194                         $len,
 195                         '1',
 196                         'Xref: '. hostname . ' test-nntpd:1'] },
 197                 "XOVER by article works");
 198
 199         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 200         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 201         is_deeply($n->nntpstat(1), '<nntp@example.com>', 'STAT');
 202         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 203                 'body really matches');
 204         my $art = $n->article(1);
 205         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 206         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 207         is($n->article(999), undef, 'non-existent num');
 208         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 209
 210         {
 211                 syswrite($s, "OVER $mid\r\n");
 212                 $buf = read_til_dot($s);
 213                 my @r = split("\r\n", $buf);
 214                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 215                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 216                         "El\xc3\xa9anor <me\@example.com>\t" .
 217                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 218                         "$mid\t<reftabsqueezed>\t$len\t1" .
 219                         "\tXref: " . hostname . " test-nntpd:0",
 220                         'OVER by Message-ID works');
 221                 is($r[2], '.', 'correctly terminated response');
 222         }
 223
 224         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 225                  'XHDR Cc 1- works');
 226         is_deeply($n->xhdr(qw(References 1-)), { 1 => '<reftabsqueezed>' },
 227                  'XHDR References 1- works)');
 228         is_deeply($n->xhdr(qw(list-id 1-)), {},
 229                  'XHDR on invalid header returns empty');
 230
 231         my $mids = $n->newnews(0, $group);
 232         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 233         {
 234                 my $t0 = time;
 235                 my $date = $n->date;
 236                 my $t1 = time;
 237                 ok($date >= $t0, 'valid date after start');
 238                 ok($date <= $t1, 'valid date before stop');
 239         }
 240         if ('leafnode interop') {
 241                 my $for_leafnode = PublicInbox::Eml->new(<<"");
 242 From: longheader\@example.com
 243 To: $addr
 244 Subject: none
 245 Date: Fri, 02 Oct 1993 00:00:00 +0000
 246
 247                 my $long_hdr = 'for-leafnode-'.('y'x200).'@example.com';
 248                 $for_leafnode->header_set('Message-ID', "<$long_hdr>");
 249                 my $im = $ibx->importer(0);
 250                 $im->add($for_leafnode);
 251                 $im->done;
 252                 my $hdr = $n->head("<$long_hdr>");
 253                 my $expect = qr/\AMessage-ID: /i . qr/\Q<$long_hdr>\E/;
 254                 ok(scalar(grep(/$expect/, @$hdr)), 'Message-ID not folded');
 255                 ok(scalar(grep(/^Path:/, @$hdr)), 'Path: header found');
 256
 257                 # it's possible for v2 messages to have 2+ Message-IDs,
 258                 # but leafnode can't handle it
 259                 if ($version != 1) {
 260                         my @mids = ("<$long_hdr>", '<2mid@wtf>');
 261                         $for_leafnode->header_set('Message-ID', @mids);
 262                         $for_leafnode->body_set('not-a-dupe');
 263                         my $warn = '';
 264                         local $SIG{__WARN__} = sub { $warn .= join('', @_) };
 265                         $im->add($for_leafnode);
 266                         $im->done;
 267                         like($warn, qr/reused/, 'warned for reused MID');
 268                         $hdr = $n->head('<2mid@wtf>');
 269                         my @hmids = grep(/\AMessage-ID: /i, @$hdr);
 270                         is(scalar(@hmids), 1, 'Single Message-ID in header');
 271                         like($hmids[0], qr/: <2mid\@wtf>/, 'got expected mid');
 272                 }
 273         }
 274
 275         ok($n->article('<testmessage@example.com>'),
 276                 'cross newsgroup ARTICLE by Message-ID');
 277         ok($n->body('<testmessage@example.com>'),
 278                 'cross newsgroup BODY by Message-ID');
 279         ok($n->head('<testmessage@example.com>'),
 280                 'cross newsgroup HEAD by Message-ID');
 281         is($n->xpath('<testmessage@example.com>'), 'x.y.z/1', 'xpath hit');
 282         is($n->xpath('<non-existent@example.com>'), undef, 'xpath miss');
 283
 284         # pipelined requests:
 285         {
 286                 my $nreq = 90;
 287                 my $nart = 2;
 288                 syswrite($s, "GROUP $group\r\n");
 289                 my $res = <$s>;
 290                 my $rdr = fork;
 291                 if ($rdr == 0) {
 292                         for (1..$nreq) {
 293                                 <$s> =~ /\A224 / or _exit(1);
 294                                 <$s> =~ /\A1/ or _exit(2);
 295                                 <$s> eq ".\r\n" or _exit(3);
 296                         }
 297                         my %sums;
 298                         for (1..$nart) {
 299                                 <$s> =~ /\A220 / or _exit(4);
 300                                 my $dig = Digest::SHA->new(1);
 301                                 while (my $l = <$s>) {
 302                                         last if $l eq ".\r\n";
 303                                         $dig->add($l);
 304                                 }
 305                                 $dig = $dig->hexdigest;
 306                                 $sums{$dig}++;
 307                         }
 308                         if ($nart) {
 309                                 scalar(keys(%sums)) == 1 or _exit(5);
 310                                 (values(%sums))[0] == $nart or _exit(6);
 311                         }
 312                         _exit(0);
 313                 }
 314                 for (1..$nreq) {
 315                         syswrite($s, "XOVER 1\r\n");
 316                 }
 317                 syswrite($s, "ARTICLE 1\r\n" x $nart);
 318                 is($rdr, waitpid($rdr, 0), 'reader done');
 319                 is($? >> 8, 0, 'no errors');
 320         }
 321         my $noerr = { 2 => \(my $null) };
 322         SKIP: {
 323                 if ($INC{'Search/Xapian.pm'} && ($ENV{TEST_RUN_MODE}//2)) {
 324                         skip 'Search/Xapian.pm pre-loaded (by t/run.perl?)', 1;
 325                 }
 326                 $lsof or skip 'lsof missing', 1;
 327                 my @of = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 328                 skip('lsof broken', 1) if (!scalar(@of) || $?);
 329                 my @xap = grep m!Search/Xapian!, @of;
 330                 is_deeply(\@xap, [], 'Xapian not loaded in nntpd');
 331         }
 332         # -compact requires Xapian
 333         SKIP: {
 334                 require_mods('Search::Xapian', 2);
 335                 have_xapian_compact or skip 'xapian-compact missing', 2;
 336                 is(xsys(qw(git config), "--file=$home/.public-inbox/config",
 337                                 "publicinbox.$group.indexlevel", 'medium'),
 338                         0, 'upgraded indexlevel');
 339                 my $ex = eml_load('t/data/0001.patch');
 340                 is($n->article($ex->header('Message-ID')), undef,
 341                         'article did not exist');
 342                 my $im = $ibx->importer(0);
 343                 $im->add($ex);
 344                 $im->done;
 345                 {
 346                         my $f = $ibx->mm->{dbh}->sqlite_db_filename;
 347                         my $tmp = "$tmpdir/tmp.sqlite3";
 348                         $ibx->mm->{dbh}->sqlite_backup_to_file($tmp);
 349                         delete $ibx->{mm};
 350                         rename($tmp, $f) or BAIL_OUT "rename($tmp, $f): $!";
 351                 }
 352                 ok(run_script([qw(-index -c -j0 --reindex), $ibx->{inboxdir}],
 353                                 undef, $noerr), '-compacted');
 354                 select(undef, undef, undef, $fast_idle ? 0.1 : 2.1);
 355                 $art = $n->article($ex->header('Message-ID'));
 356                 ok($art, 'new article retrieved after compact');
 357                 $lsof or skip 'lsof missing', 1;
 358                 ($^O =~ /\A(?:linux)\z/) or
 359                         skip "lsof /(deleted)/ check untested on $^O", 1;
 360                 my @lsof = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 361                 my $d = [ grep(/\(deleted\)/, @lsof) ];
 362                 is_deeply($d, [], 'no deleted files') or diag explain($d);
 363         };
 364         SKIP: { test_watch($tmpdir, $host_port, $group) };
 365         {
 366                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 367                 syswrite($s, 'HDR List-id 1-');
 368                 select(undef, undef, undef, 0.15);
 369                 ok($td->kill, 'killed nntpd');
 370                 select(undef, undef, undef, 0.15);
 371                 syswrite($s, "\r\n");
 372                 $buf = '';
 373                 do {
 374                         sysread($s, $buf, 4096, length($buf));
 375                 } until ($buf =~ /\r\n\z/);
 376                 my @r = split("\r\n", $buf);
 377                 like($r[0], qr/^5\d\d /,
 378                         'got 5xx response for unoptimized HDR');
 379                 is(scalar @r, 1, 'only one response line');
 380         }
 381         $n = $s = undef;
 382         $td->join;
 383         is($?, 0, 'no error in exited process');
 384         my $eout = do {
 385                 open my $fh, '<', $err or die "open $err failed: $!";
 386                 local $/;
 387                 <$fh>;
 388         };
 389         unlike($eout, qr/wide/i, 'no Wide character warnings');
 390 }
 391
 392 $td = undef;
 393 done_testing();
 394
 395 sub read_til_dot {
 396         my ($s) = @_;
 397         my $buf = '';
 398         do {
 399                 sysread($s, $buf, 4096, length($buf));
 400         } until ($buf =~ /\r\n\.\r\n\z/);
 401         $buf;
 402 }
 403
 404 sub test_watch {
 405         my ($tmpdir, $host_port, $group) = @_;
 406         use_ok 'PublicInbox::Watch';
 407         use_ok 'PublicInbox::InboxIdle';
 408         use_ok 'PublicInbox::Config';
 409         require_git('1.8.5', 1) or skip('git 1.8.5+ needed for --urlmatch', 4);
 410         my $old_env = { HOME => $ENV{HOME} };
 411         my $home = "$tmpdir/watch_home";
 412         mkdir $home or BAIL_OUT $!;
 413         mkdir "$home/.public-inbox" or BAIL_OUT $!;
 414         local $ENV{HOME} = $home;
 415         my $name = 'watchnntp';
 416         my $addr = "i1\@example.com";
 417         my $url = "http://example.com/i1";
 418         my $inboxdir = "$tmpdir/watchnntp";
 419         my $cmd = ['-init', '-V1', '-Lbasic', $name, $inboxdir, $url, $addr];
 420         my $nntpurl = "nntp://$host_port/$group";
 421         run_script($cmd) or BAIL_OUT("init $name");
 422         xsys(qw(git config), "--file=$home/.public-inbox/config",
 423                         "publicinbox.$name.watch",
 424                         $nntpurl) == 0 or BAIL_OUT "git config $?";
 425         # try again with polling
 426         xsys(qw(git config), "--file=$home/.public-inbox/config",
 427                 'nntp.PollInterval', 0.11) == 0
 428                 or BAIL_OUT "git config $?";
 429         my $cfg = PublicInbox::Config->new;
 430         PublicInbox::DS->Reset;
 431         my $ii = PublicInbox::InboxIdle->new($cfg);
 432         my $cb = sub { PublicInbox::DS->SetPostLoopCallback(sub {}) };
 433         my $obj = bless \$cb, 'PublicInbox::TestCommon::InboxWakeup';
 434         $cfg->each_inbox(sub { $_[0]->subscribe_unlock('ident', $obj) });
 435         my $watcherr = "$tmpdir/watcherr";
 436         open my $err_wr, '>', $watcherr or BAIL_OUT $!;
 437         open my $err, '<', $watcherr or BAIL_OUT $!;
 438         my $w = start_script(['-watch'], undef, { 2 => $err_wr });
 439
 440         diag 'waiting for initial fetch...';
 441         PublicInbox::DS::event_loop();
 442         diag 'inbox unlocked on initial fetch';
 443         $w->kill;
 444         $w->join;
 445         is($?, 0, 'no error in exited -watch process');
 446         $cfg->each_inbox(sub { shift->unsubscribe_unlock('ident') });
 447         $ii->close;
 448         PublicInbox::DS->Reset;
 449         my @err = grep(!/^(?:I:|#)/, <$err>);
 450         is(@err, 0, 'no warnings/errors from -watch'.join(' ', @err));
 451         my @ls = xqx(['git', "--git-dir=$inboxdir", qw(ls-tree -r HEAD)]);
 452         isnt(scalar(@ls), 0, 'imported something');
 453 }
 454
 455 1;