t/nntpd.t

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 foreach my $mod (qw(DBD::SQLite)) {
   7         eval "require $mod";
   8         plan skip_all => "$mod missing for nntpd.t" if $@;
   9 }
  10 require PublicInbox::SearchIdx;
  11 require PublicInbox::Msgmap;
  12 require PublicInbox::InboxWritable;
  13 use Email::Simple;
  14 use IO::Socket;
  15 use Socket qw(IPPROTO_TCP TCP_NODELAY);
  16 use File::Temp qw/tempdir/;
  17 use Net::NNTP;
  18 use Sys::Hostname;
  19 require './t/common.perl';
  20
  21 # FIXME: make easier to test both versions
  22 my $version = $ENV{PI_TEST_VERSION} || 2;
  23 require_git('2.6') if $version == 2;
  24
  25 my $tmpdir = tempdir('pi-nntpd-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  26 my $home = "$tmpdir/pi-home";
  27 my $err = "$tmpdir/stderr.log";
  28 my $out = "$tmpdir/stdout.log";
  29 my $mainrepo = "$tmpdir/main.git";
  30 my $group = 'test-nntpd';
  31 my $addr = $group . '@example.com';
  32 my $nntpd = 'blib/script/public-inbox-nntpd';
  33 my $init = 'blib/script/public-inbox-init';
  34 SKIP: {
  35         skip "git 2.6+ required for V2Writable", 1 if $version == 1;
  36         use_ok 'PublicInbox::V2Writable';
  37 }
  38
  39 my %opts = (
  40         LocalAddr => '127.0.0.1',
  41         ReuseAddr => 1,
  42         Proto => 'tcp',
  43         Type => SOCK_STREAM,
  44         Listen => 1024,
  45 );
  46 my $sock = IO::Socket::INET->new(%opts);
  47 my $pid;
  48 my $len;
  49 END { kill 'TERM', $pid if defined $pid };
  50
  51 my $ibx = {
  52         mainrepo => $mainrepo,
  53         name => $group,
  54         version => $version,
  55         -primary_address => $addr,
  56         indexlevel => 'basic',
  57 };
  58 $ibx = PublicInbox::Inbox->new($ibx);
  59 {
  60         local $ENV{HOME} = $home;
  61         my @cmd = ($init, $group, $mainrepo, 'http://example.com/', $addr);
  62         push @cmd, "-V$version", '-Lbasic';
  63         is(system(@cmd), 0, 'init OK');
  64         is(system(qw(git config), "--file=$home/.public-inbox/config",
  65                         "publicinbox.$group.newsgroup", $group),
  66                 0, 'enabled newsgroup');
  67         my $len;
  68
  69         $ibx = PublicInbox::InboxWritable->new($ibx);
  70         my $im = $ibx->importer;
  71
  72         # ensure successful message delivery
  73         {
  74                 my $mime = Email::MIME->new(<<EOF);
  75 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  76 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  77 Cc: $addr
  78 Message-Id: <nntp\@example.com>
  79 Content-Type: text/plain; charset=utf-8
  80 Subject: Testing for    =?utf-8?Q?El=C3=A9anor?=
  81 Date: Thu, 01 Jan 1970 06:06:06 +0000
  82 Content-Transfer-Encoding: 8bit
  83 References: <ref        tab     squeezed>
  84
  85 This is a test message for El\xc3\xa9anor
  86 EOF
  87                 my $list_id = $addr;
  88                 $list_id =~ s/@/./;
  89                 $mime->header_set('List-Id', "<$list_id>");
  90                 $len = length($mime->as_string);
  91                 $im->add($mime);
  92                 $im->done;
  93                 if ($version == 1) {
  94                         my $s = PublicInbox::SearchIdx->new($ibx, 1);
  95                         $s->index_sync;
  96                 }
  97         }
  98
  99         ok($sock, 'sock created');
 100         my $cmd = [ $nntpd, "--stdout=$out", "--stderr=$err" ];
 101         $pid = spawn_listener(undef, $cmd, [ $sock ]);
 102         ok(defined $pid, 'forked nntpd process successfully');
 103         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 104         my $n = Net::NNTP->new($host_port);
 105         my $list = $n->list;
 106         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
 107         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
 108         is_deeply($n->listgroup($group), [1], 'listgroup OK');
 109
 110         SKIP: {
 111                 $n->can('starttls') or
 112                         skip('Net::NNTP too old to support STARTTLS', 2);
 113                 ok(!$n->starttls, 'STARTTLS fails when unconfigured');
 114                 is($n->code, 580, 'got 580 code on server w/o TLS');
 115         };
 116
 117         %opts = (
 118                 PeerAddr => $host_port,
 119                 Proto => 'tcp',
 120                 Type => SOCK_STREAM,
 121                 Timeout => 1,
 122         );
 123         my $mid = '<nntp@example.com>';
 124         my %xhdr = (
 125                 'message-id' => $mid,
 126                 subject => "Testing for El\xc3\xa9anor",
 127                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 128                 'from' => "El\xc3\xa9anor <me\@example.com>",
 129                 'to' => "El\xc3\xa9anor <you\@example.com>",
 130                 'cc' => $addr,
 131                 'xref' => hostname . " $group:1",
 132                 'references' => '<reftabsqueezed>',
 133         );
 134
 135         my $s = IO::Socket::INET->new(%opts);
 136         sysread($s, my $buf, 4096);
 137         is($buf, "201 " . hostname . " ready - post via email\r\n",
 138                 'got greeting');
 139         $s->autoflush(1);
 140
 141         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 142         ok(syswrite($s, "\r\n"), 'wrote nothing');
 143         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 144         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 145
 146         $s = IO::Socket::INET->new(%opts);
 147         sysread($s, $buf, 4096);
 148         is($buf, "201 " . hostname . " ready - post via email\r\n",
 149                 'got greeting');
 150         $s->autoflush(1);
 151
 152         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 153         $buf = read_til_dot($s);
 154         like($buf, qr/\A231 list of /, 'newgroups OK');
 155
 156         while (my ($k, $v) = each %xhdr) {
 157                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 158                           "XHDR $k by message-id works");
 159                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 160                           "$k by article number works");
 161                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 162                           "$k by article range works");
 163                 $buf = '';
 164                 syswrite($s, "HDR $k $mid\r\n");
 165                 $buf = read_til_dot($s);
 166                 my @r = split("\r\n", $buf);
 167                 like($r[0], qr/\A225 /, '225 response for HDR');
 168                 is($r[1], "0 $v", 'got expected response for HDR');
 169         }
 170
 171         {
 172                 my $nogroup = Net::NNTP->new($host_port);
 173                 while (my ($k, $v) = each %xhdr) {
 174                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 175                                   "$k by message-id works without group");
 176                 }
 177         }
 178
 179         is_deeply($n->xover('1-'), {
 180                 '1' => ["Testing for El\xc3\xa9anor",
 181                         "El\xc3\xa9anor <me\@example.com>",
 182                         'Thu, 01 Jan 1970 06:06:06 +0000',
 183                         '<nntp@example.com>',
 184                         '<reftabsqueezed>',
 185                         $len,
 186                         '1',
 187                         'Xref: '. hostname . ' test-nntpd:1'] },
 188                 "XOVER range works");
 189
 190         is_deeply($n->xover('1'), {
 191                 '1' => ["Testing for El\xc3\xa9anor",
 192                         "El\xc3\xa9anor <me\@example.com>",
 193                         'Thu, 01 Jan 1970 06:06:06 +0000',
 194                         '<nntp@example.com>',
 195                         '<reftabsqueezed>',
 196                         $len,
 197                         '1',
 198                         'Xref: '. hostname . ' test-nntpd:1'] },
 199                 "XOVER by article works");
 200
 201         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 202         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 203         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 204                 'body really matches');
 205         my $art = $n->article(1);
 206         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 207         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 208         is($n->article(999), undef, 'non-existent num');
 209         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 210
 211         {
 212                 syswrite($s, "OVER $mid\r\n");
 213                 $buf = read_til_dot($s);
 214                 my @r = split("\r\n", $buf);
 215                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 216                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 217                         "El\xc3\xa9anor <me\@example.com>\t" .
 218                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 219                         "$mid\t<reftabsqueezed>\t$len\t1" .
 220                         "\tXref: " . hostname . " test-nntpd:0",
 221                         'OVER by Message-ID works');
 222                 is($r[2], '.', 'correctly terminated response');
 223         }
 224
 225         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 226                  'XHDR Cc 1- works');
 227         is_deeply($n->xhdr(qw(References 1-)), { 1 => '<reftabsqueezed>' },
 228                  'XHDR References 1- works)');
 229         is_deeply($n->xhdr(qw(list-id 1-)), {},
 230                  'XHDR on invalid header returns empty');
 231
 232         my $mids = $n->newnews(0, '*');
 233         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 234         {
 235                 my $t0 = time;
 236                 my $date = $n->date;
 237                 my $t1 = time;
 238                 ok($date >= $t0, 'valid date after start');
 239                 ok($date <= $t1, 'valid date before stop');
 240         }
 241         if ('leafnode interop') {
 242                 my $for_leafnode = PublicInbox::MIME->new(<<"");
 243 From: longheader\@example.com
 244 To: $addr
 245 Subject: none
 246 Date: Fri, 02 Oct 1993 00:00:00 +0000
 247
 248                 my $long_hdr = 'for-leafnode-'.('y'x200).'@example.com';
 249                 $for_leafnode->header_set('Message-ID', "<$long_hdr>");
 250                 $im->add($for_leafnode);
 251                 $im->done;
 252                 if ($version == 1) {
 253                         my $s = PublicInbox::SearchIdx->new($ibx, 1);
 254                         $s->index_sync;
 255                 }
 256                 my $hdr = $n->head("<$long_hdr>");
 257                 my $expect = qr/\AMessage-ID: /i . qr/\Q<$long_hdr>\E/;
 258                 ok(scalar(grep(/$expect/, @$hdr)), 'Message-ID not folded');
 259                 ok(scalar(grep(/^Path:/, @$hdr)), 'Path: header found');
 260
 261                 # it's possible for v2 messages to have 2+ Message-IDs,
 262                 # but leafnode can't handle it
 263                 if ($version != 1) {
 264                         my @mids = ("<$long_hdr>", '<2mid@wtf>');
 265                         $for_leafnode->header_set('Message-ID', @mids);
 266                         $for_leafnode->body_set('not-a-dupe');
 267                         my $warn = '';
 268                         $SIG{__WARN__} = sub { $warn .= join('', @_) };
 269                         $im->add($for_leafnode);
 270                         $im->done;
 271                         like($warn, qr/reused/, 'warned for reused MID');
 272                         $hdr = $n->head('<2mid@wtf>');
 273                         my @hmids = grep(/\AMessage-ID: /i, @$hdr);
 274                         is(scalar(@hmids), 1, 'Single Message-ID in header');
 275                         like($hmids[0], qr/: <2mid\@wtf>/, 'got expected mid');
 276                 }
 277         }
 278
 279         # pipelined requests:
 280         {
 281                 my $nreq = 90;
 282                 syswrite($s, "GROUP $group\r\n");
 283                 my $res = <$s>;
 284                 my $rdr = fork;
 285                 if ($rdr == 0) {
 286                         use POSIX qw(_exit);
 287                         for (1..$nreq) {
 288                                 <$s> =~ /\A224 / or _exit(1);
 289                                 <$s> =~ /\A1/ or _exit(2);
 290                                 <$s> eq ".\r\n" or _exit(3);
 291                         }
 292                         _exit(0);
 293                 }
 294                 for (1..$nreq) {
 295                         syswrite($s, "XOVER 1\r\n");
 296                 }
 297                 is($rdr, waitpid($rdr, 0), 'reader done');
 298                 is($? >> 8, 0, 'no errors');
 299         }
 300         SKIP: {
 301                 my @of = `lsof -p $pid 2>/dev/null`;
 302                 skip('lsof broken', 1) if (!scalar(@of) || $?);
 303                 my @xap = grep m!Search/Xapian!, @of;
 304                 is_deeply(\@xap, [], 'Xapian not loaded in nntpd');
 305         }
 306         {
 307                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 308                 syswrite($s, 'HDR List-id 1-');
 309                 select(undef, undef, undef, 0.15);
 310                 ok(kill('TERM', $pid), 'killed nntpd');
 311                 select(undef, undef, undef, 0.15);
 312                 syswrite($s, "\r\n");
 313                 $buf = '';
 314                 do {
 315                         sysread($s, $buf, 4096, length($buf));
 316                 } until ($buf =~ /\r\n\z/);
 317                 my @r = split("\r\n", $buf);
 318                 like($r[0], qr/^5\d\d /,
 319                         'got 5xx response for unoptimized HDR');
 320                 is(scalar @r, 1, 'only one response line');
 321         }
 322
 323         $n = $s = undef;
 324         is($pid, waitpid($pid, 0), 'nntpd exited successfully');
 325         my $eout = eval {
 326                 local $/;
 327                 open my $fh, '<', $err or die "open $err failed: $!";
 328                 <$fh>;
 329         };
 330         is($?, 0, 'no error in exited process');
 331         unlike($eout, qr/wide/i, 'no Wide character warnings');
 332 }
 333
 334 done_testing();
 335
 336 sub read_til_dot {
 337         my ($s) = @_;
 338         my $buf = '';
 339         do {
 340                 sysread($s, $buf, 4096, length($buf));
 341         } until ($buf =~ /\r\n\.\r\n\z/);
 342         $buf;
 343 }
 344
 345 1;