t/nntpd.t

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::TestCommon;
   7 use PublicInbox::Spawn qw(which);
   8 require_mods(qw(DBD::SQLite));
   9 require PublicInbox::InboxWritable;
  10 use PublicInbox::Eml;
  11 use IO::Socket;
  12 use Socket qw(IPPROTO_TCP TCP_NODELAY);
  13 use Net::NNTP;
  14 use Sys::Hostname;
  15 use POSIX qw(_exit);
  16 use Digest::SHA;
  17
  18 # FIXME: make easier to test both versions
  19 my $version = $ENV{PI_TEST_VERSION} || 1;
  20 require_git('2.6') if $version == 2;
  21 my $lsof = which('lsof');
  22 my $fast_idle = eval { require Linux::Inotify2; 1 } //
  23                 eval { require IO::KQueue; 1 };
  24
  25 my ($tmpdir, $for_destroy) = tmpdir();
  26 my $home = "$tmpdir/pi-home";
  27 my $err = "$tmpdir/stderr.log";
  28 my $out = "$tmpdir/stdout.log";
  29 my $inboxdir = "$tmpdir/main.git";
  30 my $group = 'test-nntpd';
  31 my $addr = $group . '@example.com';
  32 SKIP: {
  33         skip "git 2.6+ required for V2Writable", 1 if $version == 1;
  34         use_ok 'PublicInbox::V2Writable';
  35 }
  36
  37 my %opts;
  38 my $sock = tcp_server();
  39 my $td;
  40 my $len;
  41
  42 my $ibx = {
  43         inboxdir => $inboxdir,
  44         name => $group,
  45         version => $version,
  46         -primary_address => $addr,
  47         indexlevel => 'basic',
  48 };
  49 $ibx = PublicInbox::Inbox->new($ibx);
  50 {
  51         local $ENV{HOME} = $home;
  52         my @cmd = ('-init', $group, $inboxdir, 'http://example.com/', $addr);
  53         push @cmd, "-V$version", '-Lbasic';
  54         ok(run_script(\@cmd), 'init OK');
  55         is(xsys(qw(git config), "--file=$home/.public-inbox/config",
  56                         "publicinbox.$group.newsgroup", $group),
  57                 0, 'enabled newsgroup');
  58         my $len;
  59
  60         $ibx = PublicInbox::InboxWritable->new($ibx);
  61         my $im = $ibx->importer(0);
  62
  63         # ensure successful message delivery
  64         {
  65                 my $mime = PublicInbox::Eml->new(<<EOF);
  66 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  67 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  68 Cc: $addr
  69 Message-Id: <nntp\@example.com>
  70 Content-Type: text/plain; charset=utf-8
  71 Subject: Testing for    =?utf-8?Q?El=C3=A9anor?=
  72 Date: Thu, 01 Jan 1970 06:06:06 +0000
  73 Content-Transfer-Encoding: 8bit
  74 References: <ref        tab     squeezed>
  75
  76 This is a test message for El\xc3\xa9anor
  77 EOF
  78                 my $list_id = $addr;
  79                 $list_id =~ s/@/./;
  80                 $mime->header_set('List-Id', "<$list_id>");
  81                 my $str = $mime->as_string;
  82                 $str =~ s/(?<!\r)\n/\r\n/sg;
  83                 $len = length($str);
  84                 undef $str;
  85                 $im->add($mime);
  86                 $im->done;
  87                 if ($version == 1) {
  88                         ok(run_script(['-index', $ibx->{inboxdir}]),
  89                                 'indexed v1');
  90                 }
  91         }
  92
  93         ok($sock, 'sock created');
  94         my $cmd = [ '-nntpd', '-W0', "--stdout=$out", "--stderr=$err" ];
  95         $td = start_script($cmd, undef, { 3 => $sock });
  96         my $host_port = $sock->sockhost . ':' . $sock->sockport;
  97         my $n = Net::NNTP->new($host_port);
  98         my $list = $n->list;
  99         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
 100         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
 101         is_deeply($n->listgroup($group), [1], 'listgroup OK');
 102         # TODO: Net::NNTP::listgroup does not support range at the moment
 103
 104         {
 105                 my $expect = [ qw(Subject: From: Date: Message-ID:
 106                                 References: Bytes: Lines: Xref:full) ];
 107                 is_deeply($n->overview_fmt, $expect,
 108                         'RFC3977 8.4.2 compliant LIST OVERVIEW.FMT');
 109         }
 110         SKIP: {
 111                 $n->can('starttls') or
 112                         skip('Net::NNTP too old to support STARTTLS', 2);
 113                 require_mods('IO::Socket::SSL', 2);
 114                 ok(!$n->starttls, 'STARTTLS fails when unconfigured');
 115                 is($n->code, 580, 'got 580 code on server w/o TLS');
 116         };
 117
 118         my $mid = '<nntp@example.com>';
 119         my %xhdr = (
 120                 'message-id' => $mid,
 121                 subject => "Testing for El\xc3\xa9anor",
 122                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 123                 'from' => "El\xc3\xa9anor <me\@example.com>",
 124                 'to' => "El\xc3\xa9anor <you\@example.com>",
 125                 'cc' => $addr,
 126                 'xref' => hostname . " $group:1",
 127                 'references' => '<reftabsqueezed>',
 128         );
 129
 130         my $s = tcp_connect($sock);
 131         sysread($s, my $buf, 4096);
 132         is($buf, "201 " . hostname . " ready - post via email\r\n",
 133                 'got greeting');
 134
 135         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 136         ok(syswrite($s, "\r\n"), 'wrote nothing');
 137         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 138         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 139
 140         $s = tcp_connect($sock);
 141         sysread($s, $buf, 4096);
 142         is($buf, "201 " . hostname . " ready - post via email\r\n",
 143                 'got greeting');
 144
 145         syswrite($s, "CAPABILITIES\r\n");
 146         $buf = read_til_dot($s);
 147         like($buf, qr/\r\nVERSION 2\r\n/s, 'CAPABILITIES works');
 148         unlike($buf, qr/STARTTLS/s, 'STARTTLS not advertised');
 149         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 150         if (eval { require Compress::Raw::Zlib }) {
 151                 like($buf, $deflate_capa, 'DEFLATE advertised');
 152         } else {
 153                 unlike($buf, $deflate_capa,
 154                         'DEFLATE not advertised (Compress::Raw::Zlib missing)');
 155         }
 156
 157         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 158         $buf = read_til_dot($s);
 159         like($buf, qr/\A231 list of /, 'newgroups OK');
 160
 161         while (my ($k, $v) = each %xhdr) {
 162                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 163                           "XHDR $k by message-id works");
 164                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 165                           "$k by article number works");
 166                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 167                           "$k by article range works");
 168                 $buf = '';
 169                 syswrite($s, "HDR $k $mid\r\n");
 170                 $buf = read_til_dot($s);
 171                 my @r = split("\r\n", $buf);
 172                 like($r[0], qr/\A225 /, '225 response for HDR');
 173                 is($r[1], "0 $v", 'got expected response for HDR');
 174         }
 175
 176         {
 177                 my $nogroup = Net::NNTP->new($host_port);
 178                 while (my ($k, $v) = each %xhdr) {
 179                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 180                                   "$k by message-id works without group");
 181                 }
 182         }
 183
 184         is_deeply($n->xover('1-'), {
 185                 '1' => ["Testing for El\xc3\xa9anor",
 186                         "El\xc3\xa9anor <me\@example.com>",
 187                         'Thu, 01 Jan 1970 06:06:06 +0000',
 188                         '<nntp@example.com>',
 189                         '<reftabsqueezed>',
 190                         $len,
 191                         '1',
 192                         'Xref: '. hostname . ' test-nntpd:1'] },
 193                 "XOVER range works");
 194
 195         is_deeply($n->xover('1'), {
 196                 '1' => ["Testing for El\xc3\xa9anor",
 197                         "El\xc3\xa9anor <me\@example.com>",
 198                         'Thu, 01 Jan 1970 06:06:06 +0000',
 199                         '<nntp@example.com>',
 200                         '<reftabsqueezed>',
 201                         $len,
 202                         '1',
 203                         'Xref: '. hostname . ' test-nntpd:1'] },
 204                 "XOVER by article works");
 205
 206         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 207         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 208         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 209                 'body really matches');
 210         my $art = $n->article(1);
 211         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 212         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 213         is($n->article(999), undef, 'non-existent num');
 214         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 215
 216         {
 217                 syswrite($s, "OVER $mid\r\n");
 218                 $buf = read_til_dot($s);
 219                 my @r = split("\r\n", $buf);
 220                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 221                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 222                         "El\xc3\xa9anor <me\@example.com>\t" .
 223                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 224                         "$mid\t<reftabsqueezed>\t$len\t1" .
 225                         "\tXref: " . hostname . " test-nntpd:0",
 226                         'OVER by Message-ID works');
 227                 is($r[2], '.', 'correctly terminated response');
 228         }
 229
 230         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 231                  'XHDR Cc 1- works');
 232         is_deeply($n->xhdr(qw(References 1-)), { 1 => '<reftabsqueezed>' },
 233                  'XHDR References 1- works)');
 234         is_deeply($n->xhdr(qw(list-id 1-)), {},
 235                  'XHDR on invalid header returns empty');
 236
 237         my $mids = $n->newnews(0, '*');
 238         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 239         {
 240                 my $t0 = time;
 241                 my $date = $n->date;
 242                 my $t1 = time;
 243                 ok($date >= $t0, 'valid date after start');
 244                 ok($date <= $t1, 'valid date before stop');
 245         }
 246         if ('leafnode interop') {
 247                 my $for_leafnode = PublicInbox::Eml->new(<<"");
 248 From: longheader\@example.com
 249 To: $addr
 250 Subject: none
 251 Date: Fri, 02 Oct 1993 00:00:00 +0000
 252
 253                 my $long_hdr = 'for-leafnode-'.('y'x200).'@example.com';
 254                 $for_leafnode->header_set('Message-ID', "<$long_hdr>");
 255                 $im->add($for_leafnode);
 256                 $im->done;
 257                 if ($version == 1) {
 258                         ok(run_script(['-index', $ibx->{inboxdir}]),
 259                                 'indexed v1');
 260                 }
 261                 my $hdr = $n->head("<$long_hdr>");
 262                 my $expect = qr/\AMessage-ID: /i . qr/\Q<$long_hdr>\E/;
 263                 ok(scalar(grep(/$expect/, @$hdr)), 'Message-ID not folded');
 264                 ok(scalar(grep(/^Path:/, @$hdr)), 'Path: header found');
 265
 266                 # it's possible for v2 messages to have 2+ Message-IDs,
 267                 # but leafnode can't handle it
 268                 if ($version != 1) {
 269                         my @mids = ("<$long_hdr>", '<2mid@wtf>');
 270                         $for_leafnode->header_set('Message-ID', @mids);
 271                         $for_leafnode->body_set('not-a-dupe');
 272                         my $warn = '';
 273                         local $SIG{__WARN__} = sub { $warn .= join('', @_) };
 274                         $im->add($for_leafnode);
 275                         $im->done;
 276                         like($warn, qr/reused/, 'warned for reused MID');
 277                         $hdr = $n->head('<2mid@wtf>');
 278                         my @hmids = grep(/\AMessage-ID: /i, @$hdr);
 279                         is(scalar(@hmids), 1, 'Single Message-ID in header');
 280                         like($hmids[0], qr/: <2mid\@wtf>/, 'got expected mid');
 281                 }
 282         }
 283
 284         # pipelined requests:
 285         {
 286                 my $nreq = 90;
 287                 my $nart = 2;
 288                 syswrite($s, "GROUP $group\r\n");
 289                 my $res = <$s>;
 290                 my $rdr = fork;
 291                 if ($rdr == 0) {
 292                         for (1..$nreq) {
 293                                 <$s> =~ /\A224 / or _exit(1);
 294                                 <$s> =~ /\A1/ or _exit(2);
 295                                 <$s> eq ".\r\n" or _exit(3);
 296                         }
 297                         my %sums;
 298                         for (1..$nart) {
 299                                 <$s> =~ /\A220 / or _exit(4);
 300                                 my $dig = Digest::SHA->new(1);
 301                                 while (my $l = <$s>) {
 302                                         last if $l eq ".\r\n";
 303                                         $dig->add($l);
 304                                 }
 305                                 $dig = $dig->hexdigest;
 306                                 $sums{$dig}++;
 307                         }
 308                         if ($nart) {
 309                                 scalar(keys(%sums)) == 1 or _exit(5);
 310                                 (values(%sums))[0] == $nart or _exit(6);
 311                         }
 312                         _exit(0);
 313                 }
 314                 for (1..$nreq) {
 315                         syswrite($s, "XOVER 1\r\n");
 316                 }
 317                 syswrite($s, "ARTICLE 1\r\n" x $nart);
 318                 is($rdr, waitpid($rdr, 0), 'reader done');
 319                 is($? >> 8, 0, 'no errors');
 320         }
 321         my $noerr = { 2 => \(my $null) };
 322         SKIP: {
 323                 if ($INC{'Search/Xapian.pm'} && ($ENV{TEST_RUN_MODE}//2)) {
 324                         skip 'Search/Xapian.pm pre-loaded (by t/run.perl?)', 1;
 325                 }
 326                 $lsof or skip 'lsof missing', 1;
 327                 my @of = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 328                 skip('lsof broken', 1) if (!scalar(@of) || $?);
 329                 my @xap = grep m!Search/Xapian!, @of;
 330                 is_deeply(\@xap, [], 'Xapian not loaded in nntpd');
 331         }
 332         # -compact requires Xapian
 333         SKIP: {
 334                 require_mods('Search::Xapian', 2);
 335                 which('xapian-compact') or skip 'xapian-compact missing', 2;
 336                 is(xsys(qw(git config), "--file=$home/.public-inbox/config",
 337                                 "publicinbox.$group.indexlevel", 'medium'),
 338                         0, 'upgraded indexlevel');
 339                 my $ex = eml_load('t/data/0001.patch');
 340                 is($n->article($ex->header('Message-ID')), undef,
 341                         'article did not exist');
 342                 $im->add($ex);
 343                 $im->done;
 344                 ok(run_script([qw(-index --reindex -c), $ibx->{inboxdir}],
 345                                 undef, $noerr), '-compacted');
 346                 select(undef, undef, undef, $fast_idle ? 0.1 : 2.1);
 347                 $art = $n->article($ex->header('Message-ID'));
 348                 ok($art, 'new article retrieved after compact');
 349                 $lsof or skip 'lsof missing', 1;
 350                 ($^O =~ /\A(?:linux)\z/) or
 351                         skip "lsof /(deleted)/ check untested on $^O", 1;
 352                 my @of = xqx([$lsof, '-p', $td->{pid}], undef, $noerr);
 353                 is(scalar(grep(/\(deleted\)/, @of)), 0, 'no deleted files');
 354         };
 355         SKIP: { test_watch($tmpdir, $sock, $group) };
 356         {
 357                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 358                 syswrite($s, 'HDR List-id 1-');
 359                 select(undef, undef, undef, 0.15);
 360                 ok($td->kill, 'killed nntpd');
 361                 select(undef, undef, undef, 0.15);
 362                 syswrite($s, "\r\n");
 363                 $buf = '';
 364                 do {
 365                         sysread($s, $buf, 4096, length($buf));
 366                 } until ($buf =~ /\r\n\z/);
 367                 my @r = split("\r\n", $buf);
 368                 like($r[0], qr/^5\d\d /,
 369                         'got 5xx response for unoptimized HDR');
 370                 is(scalar @r, 1, 'only one response line');
 371         }
 372         $n = $s = undef;
 373         $td->join;
 374         is($?, 0, 'no error in exited process');
 375         my $eout = do {
 376                 open my $fh, '<', $err or die "open $err failed: $!";
 377                 local $/;
 378                 <$fh>;
 379         };
 380         unlike($eout, qr/wide/i, 'no Wide character warnings');
 381 }
 382
 383 $td = undef;
 384 done_testing();
 385
 386 sub read_til_dot {
 387         my ($s) = @_;
 388         my $buf = '';
 389         do {
 390                 sysread($s, $buf, 4096, length($buf));
 391         } until ($buf =~ /\r\n\.\r\n\z/);
 392         $buf;
 393 }
 394
 395 sub test_watch {
 396         my ($tmpdir, $sock, $group) = @_;
 397         use_ok 'PublicInbox::WatchMaildir';
 398         use_ok 'PublicInbox::InboxIdle';
 399         require_git('1.8.5', 1) or skip('git 1.8.5+ needed for --urlmatch', 4);
 400         my $old_env = { HOME => $ENV{HOME} };
 401         my $home = "$tmpdir/watch_home";
 402         mkdir $home or BAIL_OUT $!;
 403         mkdir "$home/.public-inbox" or BAIL_OUT $!;
 404         local $ENV{HOME} = $home;
 405         my $name = 'watchnntp';
 406         my $addr = "i1\@example.com";
 407         my $url = "http://example.com/i1";
 408         my $inboxdir = "$tmpdir/watchnntp";
 409         my $cmd = ['-init', '-V1', '-Lbasic', $name, $inboxdir, $url, $addr];
 410         my ($ihost, $iport) = ($sock->sockhost, $sock->sockport);
 411         my $nntpurl = "nntp://$ihost:$iport/$group";
 412         run_script($cmd) or BAIL_OUT("init $name");
 413         xsys(qw(git config), "--file=$home/.public-inbox/config",
 414                         "publicinbox.$name.watch",
 415                         $nntpurl) == 0 or BAIL_OUT "git config $?";
 416         # try again with polling
 417         xsys(qw(git config), "--file=$home/.public-inbox/config",
 418                 'nntp.PollInterval', 0.11) == 0
 419                 or BAIL_OUT "git config $?";
 420         my $cfg = PublicInbox::Config->new;
 421         PublicInbox::DS->Reset;
 422         my $ii = PublicInbox::InboxIdle->new($cfg);
 423         my $cb = sub { PublicInbox::DS->SetPostLoopCallback(sub {}) };
 424         my $obj = bless \$cb, 'PublicInbox::TestCommon::InboxWakeup';
 425         $cfg->each_inbox(sub { $_[0]->subscribe_unlock('ident', $obj) });
 426         my $watcherr = "$tmpdir/watcherr";
 427         open my $err_wr, '>', $watcherr or BAIL_OUT $!;
 428         open my $err, '<', $watcherr or BAIL_OUT $!;
 429         my $w = start_script(['-watch'], undef, { 2 => $err_wr });
 430
 431         diag 'waiting for initial fetch...';
 432         PublicInbox::DS->EventLoop;
 433         diag 'inbox unlocked on initial fetch';
 434         $w->kill;
 435         $w->join;
 436         is($?, 0, 'no error in exited -watch process');
 437         $cfg->each_inbox(sub { shift->unsubscribe_unlock('ident') });
 438         $ii->close;
 439         PublicInbox::DS->Reset;
 440         my @err = grep(!/^I:/, <$err>);
 441         is(@err, 0, 'no warnings/errors from -watch'.join(' ', @err));
 442         my @ls = xqx(['git', "--git-dir=$inboxdir", qw(ls-tree -r HEAD)]);
 443         isnt(scalar(@ls), 0, 'imported something');
 444 }
 445
 446 1;