t/nntpd.t

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 foreach my $mod (qw(DBD::SQLite Search::Xapian Danga::Socket)) {
   7         eval "require $mod";
   8         plan skip_all => "$mod missing for nntpd.t" if $@;
   9 }
  10 require PublicInbox::SearchIdx;
  11 require PublicInbox::Msgmap;
  12 use Cwd;
  13 use Email::Simple;
  14 use IO::Socket;
  15 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD);
  16 use Socket qw(SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
  17 use File::Temp qw/tempdir/;
  18 use Net::NNTP;
  19
  20 my $tmpdir = tempdir('pi-nntpd-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  21 my $home = "$tmpdir/pi-home";
  22 my $err = "$tmpdir/stderr.log";
  23 my $out = "$tmpdir/stdout.log";
  24 my $maindir = "$tmpdir/main.git";
  25 my $group = 'test-nntpd';
  26 my $addr = $group . '@example.com';
  27 my $cfgpfx = "publicinbox.$group";
  28 my $nntpd = 'blib/script/public-inbox-nntpd';
  29 my $init = 'blib/script/public-inbox-init';
  30 use_ok 'PublicInbox::Import';
  31 use_ok 'PublicInbox::Git';
  32
  33 my %opts = (
  34         LocalAddr => '127.0.0.1',
  35         ReuseAddr => 1,
  36         Proto => 'tcp',
  37         Type => SOCK_STREAM,
  38         Listen => 1024,
  39 );
  40 my $sock = IO::Socket::INET->new(%opts);
  41 my $pid;
  42 my $len;
  43 END { kill 'TERM', $pid if defined $pid };
  44 {
  45         local $ENV{HOME} = $home;
  46         system($init, $group, $maindir, 'http://example.com/', $addr);
  47         my $len;
  48
  49         # ensure successful message delivery
  50         {
  51                 my $mime = Email::MIME->new(<<EOF);
  52 From: Me <me\@example.com>
  53 To: You <you\@example.com>
  54 Cc: $addr
  55 Message-Id: <nntp\@example.com>
  56 Subject: hihi
  57 Date: Thu, 01 Jan 1970 06:06:06 +0000
  58
  59 nntp
  60 EOF
  61                 $mime->header_set('List-Id', "<$addr>");
  62                 $len = length($mime->as_string);
  63                 my $git = PublicInbox::Git->new($maindir);
  64                 my $im = PublicInbox::Import->new($git, 'test', $addr);
  65                 $im->add($mime);
  66                 $im->done;
  67                 my $s = PublicInbox::SearchIdx->new($maindir, 1);
  68                 $s->index_sync;
  69         }
  70
  71         ok($sock, 'sock created');
  72         $! = 0;
  73         my $fl = fcntl($sock, F_GETFD, 0);
  74         ok(! $!, 'no error from fcntl(F_GETFD)');
  75         is($fl, FD_CLOEXEC, 'cloexec set by default (Perl behavior)');
  76         $pid = fork;
  77         if ($pid == 0) {
  78                 use POSIX qw(dup2);
  79                 # pretend to be systemd
  80                 fcntl($sock, F_SETFD, $fl &= ~FD_CLOEXEC);
  81                 dup2(fileno($sock), 3) or die "dup2 failed: $!\n";
  82                 $ENV{LISTEN_PID} = $$;
  83                 $ENV{LISTEN_FDS} = 1;
  84                 exec $nntpd, "--stdout=$out", "--stderr=$err";
  85                 die "FAIL: $!\n";
  86         }
  87         ok(defined $pid, 'forked nntpd process successfully');
  88         $! = 0;
  89         fcntl($sock, F_SETFD, $fl |= FD_CLOEXEC);
  90         ok(! $!, 'no error from fcntl(F_SETFD)');
  91         my $host_port = $sock->sockhost . ':' . $sock->sockport;
  92         my $n = Net::NNTP->new($host_port);
  93         my $list = $n->list;
  94         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
  95         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
  96
  97         %opts = (
  98                 PeerAddr => $host_port,
  99                 Proto => 'tcp',
 100                 Type => SOCK_STREAM,
 101                 Timeout => 1,
 102         );
 103         my $mid = '<nntp@example.com>';
 104         my %xhdr = (
 105                 'message-id' => $mid,
 106                 'subject' => 'hihi',
 107                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 108                 'from' => 'Me <me@example.com>',
 109                 'to' => 'You <you@example.com>',
 110                 'cc' => $addr,
 111                 'xref' => "example.com $group:1"
 112         );
 113
 114         my $s = IO::Socket::INET->new(%opts);
 115         sysread($s, my $buf, 4096);
 116         is($buf, "201 server ready - post via email\r\n", 'got greeting');
 117         $s->autoflush(1);
 118
 119         while (my ($k, $v) = each %xhdr) {
 120                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 121                           "XHDR $k by message-id works");
 122                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 123                           "$k by article number works");
 124                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 125                           "$k by article range works");
 126                 next;
 127                 $buf = '';
 128                 syswrite($s, "HDR $k $mid\r\n");
 129                 do {
 130                         sysread($s, $buf, 4096, length($buf));
 131                 } until ($buf =~ /\r\n\.\r\n\z/);
 132                 my @r = split("\r\n", $buf);
 133                 like($r[0], qr/\A224 /, '224 response for HDR');
 134                 is($r[1], "0 $v", 'got expected response for HDR');
 135         }
 136
 137         {
 138                 my $nogroup = Net::NNTP->new($host_port);
 139                 while (my ($k, $v) = each %xhdr) {
 140                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 141                                   "$k by message-id works without group");
 142                 }
 143         }
 144
 145         is_deeply($n->xover('1-'), {
 146                 '1' => ['hihi',
 147                         'Me <me@example.com>',
 148                         'Thu, 01 Jan 1970 06:06:06 +0000',
 149                         '<nntp@example.com>',
 150                         '',
 151                         $len,
 152                         '1' ] }, "XOVER range works");
 153
 154         is_deeply($n->xover('1'), {
 155                 '1' => ['hihi',
 156                         'Me <me@example.com>',
 157                         'Thu, 01 Jan 1970 06:06:06 +0000',
 158                         '<nntp@example.com>',
 159                         '',
 160                         $len,
 161                         '1' ] }, "XOVER by article works");
 162
 163         {
 164                 syswrite($s, "OVER $mid\r\n");
 165                 $buf = '';
 166                 do {
 167                         sysread($s, $buf, 4096, length($buf));
 168                 } until ($buf =~ /\r\n\.\r\n\z/);
 169                 my @r = split("\r\n", $buf);
 170                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 171                 is($r[1], "0\thihi\tMe <me\@example.com>\t" .
 172                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 173                         "$mid\t\t$len\t1", 'OVER by Message-ID works');
 174                 is($r[2], '.', 'correctly terminated response');
 175         }
 176
 177         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 178                  'XHDR Cc 1- works');
 179         is_deeply($n->xhdr(qw(References 1-)), { 1 => '' },
 180                  'XHDR References 1- works (empty string)');
 181         is_deeply($n->xhdr(qw(list-id 1-)), {},
 182                  'XHDR on invalid header returns empty');
 183
 184         {
 185                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 186                 syswrite($s, 'HDR List-id 1-');
 187                 select(undef, undef, undef, 0.15);
 188                 ok(kill('TERM', $pid), 'killed nntpd');
 189                 select(undef, undef, undef, 0.15);
 190                 syswrite($s, "\r\n");
 191                 $buf = '';
 192                 do {
 193                         sysread($s, $buf, 4096, length($buf));
 194                 } until ($buf =~ /\r\n\z/);
 195                 my @r = split("\r\n", $buf);
 196                 like($r[0], qr/^5\d\d /,
 197                         'got 5xx response for unoptimized HDR');
 198                 is(scalar @r, 1, 'only one response line');
 199         }
 200
 201         is($pid, waitpid($pid, 0), 'nntpd exited successfully');
 202         is($?, 0, 'no error in exited process');
 203 }
 204
 205 done_testing();
 206
 207 1;