t/nntpd.t

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 eval { require PublicInbox::SearchIdx };
   7 plan skip_all => "Xapian missing for nntpd" if $@;
   8 eval { require PublicInbox::Msgmap };
   9 plan skip_all => "DBD::SQLite missing for nntpd" if $@;
  10 use Cwd;
  11 use Email::Simple;
  12 use IO::Socket;
  13 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
  14 use Socket qw(SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
  15 use File::Temp qw/tempdir/;
  16 use Net::NNTP;
  17 use IPC::Run qw(run);
  18 use Data::Dumper;
  19
  20 my $tmpdir = tempdir(CLEANUP => 1);
  21 my $home = "$tmpdir/pi-home";
  22 my $err = "$tmpdir/stderr.log";
  23 my $out = "$tmpdir/stdout.log";
  24 my $pi_home = "$home/.public-inbox";
  25 my $pi_config = "$pi_home/config";
  26 my $maindir = "$tmpdir/main.git";
  27 my $main_bin = getcwd()."/t/main-bin";
  28 my $main_path = "$main_bin:$ENV{PATH}"; # for spamc ham mock
  29 my $group = 'test-nntpd';
  30 my $addr = $group . '@example.com';
  31 my $cfgpfx = "publicinbox.$group";
  32 my $failbox = "$home/fail.mbox";
  33 local $ENV{PI_EMERGENCY} = $failbox;
  34 my $mda = 'blib/script/public-inbox-mda';
  35 my $nntpd = 'blib/script/public-inbox-nntpd';
  36 my $init = 'blib/script/public-inbox-init';
  37 my $index = 'blib/script/public-inbox-index';
  38
  39 my %opts = (
  40         LocalAddr => '127.0.0.1',
  41         ReuseAddr => 1,
  42         Proto => 'tcp',
  43         Type => SOCK_STREAM,
  44         Listen => 1024,
  45 );
  46 my $sock = IO::Socket::INET->new(%opts);
  47 plan skip_all => 'sock fd!=3, cannot test nntpd integration' if fileno($sock) != 3;
  48 my $pid;
  49 END { kill 'TERM', $pid if defined $pid };
  50 {
  51         local $ENV{HOME} = $home;
  52         system($init, $group, $maindir, 'http://example.com/', $addr);
  53
  54         # ensure successful message delivery
  55         {
  56                 local $ENV{ORIGINAL_RECIPIENT} = $addr;
  57                 my $simple = Email::Simple->new(<<EOF);
  58 From: Me <me\@example.com>
  59 To: You <you\@example.com>
  60 Cc: $addr
  61 Message-Id: <nntp\@example.com>
  62 Subject: hihi
  63 Date: Thu, 01 Jan 1970 00:00:00 +0000
  64
  65 nntp
  66 EOF
  67                 my $in = $simple->as_string;
  68                 local $ENV{PATH} = $main_path;
  69                 IPC::Run::run([$mda], \$in);
  70                 is(0, $?, 'ran MDA correctly');
  71                 is(0, system($index, $maindir), 'indexed git dir');
  72         }
  73
  74         ok($sock, 'sock created');
  75         $! = 0;
  76         my $fl = fcntl($sock, F_GETFD, 0);
  77         ok(! $!, 'no error from fcntl(F_GETFD)');
  78         is($fl, FD_CLOEXEC, 'cloexec set by default (Perl behavior)');
  79         $pid = fork;
  80         if ($pid == 0) {
  81                 # pretend to be systemd
  82                 fcntl($sock, F_SETFD, $fl &= ~FD_CLOEXEC);
  83                 $ENV{LISTEN_PID} = $$;
  84                 $ENV{LISTEN_FDS} = 1;
  85                 exec $nntpd, "--stdout=$out", "--stderr=$err";
  86                 die "FAIL: $!\n";
  87         }
  88         ok(defined $pid, 'forked nntpd process successfully');
  89         $! = 0;
  90         ok(! $!, 'no error from fcntl(F_SETFD)');
  91         fcntl($sock, F_SETFD, $fl |= FD_CLOEXEC);
  92         my $n = Net::NNTP->new($sock->sockhost . ':' . $sock->sockport);
  93         my $list = $n->list;
  94         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
  95         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
  96
  97         # TODO: upgrades and such
  98
  99         ok(kill('TERM', $pid), 'killed nntpd');
 100         $pid = undef;
 101         waitpid(-1, 0);
 102 }
 103
 104 done_testing();
 105
 106 1;