t/plack.t

   1 #!perl -w
   2 # Copyright (C) 2014-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 my $psgi = "./examples/public-inbox.psgi";
   8 my @mods = qw(HTTP::Request::Common Plack::Test URI::Escape);
   9 require_mods(@mods);
  10 foreach my $mod (@mods) { use_ok $mod; }
  11 ok(-f $psgi, "psgi example file found");
  12 my ($tmpdir, $for_destroy) = tmpdir();
  13 my $pfx = 'http://example.com/test';
  14 my $eml = eml_load('t/iso-2202-jp.eml');
  15 # ensure successful message deliveries
  16 my $ibx = create_inbox('test-1', sub {
  17         my ($im, $ibx) = @_;
  18         my $addr = $ibx->{-primary_address};
  19         $im->add($eml) or xbail '->add';
  20         $eml->header_set('Content-Type',
  21                 "text/plain; charset=\rso\rb\0gus\rithurts");
  22         $eml->header_set('Message-ID', '<broken@example.com>');
  23         $im->add($eml) or xbail '->add';
  24         $im->add(PublicInbox::Eml->new(<<EOF)) or xbail '->add';
  25 From: Me <me\@example.com>
  26 To: You <you\@example.com>
  27 Cc: $addr
  28 Message-Id: <blah\@example.com>
  29 Subject: hihi
  30 Date: Fri, 02 Oct 1993 00:00:00 +0000
  31 Content-Type: text/plain; charset=iso-8859-1
  32
  33 > quoted text
  34 zzzzzz
  35 EOF
  36         # multipart with two text bodies
  37         $im->add(eml_load('t/plack-2-txt-bodies.eml')) or BAIL_OUT '->add';
  38
  39         # multipart with attached patch + filename
  40         $im->add(eml_load('t/plack-attached-patch.eml')) or BAIL_OUT '->add';
  41
  42         # multipart collapsed to single quoted-printable text/plain
  43         $im->add(eml_load('t/plack-qp.eml')) or BAIL_OUT '->add';
  44         my $crlf = <<EOF;
  45 From: Me
  46   <me\@example.com>
  47 To: $addr
  48 Message-Id: <crlf\@example.com>
  49 Subject: carriage
  50   return
  51   in
  52   long
  53   subject
  54 Date: Fri, 02 Oct 1993 00:00:00 +0000
  55
  56 :(
  57 EOF
  58         $crlf =~ s/\n/\r\n/sg;
  59         $im->add(PublicInbox::Eml->new($crlf)) or BAIL_OUT '->add';
  60
  61         open my $fh, '>', "$ibx->{inboxdir}/description" or BAIL_OUT "open: $!";
  62         print $fh "test for public-inbox\n" or BAIL_OUT;
  63         close $fh or BAIL_OUT "close: $!";
  64         open $fh, '>', "$ibx->{inboxdir}/pi_config";
  65         print $fh <<EOF or BAIL_OUT;
  66 [publicinbox "test"]
  67         inboxdir = $ibx->{inboxdir}
  68         newsgroup = inbox.test
  69         address = $addr
  70         url = $pfx/
  71 EOF
  72         close $fh or BAIL_OUT "close: $!";
  73 });
  74
  75 my $env = { PI_CONFIG => "$ibx->{inboxdir}/pi_config", TMPDIR => $tmpdir };
  76 local @ENV{keys %$env} = values %$env;
  77 my $c1 = sub {
  78         my ($cb) = @_;
  79         my $uri = $ENV{PLACK_TEST_EXTERNALSERVER_URI} // 'http://example.com';
  80         $pfx = "$uri/test";
  81
  82         foreach my $u (qw(robots.txt favicon.ico .well-known/foo)) {
  83                 my $res = $cb->(GET("$uri/$u"));
  84                 is($res->code, 404, "$u is missing");
  85         }
  86
  87         my $res = $cb->(GET("$uri/test/crlf\@example.com/"));
  88         is($res->code, 200, 'retrieved CRLF as HTML');
  89         like($res->content, qr/mailto:me\@example/, 'no %40, per RFC 6068');
  90         unlike($res->content, qr/\r/, 'no CR in HTML');
  91         $res = $cb->(GET("$uri/test/crlf\@example.com/raw"));
  92         is($res->code, 200, 'retrieved CRLF raw');
  93         like($res->content, qr/\r/, 'CR preserved in raw message');
  94         $res = $cb->(GET("$uri/test/bogus\@example.com/raw"));
  95         is($res->code, 404, 'missing /raw is 404');
  96
  97         # redirect with newsgroup
  98         my $from = "$uri/inbox.test";
  99         my $to = "http://example.com/test/";
 100         $res = $cb->(GET($from));
 101         is($res->code, 301, 'newsgroup name is permanent redirect');
 102         is($to, $res->header('Location'), 'redirect location matches');
 103         $from .= '/';
 104         is($res->code, 301, 'newsgroup name/ is permanent redirect');
 105         is($to, $res->header('Location'), 'redirect location matches');
 106
 107         # redirect with trailing /
 108         $from = "$uri/test";
 109         $to = "$from/";
 110         $res = $cb->(GET($from));
 111         is(301, $res->code, 'is permanent redirect');
 112         is($to, $res->header('Location'),
 113                 'redirect location matches with trailing slash');
 114
 115         for my $t (qw(T t)) {
 116                 my $u = $pfx . "/blah\@example.com/$t";
 117                 $res = $cb->(GET($u));
 118                 is(301, $res->code, "redirect for missing /");
 119                 my $location = $res->header('Location');
 120                 like($location, qr!/\Q$t\E/#u\z!,
 121                         'redirected with missing /');
 122         }
 123
 124         for my $t (qw(f)) { # legacy redirect
 125                 my $u = $pfx . "/blah\@example.com/$t";
 126                 $res = $cb->(GET($u));
 127                 is(301, $res->code, "redirect for legacy /f");
 128                 my $location = $res->header('Location');
 129                 like($location, qr!/blah\@example\.com/\z!,
 130                         'redirected with missing /');
 131         }
 132
 133         my $atomurl = "$uri/test/new.atom";
 134         $res = $cb->(GET("$uri/test/new.html"));
 135         is(200, $res->code, 'success response received');
 136         like($res->content, qr!href="new\.atom"!,
 137                 'atom URL generated');
 138         like($res->content, qr!href="blah\@example\.com/"!,
 139                 'index generated');
 140         like($res->content, qr!1993-10-02!, 'date set');
 141
 142         $res = $cb->(GET($pfx . '/atom.xml'));
 143         is(200, $res->code, 'success response received for atom');
 144         my $body = $res->content;
 145         like($body, qr!link\s+href="\Q$pfx\E/blah\@example\.com/"!s,
 146                 'atom feed generated correct URL');
 147         like($body, qr/<title>test for public-inbox/,
 148                 "set title in XML feed");
 149         like($body, qr/zzzzzz/, 'body included');
 150         $res = $cb->(GET($pfx . '/description'));
 151         like($res->content, qr/test for public-inbox/, 'got description');
 152
 153         my $path = '/blah@example.com/';
 154         $res = $cb->(GET($pfx . $path));
 155         is(200, $res->code, "success for $path");
 156         my $html = $res->content;
 157         like($html, qr!<title>hihi - Me</title>!, 'HTML returned');
 158         like($html, qr!<a\nhref=raw!s, 'raw link present');
 159         like($html, qr!&gt; quoted text!s, 'quoted text inline');
 160
 161         $path .= 'f/';
 162         $res = $cb->(GET($pfx . $path));
 163         is(301, $res->code, "redirect for $path");
 164         my $location = $res->header('Location');
 165         like($location, qr!/blah\@example\.com/\z!,
 166                 '/$MESSAGE_ID/f/ redirected to /$MESSAGE_ID/');
 167
 168         $res = $cb->(GET($pfx . '/multipart@example.com/'));
 169         like($res->content,
 170                 qr/hi\n.*-- Attachment #2.*\nbye\n/s, 'multipart split');
 171
 172         $res = $cb->(GET($pfx . '/patch@example.com/'));
 173         $html = $res->content;
 174         like($html, qr!see attached!, 'original body');
 175         like($html, qr!.*Attachment #2: foo&(?:amp|#38);\.patch --!,
 176                 'parts split with filename');
 177
 178         $res = $cb->(GET($pfx . '/qp@example.com/'));
 179         like($res->content, qr/\bhi = bye\b/, "HTML output decoded QP");
 180
 181
 182         $res = $cb->(GET($pfx . '/blah@example.com/raw'));
 183         is(200, $res->code, 'success response received for /*/raw');
 184         like($res->content, qr!^From !sm, "mbox returned");
 185         is($res->header('Content-Type'), 'text/plain; charset=iso-8859-1',
 186                 'charset from message used');
 187
 188         $res = $cb->(GET($pfx . '/broken@example.com/raw'));
 189         is($res->header('Content-Type'), 'text/plain; charset=UTF-8',
 190                 'broken charset ignored');
 191
 192         $res = $cb->(GET($pfx . '/199707281508.AAA24167@hoyogw.example/raw'));
 193         is($res->header('Content-Type'), 'text/plain; charset=ISO-2022-JP',
 194                 'ISO-2002-JP returned');
 195         chomp($body = $res->content);
 196         my $raw = PublicInbox::Eml->new(\$body);
 197         is($raw->body_raw, $eml->body_raw, 'ISO-2022-JP body unmodified');
 198
 199         $res = $cb->(GET($pfx . '/blah@example.com/t.mbox.gz'));
 200         is(501, $res->code, '501 when overview missing');
 201         like($res->content, qr!\bOverview\b!, 'overview omission noted');
 202
 203         # legacy redirects
 204         for my $t (qw(m f)) {
 205                 $res = $cb->(GET($pfx . "/$t/blah\@example.com.txt"));
 206                 is(301, $res->code, "redirect for old $t .txt link");
 207                 $location = $res->header('Location');
 208                 like($location, qr!/blah\@example\.com/raw\z!,
 209                         ".txt redirected to /raw");
 210         }
 211
 212         my %umap = (
 213                 'm' => '',
 214                 'f' => '',
 215                 't' => 't/',
 216         );
 217         while (my ($t, $e) = each %umap) {
 218                 $res = $cb->(GET($pfx . "/$t/blah\@example.com.html"));
 219                 is(301, $res->code, "redirect for old $t .html link");
 220                 $location = $res->header('Location');
 221                 like($location, qr!/blah\@example\.com/$e(?:#u)?\z!,
 222                                 ".html redirected to new location");
 223         }
 224
 225         for my $sfx (qw(mbox mbox.gz)) {
 226                 $res = $cb->(GET($pfx . "/t/blah\@example.com.$sfx"));
 227                 is(301, $res->code, 'redirect for old thread link');
 228                 $location = $res->header('Location');
 229                 like($location,
 230                      qr!/blah\@example\.com/t\.mbox(?:\.gz)?\z!,
 231                      "$sfx redirected to /mbox.gz");
 232         }
 233
 234         # for a while, we used to support /$INBOX/$X40/
 235         # when we "compressed" long Message-IDs to SHA-1
 236         # Now we're stuck supporting them forever :<
 237         for my $path ('f2912279bd7bcd8b7ab3033234942d58746d56f7') {
 238                 $from = "$uri/test/$path/";
 239                 $res = $cb->(GET($from));
 240                 is(301, $res->code, 'is permanent redirect');
 241                 like($res->header('Location'),
 242                         qr!/test/blah\@example\.com/!,
 243                         'redirect from x40 MIDs works');
 244         }
 245
 246
 247         # dumb HTTP clone/fetch support
 248         $path = '/test/info/refs';
 249         my $req = HTTP::Request->new('GET' => $path);
 250         $res = $cb->($req);
 251         is(200, $res->code, 'refs readable');
 252         my $orig = $res->content;
 253
 254         $req->header('Range', 'bytes=5-10');
 255         $res = $cb->($req);
 256         is(206, $res->code, 'got partial response');
 257         is($res->content, substr($orig, 5, 6), 'partial body OK');
 258
 259         $req->header('Range', 'bytes=5-');
 260         $res = $cb->($req);
 261         is(206, $res->code, 'got partial another response');
 262         is($res->content, substr($orig, 5), 'partial body OK past end');
 263
 264
 265         # things which should fail
 266         $res = $cb->(PUT('/'));
 267         is(405, $res->code, 'no PUT to / allowed');
 268         $res = $cb->(PUT('/test/'));
 269         is(405, $res->code, 'no PUT /$INBOX allowed');
 270 };
 271 test_psgi(require $psgi, $c1);
 272 test_httpd($env, $c1);
 273 done_testing;