t/nntpd.t

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 foreach my $mod (qw(DBD::SQLite)) {
   7         eval "require $mod";
   8         plan skip_all => "$mod missing for nntpd.t" if $@;
   9 }
  10 require PublicInbox::SearchIdx;
  11 require PublicInbox::Msgmap;
  12 require PublicInbox::InboxWritable;
  13 use Email::Simple;
  14 use IO::Socket;
  15 use Socket qw(IPPROTO_TCP TCP_NODELAY);
  16 use File::Temp qw/tempdir/;
  17 use Net::NNTP;
  18 use Sys::Hostname;
  19 require './t/common.perl';
  20
  21 # FIXME: make easier to test both versions
  22 my $version = $ENV{PI_TEST_VERSION} || 2;
  23 require_git('2.6') if $version == 2;
  24
  25 my $tmpdir = tempdir('pi-nntpd-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  26 my $home = "$tmpdir/pi-home";
  27 my $err = "$tmpdir/stderr.log";
  28 my $out = "$tmpdir/stdout.log";
  29 my $mainrepo = "$tmpdir/main.git";
  30 my $group = 'test-nntpd';
  31 my $addr = $group . '@example.com';
  32 my $nntpd = 'blib/script/public-inbox-nntpd';
  33 my $init = 'blib/script/public-inbox-init';
  34 SKIP: {
  35         skip "git 2.6+ required for V2Writable", 1 if $version == 1;
  36         use_ok 'PublicInbox::V2Writable';
  37 }
  38
  39 my %opts;
  40 my $sock = tcp_server();
  41 my $pid;
  42 my $len;
  43 END { kill 'TERM', $pid if defined $pid };
  44
  45 my $ibx = {
  46         mainrepo => $mainrepo,
  47         name => $group,
  48         version => $version,
  49         -primary_address => $addr,
  50         indexlevel => 'basic',
  51 };
  52 $ibx = PublicInbox::Inbox->new($ibx);
  53 {
  54         local $ENV{HOME} = $home;
  55         my @cmd = ($init, $group, $mainrepo, 'http://example.com/', $addr);
  56         push @cmd, "-V$version", '-Lbasic';
  57         is(system(@cmd), 0, 'init OK');
  58         is(system(qw(git config), "--file=$home/.public-inbox/config",
  59                         "publicinbox.$group.newsgroup", $group),
  60                 0, 'enabled newsgroup');
  61         my $len;
  62
  63         $ibx = PublicInbox::InboxWritable->new($ibx);
  64         my $im = $ibx->importer;
  65
  66         # ensure successful message delivery
  67         {
  68                 my $mime = Email::MIME->new(<<EOF);
  69 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  70 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  71 Cc: $addr
  72 Message-Id: <nntp\@example.com>
  73 Content-Type: text/plain; charset=utf-8
  74 Subject: Testing for    =?utf-8?Q?El=C3=A9anor?=
  75 Date: Thu, 01 Jan 1970 06:06:06 +0000
  76 Content-Transfer-Encoding: 8bit
  77 References: <ref        tab     squeezed>
  78
  79 This is a test message for El\xc3\xa9anor
  80 EOF
  81                 my $list_id = $addr;
  82                 $list_id =~ s/@/./;
  83                 $mime->header_set('List-Id', "<$list_id>");
  84                 $len = length($mime->as_string);
  85                 $im->add($mime);
  86                 $im->done;
  87                 if ($version == 1) {
  88                         my $s = PublicInbox::SearchIdx->new($ibx, 1);
  89                         $s->index_sync;
  90                 }
  91         }
  92
  93         ok($sock, 'sock created');
  94         my $cmd = [ $nntpd, "--stdout=$out", "--stderr=$err" ];
  95         $pid = spawn_listener(undef, $cmd, [ $sock ]);
  96         ok(defined $pid, 'forked nntpd process successfully');
  97         my $host_port = $sock->sockhost . ':' . $sock->sockport;
  98         my $n = Net::NNTP->new($host_port);
  99         my $list = $n->list;
 100         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
 101         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
 102         is_deeply($n->listgroup($group), [1], 'listgroup OK');
 103         # TODO: Net::NNTP::listgroup does not support range at the moment
 104
 105         {
 106                 my $expect = [ qw(Subject: From: Date: Message-ID:
 107                                 References: Bytes: Lines: Xref:full) ];
 108                 is_deeply($n->overview_fmt, $expect,
 109                         'RFC3977 8.4.2 compliant LIST OVERVIEW.FMT');
 110         }
 111         SKIP: {
 112                 $n->can('starttls') or
 113                         skip('Net::NNTP too old to support STARTTLS', 2);
 114                 eval {
 115                         require IO::Socket::SSL;
 116                         IO::Socket::SSL->VERSION(2.007);
 117                 } or skip('IO::Socket::SSL <2.007 not supported by Net::NNTP');
 118                 ok(!$n->starttls, 'STARTTLS fails when unconfigured');
 119                 is($n->code, 580, 'got 580 code on server w/o TLS');
 120         };
 121
 122         %opts = (
 123                 PeerAddr => $host_port,
 124                 Proto => 'tcp',
 125                 Type => SOCK_STREAM,
 126                 Timeout => 1,
 127         );
 128         my $mid = '<nntp@example.com>';
 129         my %xhdr = (
 130                 'message-id' => $mid,
 131                 subject => "Testing for El\xc3\xa9anor",
 132                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 133                 'from' => "El\xc3\xa9anor <me\@example.com>",
 134                 'to' => "El\xc3\xa9anor <you\@example.com>",
 135                 'cc' => $addr,
 136                 'xref' => hostname . " $group:1",
 137                 'references' => '<reftabsqueezed>',
 138         );
 139
 140         my $s = IO::Socket::INET->new(%opts);
 141         sysread($s, my $buf, 4096);
 142         is($buf, "201 " . hostname . " ready - post via email\r\n",
 143                 'got greeting');
 144         $s->autoflush(1);
 145
 146         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 147         ok(syswrite($s, "\r\n"), 'wrote nothing');
 148         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 149         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 150
 151         $s = IO::Socket::INET->new(%opts);
 152         sysread($s, $buf, 4096);
 153         is($buf, "201 " . hostname . " ready - post via email\r\n",
 154                 'got greeting');
 155         $s->autoflush(1);
 156
 157         syswrite($s, "CAPABILITIES\r\n");
 158         $buf = read_til_dot($s);
 159         like($buf, qr/\r\nVERSION 2\r\n/s, 'CAPABILITIES works');
 160         unlike($buf, qr/STARTTLS/s, 'STARTTLS not advertised');
 161         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 162         if (eval { require Compress::Raw::Zlib }) {
 163                 like($buf, $deflate_capa, 'DEFLATE advertised');
 164         } else {
 165                 unlike($buf, $deflate_capa,
 166                         'DEFLATE not advertised (Compress::Raw::Zlib missing)');
 167         }
 168
 169         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 170         $buf = read_til_dot($s);
 171         like($buf, qr/\A231 list of /, 'newgroups OK');
 172
 173         while (my ($k, $v) = each %xhdr) {
 174                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 175                           "XHDR $k by message-id works");
 176                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 177                           "$k by article number works");
 178                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 179                           "$k by article range works");
 180                 $buf = '';
 181                 syswrite($s, "HDR $k $mid\r\n");
 182                 $buf = read_til_dot($s);
 183                 my @r = split("\r\n", $buf);
 184                 like($r[0], qr/\A225 /, '225 response for HDR');
 185                 is($r[1], "0 $v", 'got expected response for HDR');
 186         }
 187
 188         {
 189                 my $nogroup = Net::NNTP->new($host_port);
 190                 while (my ($k, $v) = each %xhdr) {
 191                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 192                                   "$k by message-id works without group");
 193                 }
 194         }
 195
 196         is_deeply($n->xover('1-'), {
 197                 '1' => ["Testing for El\xc3\xa9anor",
 198                         "El\xc3\xa9anor <me\@example.com>",
 199                         'Thu, 01 Jan 1970 06:06:06 +0000',
 200                         '<nntp@example.com>',
 201                         '<reftabsqueezed>',
 202                         $len,
 203                         '1',
 204                         'Xref: '. hostname . ' test-nntpd:1'] },
 205                 "XOVER range works");
 206
 207         is_deeply($n->xover('1'), {
 208                 '1' => ["Testing for El\xc3\xa9anor",
 209                         "El\xc3\xa9anor <me\@example.com>",
 210                         'Thu, 01 Jan 1970 06:06:06 +0000',
 211                         '<nntp@example.com>',
 212                         '<reftabsqueezed>',
 213                         $len,
 214                         '1',
 215                         'Xref: '. hostname . ' test-nntpd:1'] },
 216                 "XOVER by article works");
 217
 218         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 219         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 220         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 221                 'body really matches');
 222         my $art = $n->article(1);
 223         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 224         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 225         is($n->article(999), undef, 'non-existent num');
 226         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 227
 228         {
 229                 syswrite($s, "OVER $mid\r\n");
 230                 $buf = read_til_dot($s);
 231                 my @r = split("\r\n", $buf);
 232                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 233                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 234                         "El\xc3\xa9anor <me\@example.com>\t" .
 235                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 236                         "$mid\t<reftabsqueezed>\t$len\t1" .
 237                         "\tXref: " . hostname . " test-nntpd:0",
 238                         'OVER by Message-ID works');
 239                 is($r[2], '.', 'correctly terminated response');
 240         }
 241
 242         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 243                  'XHDR Cc 1- works');
 244         is_deeply($n->xhdr(qw(References 1-)), { 1 => '<reftabsqueezed>' },
 245                  'XHDR References 1- works)');
 246         is_deeply($n->xhdr(qw(list-id 1-)), {},
 247                  'XHDR on invalid header returns empty');
 248
 249         my $mids = $n->newnews(0, '*');
 250         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 251         {
 252                 my $t0 = time;
 253                 my $date = $n->date;
 254                 my $t1 = time;
 255                 ok($date >= $t0, 'valid date after start');
 256                 ok($date <= $t1, 'valid date before stop');
 257         }
 258         if ('leafnode interop') {
 259                 my $for_leafnode = PublicInbox::MIME->new(<<"");
 260 From: longheader\@example.com
 261 To: $addr
 262 Subject: none
 263 Date: Fri, 02 Oct 1993 00:00:00 +0000
 264
 265                 my $long_hdr = 'for-leafnode-'.('y'x200).'@example.com';
 266                 $for_leafnode->header_set('Message-ID', "<$long_hdr>");
 267                 $im->add($for_leafnode);
 268                 $im->done;
 269                 if ($version == 1) {
 270                         my $s = PublicInbox::SearchIdx->new($ibx, 1);
 271                         $s->index_sync;
 272                 }
 273                 my $hdr = $n->head("<$long_hdr>");
 274                 my $expect = qr/\AMessage-ID: /i . qr/\Q<$long_hdr>\E/;
 275                 ok(scalar(grep(/$expect/, @$hdr)), 'Message-ID not folded');
 276                 ok(scalar(grep(/^Path:/, @$hdr)), 'Path: header found');
 277
 278                 # it's possible for v2 messages to have 2+ Message-IDs,
 279                 # but leafnode can't handle it
 280                 if ($version != 1) {
 281                         my @mids = ("<$long_hdr>", '<2mid@wtf>');
 282                         $for_leafnode->header_set('Message-ID', @mids);
 283                         $for_leafnode->body_set('not-a-dupe');
 284                         my $warn = '';
 285                         $SIG{__WARN__} = sub { $warn .= join('', @_) };
 286                         $im->add($for_leafnode);
 287                         $im->done;
 288                         like($warn, qr/reused/, 'warned for reused MID');
 289                         $hdr = $n->head('<2mid@wtf>');
 290                         my @hmids = grep(/\AMessage-ID: /i, @$hdr);
 291                         is(scalar(@hmids), 1, 'Single Message-ID in header');
 292                         like($hmids[0], qr/: <2mid\@wtf>/, 'got expected mid');
 293                 }
 294         }
 295
 296         # pipelined requests:
 297         {
 298                 my $nreq = 90;
 299                 syswrite($s, "GROUP $group\r\n");
 300                 my $res = <$s>;
 301                 my $rdr = fork;
 302                 if ($rdr == 0) {
 303                         use POSIX qw(_exit);
 304                         for (1..$nreq) {
 305                                 <$s> =~ /\A224 / or _exit(1);
 306                                 <$s> =~ /\A1/ or _exit(2);
 307                                 <$s> eq ".\r\n" or _exit(3);
 308                         }
 309                         _exit(0);
 310                 }
 311                 for (1..$nreq) {
 312                         syswrite($s, "XOVER 1\r\n");
 313                 }
 314                 is($rdr, waitpid($rdr, 0), 'reader done');
 315                 is($? >> 8, 0, 'no errors');
 316         }
 317         SKIP: {
 318                 my @of = `lsof -p $pid 2>/dev/null`;
 319                 skip('lsof broken', 1) if (!scalar(@of) || $?);
 320                 my @xap = grep m!Search/Xapian!, @of;
 321                 is_deeply(\@xap, [], 'Xapian not loaded in nntpd');
 322         }
 323         {
 324                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 325                 syswrite($s, 'HDR List-id 1-');
 326                 select(undef, undef, undef, 0.15);
 327                 ok(kill('TERM', $pid), 'killed nntpd');
 328                 select(undef, undef, undef, 0.15);
 329                 syswrite($s, "\r\n");
 330                 $buf = '';
 331                 do {
 332                         sysread($s, $buf, 4096, length($buf));
 333                 } until ($buf =~ /\r\n\z/);
 334                 my @r = split("\r\n", $buf);
 335                 like($r[0], qr/^5\d\d /,
 336                         'got 5xx response for unoptimized HDR');
 337                 is(scalar @r, 1, 'only one response line');
 338         }
 339
 340         $n = $s = undef;
 341         is($pid, waitpid($pid, 0), 'nntpd exited successfully');
 342         my $eout = eval {
 343                 local $/;
 344                 open my $fh, '<', $err or die "open $err failed: $!";
 345                 <$fh>;
 346         };
 347         is($?, 0, 'no error in exited process');
 348         unlike($eout, qr/wide/i, 'no Wide character warnings');
 349 }
 350
 351 done_testing();
 352
 353 sub read_til_dot {
 354         my ($s) = @_;
 355         my $buf = '';
 356         do {
 357                 sysread($s, $buf, 4096, length($buf));
 358         } until ($buf =~ /\r\n\.\r\n\z/);
 359         $buf;
 360 }
 361
 362 1;