t/nntpd.t

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 foreach my $mod (qw(DBD::SQLite)) {
   7         eval "require $mod";
   8         plan skip_all => "$mod missing for nntpd.t" if $@;
   9 }
  10 require PublicInbox::SearchIdx;
  11 require PublicInbox::Msgmap;
  12 require PublicInbox::InboxWritable;
  13 use Email::Simple;
  14 use IO::Socket;
  15 use Socket qw(IPPROTO_TCP TCP_NODELAY);
  16 use File::Temp qw/tempdir/;
  17 use Net::NNTP;
  18 use Sys::Hostname;
  19 require './t/common.perl';
  20
  21 # FIXME: make easier to test both versions
  22 my $version = $ENV{PI_TEST_VERSION} || 2;
  23 require_git('2.6') if $version == 2;
  24
  25 my $tmpdir = tempdir('pi-nntpd-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  26 my $home = "$tmpdir/pi-home";
  27 my $err = "$tmpdir/stderr.log";
  28 my $out = "$tmpdir/stdout.log";
  29 my $mainrepo = "$tmpdir/main.git";
  30 my $group = 'test-nntpd';
  31 my $addr = $group . '@example.com';
  32 my $nntpd = 'blib/script/public-inbox-nntpd';
  33 my $init = 'blib/script/public-inbox-init';
  34 SKIP: {
  35         skip "git 2.6+ required for V2Writable", 1 if $version == 1;
  36         use_ok 'PublicInbox::V2Writable';
  37 }
  38
  39 my %opts;
  40 my $sock = tcp_server();
  41 my $pid;
  42 my $len;
  43 END { kill 'TERM', $pid if defined $pid };
  44
  45 my $ibx = {
  46         mainrepo => $mainrepo,
  47         name => $group,
  48         version => $version,
  49         -primary_address => $addr,
  50         indexlevel => 'basic',
  51 };
  52 $ibx = PublicInbox::Inbox->new($ibx);
  53 {
  54         local $ENV{HOME} = $home;
  55         my @cmd = ($init, $group, $mainrepo, 'http://example.com/', $addr);
  56         push @cmd, "-V$version", '-Lbasic';
  57         is(system(@cmd), 0, 'init OK');
  58         is(system(qw(git config), "--file=$home/.public-inbox/config",
  59                         "publicinbox.$group.newsgroup", $group),
  60                 0, 'enabled newsgroup');
  61         my $len;
  62
  63         $ibx = PublicInbox::InboxWritable->new($ibx);
  64         my $im = $ibx->importer;
  65
  66         # ensure successful message delivery
  67         {
  68                 my $mime = Email::MIME->new(<<EOF);
  69 To: =?utf-8?Q?El=C3=A9anor?= <you\@example.com>
  70 From: =?utf-8?Q?El=C3=A9anor?= <me\@example.com>
  71 Cc: $addr
  72 Message-Id: <nntp\@example.com>
  73 Content-Type: text/plain; charset=utf-8
  74 Subject: Testing for    =?utf-8?Q?El=C3=A9anor?=
  75 Date: Thu, 01 Jan 1970 06:06:06 +0000
  76 Content-Transfer-Encoding: 8bit
  77 References: <ref        tab     squeezed>
  78
  79 This is a test message for El\xc3\xa9anor
  80 EOF
  81                 my $list_id = $addr;
  82                 $list_id =~ s/@/./;
  83                 $mime->header_set('List-Id', "<$list_id>");
  84                 $len = length($mime->as_string);
  85                 $im->add($mime);
  86                 $im->done;
  87                 if ($version == 1) {
  88                         my $s = PublicInbox::SearchIdx->new($ibx, 1);
  89                         $s->index_sync;
  90                 }
  91         }
  92
  93         ok($sock, 'sock created');
  94         my $cmd = [ $nntpd, "--stdout=$out", "--stderr=$err" ];
  95         $pid = spawn_listener(undef, $cmd, [ $sock ]);
  96         ok(defined $pid, 'forked nntpd process successfully');
  97         my $host_port = $sock->sockhost . ':' . $sock->sockport;
  98         my $n = Net::NNTP->new($host_port);
  99         my $list = $n->list;
 100         is_deeply($list, { $group => [ qw(1 1 n) ] }, 'LIST works');
 101         is_deeply([$n->group($group)], [ qw(0 1 1), $group ], 'GROUP works');
 102         is_deeply($n->listgroup($group), [1], 'listgroup OK');
 103
 104         {
 105                 my $expect = [ qw(Subject: From: Date: Message-ID:
 106                                 References: Bytes: Lines: Xref:full) ];
 107                 is_deeply($n->overview_fmt, $expect,
 108                         'RFC3977 8.4.2 compliant LIST OVERVIEW.FMT');
 109         }
 110         SKIP: {
 111                 $n->can('starttls') or
 112                         skip('Net::NNTP too old to support STARTTLS', 2);
 113                 eval {
 114                         require IO::Socket::SSL;
 115                         IO::Socket::SSL->VERSION(2.007);
 116                 } or skip('IO::Socket::SSL <2.007 not supported by Net::NNTP');
 117                 ok(!$n->starttls, 'STARTTLS fails when unconfigured');
 118                 is($n->code, 580, 'got 580 code on server w/o TLS');
 119         };
 120
 121         %opts = (
 122                 PeerAddr => $host_port,
 123                 Proto => 'tcp',
 124                 Type => SOCK_STREAM,
 125                 Timeout => 1,
 126         );
 127         my $mid = '<nntp@example.com>';
 128         my %xhdr = (
 129                 'message-id' => $mid,
 130                 subject => "Testing for El\xc3\xa9anor",
 131                 'date' => 'Thu, 01 Jan 1970 06:06:06 +0000',
 132                 'from' => "El\xc3\xa9anor <me\@example.com>",
 133                 'to' => "El\xc3\xa9anor <you\@example.com>",
 134                 'cc' => $addr,
 135                 'xref' => hostname . " $group:1",
 136                 'references' => '<reftabsqueezed>',
 137         );
 138
 139         my $s = IO::Socket::INET->new(%opts);
 140         sysread($s, my $buf, 4096);
 141         is($buf, "201 " . hostname . " ready - post via email\r\n",
 142                 'got greeting');
 143         $s->autoflush(1);
 144
 145         ok(syswrite($s, "   \r\n"), 'wrote spaces');
 146         ok(syswrite($s, "\r\n"), 'wrote nothing');
 147         syswrite($s, "NEWGROUPS\t19990424 000000 \033GMT\007\r\n");
 148         is(0, sysread($s, $buf, 4096), 'GOT EOF on cntrl');
 149
 150         $s = IO::Socket::INET->new(%opts);
 151         sysread($s, $buf, 4096);
 152         is($buf, "201 " . hostname . " ready - post via email\r\n",
 153                 'got greeting');
 154         $s->autoflush(1);
 155
 156         syswrite($s, "CAPABILITIES\r\n");
 157         $buf = read_til_dot($s);
 158         like($buf, qr/\r\nVERSION 2\r\n/s, 'CAPABILITIES works');
 159         unlike($buf, qr/STARTTLS/s, 'STARTTLS not advertised');
 160         my $deflate_capa = qr/\r\nCOMPRESS DEFLATE\r\n/;
 161         if (eval { require Compress::Raw::Zlib }) {
 162                 like($buf, $deflate_capa, 'DEFLATE advertised');
 163         } else {
 164                 unlike($buf, $deflate_capa,
 165                         'DEFLATE not advertised (Compress::Raw::Zlib missing)');
 166         }
 167
 168         syswrite($s, "NEWGROUPS 19990424 000000 GMT\r\n");
 169         $buf = read_til_dot($s);
 170         like($buf, qr/\A231 list of /, 'newgroups OK');
 171
 172         while (my ($k, $v) = each %xhdr) {
 173                 is_deeply($n->xhdr("$k $mid"), { $mid => $v },
 174                           "XHDR $k by message-id works");
 175                 is_deeply($n->xhdr("$k 1"), { 1 => $v },
 176                           "$k by article number works");
 177                 is_deeply($n->xhdr("$k 1-"), { 1 => $v },
 178                           "$k by article range works");
 179                 $buf = '';
 180                 syswrite($s, "HDR $k $mid\r\n");
 181                 $buf = read_til_dot($s);
 182                 my @r = split("\r\n", $buf);
 183                 like($r[0], qr/\A225 /, '225 response for HDR');
 184                 is($r[1], "0 $v", 'got expected response for HDR');
 185         }
 186
 187         {
 188                 my $nogroup = Net::NNTP->new($host_port);
 189                 while (my ($k, $v) = each %xhdr) {
 190                         is_deeply($nogroup->xhdr("$k $mid"), { $mid => $v },
 191                                   "$k by message-id works without group");
 192                 }
 193         }
 194
 195         is_deeply($n->xover('1-'), {
 196                 '1' => ["Testing for El\xc3\xa9anor",
 197                         "El\xc3\xa9anor <me\@example.com>",
 198                         'Thu, 01 Jan 1970 06:06:06 +0000',
 199                         '<nntp@example.com>',
 200                         '<reftabsqueezed>',
 201                         $len,
 202                         '1',
 203                         'Xref: '. hostname . ' test-nntpd:1'] },
 204                 "XOVER range works");
 205
 206         is_deeply($n->xover('1'), {
 207                 '1' => ["Testing for El\xc3\xa9anor",
 208                         "El\xc3\xa9anor <me\@example.com>",
 209                         'Thu, 01 Jan 1970 06:06:06 +0000',
 210                         '<nntp@example.com>',
 211                         '<reftabsqueezed>',
 212                         $len,
 213                         '1',
 214                         'Xref: '. hostname . ' test-nntpd:1'] },
 215                 "XOVER by article works");
 216
 217         is_deeply($n->head(1), $n->head('<nntp@example.com>'), 'HEAD OK');
 218         is_deeply($n->body(1), $n->body('<nntp@example.com>'), 'BODY OK');
 219         is($n->body(1)->[0], "This is a test message for El\xc3\xa9anor\n",
 220                 'body really matches');
 221         my $art = $n->article(1);
 222         is(ref($art), 'ARRAY', 'got array for ARTICLE');
 223         is_deeply($art, $n->article('<nntp@example.com>'), 'ARTICLE OK');
 224         is($n->article(999), undef, 'non-existent num');
 225         is($n->article('<non-existent@example>'), undef, 'non-existent mid');
 226
 227         {
 228                 syswrite($s, "OVER $mid\r\n");
 229                 $buf = read_til_dot($s);
 230                 my @r = split("\r\n", $buf);
 231                 like($r[0], qr/^224 /, 'got 224 response for OVER');
 232                 is($r[1], "0\tTesting for El\xc3\xa9anor\t" .
 233                         "El\xc3\xa9anor <me\@example.com>\t" .
 234                         "Thu, 01 Jan 1970 06:06:06 +0000\t" .
 235                         "$mid\t<reftabsqueezed>\t$len\t1" .
 236                         "\tXref: " . hostname . " test-nntpd:0",
 237                         'OVER by Message-ID works');
 238                 is($r[2], '.', 'correctly terminated response');
 239         }
 240
 241         is_deeply($n->xhdr(qw(Cc 1-)), { 1 => 'test-nntpd@example.com' },
 242                  'XHDR Cc 1- works');
 243         is_deeply($n->xhdr(qw(References 1-)), { 1 => '<reftabsqueezed>' },
 244                  'XHDR References 1- works)');
 245         is_deeply($n->xhdr(qw(list-id 1-)), {},
 246                  'XHDR on invalid header returns empty');
 247
 248         my $mids = $n->newnews(0, '*');
 249         is_deeply($mids, ['<nntp@example.com>'], 'NEWNEWS works');
 250         {
 251                 my $t0 = time;
 252                 my $date = $n->date;
 253                 my $t1 = time;
 254                 ok($date >= $t0, 'valid date after start');
 255                 ok($date <= $t1, 'valid date before stop');
 256         }
 257         if ('leafnode interop') {
 258                 my $for_leafnode = PublicInbox::MIME->new(<<"");
 259 From: longheader\@example.com
 260 To: $addr
 261 Subject: none
 262 Date: Fri, 02 Oct 1993 00:00:00 +0000
 263
 264                 my $long_hdr = 'for-leafnode-'.('y'x200).'@example.com';
 265                 $for_leafnode->header_set('Message-ID', "<$long_hdr>");
 266                 $im->add($for_leafnode);
 267                 $im->done;
 268                 if ($version == 1) {
 269                         my $s = PublicInbox::SearchIdx->new($ibx, 1);
 270                         $s->index_sync;
 271                 }
 272                 my $hdr = $n->head("<$long_hdr>");
 273                 my $expect = qr/\AMessage-ID: /i . qr/\Q<$long_hdr>\E/;
 274                 ok(scalar(grep(/$expect/, @$hdr)), 'Message-ID not folded');
 275                 ok(scalar(grep(/^Path:/, @$hdr)), 'Path: header found');
 276
 277                 # it's possible for v2 messages to have 2+ Message-IDs,
 278                 # but leafnode can't handle it
 279                 if ($version != 1) {
 280                         my @mids = ("<$long_hdr>", '<2mid@wtf>');
 281                         $for_leafnode->header_set('Message-ID', @mids);
 282                         $for_leafnode->body_set('not-a-dupe');
 283                         my $warn = '';
 284                         $SIG{__WARN__} = sub { $warn .= join('', @_) };
 285                         $im->add($for_leafnode);
 286                         $im->done;
 287                         like($warn, qr/reused/, 'warned for reused MID');
 288                         $hdr = $n->head('<2mid@wtf>');
 289                         my @hmids = grep(/\AMessage-ID: /i, @$hdr);
 290                         is(scalar(@hmids), 1, 'Single Message-ID in header');
 291                         like($hmids[0], qr/: <2mid\@wtf>/, 'got expected mid');
 292                 }
 293         }
 294
 295         # pipelined requests:
 296         {
 297                 my $nreq = 90;
 298                 syswrite($s, "GROUP $group\r\n");
 299                 my $res = <$s>;
 300                 my $rdr = fork;
 301                 if ($rdr == 0) {
 302                         use POSIX qw(_exit);
 303                         for (1..$nreq) {
 304                                 <$s> =~ /\A224 / or _exit(1);
 305                                 <$s> =~ /\A1/ or _exit(2);
 306                                 <$s> eq ".\r\n" or _exit(3);
 307                         }
 308                         _exit(0);
 309                 }
 310                 for (1..$nreq) {
 311                         syswrite($s, "XOVER 1\r\n");
 312                 }
 313                 is($rdr, waitpid($rdr, 0), 'reader done');
 314                 is($? >> 8, 0, 'no errors');
 315         }
 316         SKIP: {
 317                 my @of = `lsof -p $pid 2>/dev/null`;
 318                 skip('lsof broken', 1) if (!scalar(@of) || $?);
 319                 my @xap = grep m!Search/Xapian!, @of;
 320                 is_deeply(\@xap, [], 'Xapian not loaded in nntpd');
 321         }
 322         {
 323                 setsockopt($s, IPPROTO_TCP, TCP_NODELAY, 1);
 324                 syswrite($s, 'HDR List-id 1-');
 325                 select(undef, undef, undef, 0.15);
 326                 ok(kill('TERM', $pid), 'killed nntpd');
 327                 select(undef, undef, undef, 0.15);
 328                 syswrite($s, "\r\n");
 329                 $buf = '';
 330                 do {
 331                         sysread($s, $buf, 4096, length($buf));
 332                 } until ($buf =~ /\r\n\z/);
 333                 my @r = split("\r\n", $buf);
 334                 like($r[0], qr/^5\d\d /,
 335                         'got 5xx response for unoptimized HDR');
 336                 is(scalar @r, 1, 'only one response line');
 337         }
 338
 339         $n = $s = undef;
 340         is($pid, waitpid($pid, 0), 'nntpd exited successfully');
 341         my $eout = eval {
 342                 local $/;
 343                 open my $fh, '<', $err or die "open $err failed: $!";
 344                 <$fh>;
 345         };
 346         is($?, 0, 'no error in exited process');
 347         unlike($eout, qr/wide/i, 'no Wide character warnings');
 348 }
 349
 350 done_testing();
 351
 352 sub read_til_dot {
 353         my ($s) = @_;
 354         my $buf = '';
 355         do {
 356                 sysread($s, $buf, 4096, length($buf));
 357         } until ($buf =~ /\r\n\.\r\n\z/);
 358         $buf;
 359 }
 360
 361 1;