t/plack.t

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Email::MIME;
   7 use PublicInbox::TestCommon;
   8 my $psgi = "./examples/public-inbox.psgi";
   9 my ($tmpdir, $for_destroy) = tmpdir();
  10 my $pi_config = "$tmpdir/config";
  11 my $inboxdir = "$tmpdir/main.git";
  12 my $addr = 'test-public@example.com';
  13 my @mods = qw(HTTP::Request::Common Plack::Test URI::Escape);
  14 require_mods(@mods);
  15 use_ok 'PublicInbox::Import';
  16 use_ok 'PublicInbox::Git';
  17 my @ls;
  18
  19 foreach my $mod (@mods) { use_ok $mod; }
  20 local $ENV{PI_CONFIG} = $pi_config;
  21 ok(-f $psgi, "psgi example file found");
  22 my $pfx = 'http://example.com/test';
  23 ok(run_script(['-init', 'test', $inboxdir, "$pfx/", $addr]),
  24         'initialized repo');
  25 PublicInbox::Import::run_die([qw(git config -f), $pi_config,
  26         'publicinbox.test.newsgroup', 'inbox.test']);
  27 open my $fh, '>', "$inboxdir/description" or die "open: $!\n";
  28 print $fh "test for public-inbox\n";
  29 close $fh or die "close: $!\n";
  30 my $app = require $psgi;
  31 my $git = PublicInbox::Git->new($inboxdir);
  32 my $im = PublicInbox::Import->new($git, 'test', $addr);
  33 # ensure successful message delivery
  34 {
  35         my $mime = Email::MIME->new(<<EOF);
  36 From: Me <me\@example.com>
  37 To: You <you\@example.com>
  38 Cc: $addr
  39 Message-Id: <blah\@example.com>
  40 Subject: hihi
  41 Date: Fri, 02 Oct 1993 00:00:00 +0000
  42
  43 > quoted text
  44 zzzzzz
  45 EOF
  46         $im->add($mime);
  47         $im->done;
  48         my $rev = $git->qx(qw(rev-list HEAD));
  49         like($rev, qr/\A[a-f0-9]{40}/, "good revision committed");
  50         @ls = $git->qx(qw(ls-tree -r --name-only HEAD));
  51         chomp @ls;
  52
  53         # multipart with two text bodies
  54         my %attr_text = (attributes => { content_type => 'text/plain' });
  55         my $parts = [
  56                 Email::MIME->create(%attr_text, body => 'hi'),
  57                 Email::MIME->create(%attr_text, body => 'bye')
  58         ];
  59         $mime = Email::MIME->create(
  60                 header_str => [
  61                         From => 'a@example.com',
  62                         Subject => 'blargh',
  63                         'Message-ID' => '<multipart@example.com>',
  64                         'In-Reply-To' => '<irp@example.com>'
  65                 ],
  66                 parts => $parts,
  67         );
  68         $im->add($mime);
  69
  70         # multipart with attached patch + filename
  71         $parts = [ Email::MIME->create(%attr_text, body => 'hi, see attached'),
  72                 Email::MIME->create(
  73                         attributes => {
  74                                         content_type => 'text/plain',
  75                                         filename => "foo&.patch",
  76                         },
  77                         body => "--- a/file\n+++ b/file\n" .
  78                                 "@@ -49, 7 +49,34 @@\n"
  79                         )
  80         ];
  81         $mime = Email::MIME->create(
  82                 header_str => [
  83                         From => 'a@example.com',
  84                         Subject => '[PATCH] asdf',
  85                         'Message-ID' => '<patch@example.com>'
  86                 ],
  87                 parts => $parts
  88         );
  89         $im->add($mime);
  90
  91         # multipart collapsed to single quoted-printable text/plain
  92         $parts = [
  93                 Email::MIME->create(
  94                         attributes => {
  95                                 content_type => 'text/plain',
  96                                 encoding => 'quoted-printable'
  97                         },
  98                         body => 'hi = bye',
  99                 )
 100         ];
 101         $mime = Email::MIME->create(
 102                 header_str => [
 103                         From => 'qp@example.com',
 104                         Subject => 'QP',
 105                         'Message-ID' => '<qp@example.com>',
 106                         ],
 107                 parts => $parts,
 108         );
 109         like($mime->body_raw, qr/hi =3D bye=/, 'our test used QP correctly');
 110         $im->add($mime);
 111
 112         $im->done;
 113 }
 114
 115 test_psgi($app, sub {
 116         my ($cb) = @_;
 117         foreach my $u (qw(robots.txt favicon.ico .well-known/foo)) {
 118                 my $res = $cb->(GET("http://example.com/$u"));
 119                 is($res->code, 404, "$u is missing");
 120         }
 121 });
 122
 123 # redirect with newsgroup
 124 test_psgi($app, sub {
 125         my ($cb) = @_;
 126         my $from = 'http://example.com/inbox.test';
 127         my $to = 'http://example.com/test/';
 128         my $res = $cb->(GET($from));
 129         is($res->code, 301, 'newsgroup name is permanent redirect');
 130         is($to, $res->header('Location'), 'redirect location matches');
 131         $from .= '/';
 132         is($res->code, 301, 'newsgroup name/ is permanent redirect');
 133         is($to, $res->header('Location'), 'redirect location matches');
 134 });
 135
 136 # redirect with trailing /
 137 test_psgi($app, sub {
 138         my ($cb) = @_;
 139         my $from = 'http://example.com/test';
 140         my $to = "$from/";
 141         my $res = $cb->(GET($from));
 142         is(301, $res->code, 'is permanent redirect');
 143         is($to, $res->header('Location'),
 144                 'redirect location matches with trailing slash');
 145 });
 146
 147 foreach my $t (qw(t T)) {
 148         test_psgi($app, sub {
 149                 my ($cb) = @_;
 150                 my $u = $pfx . "/blah\@example.com/$t";
 151                 my $res = $cb->(GET($u));
 152                 is(301, $res->code, "redirect for missing /");
 153                 my $location = $res->header('Location');
 154                 like($location, qr!/\Q$t\E/#u\z!,
 155                         'redirected with missing /');
 156         });
 157 }
 158 foreach my $t (qw(f)) {
 159         test_psgi($app, sub {
 160                 my ($cb) = @_;
 161                 my $u = $pfx . "/blah\@example.com/$t";
 162                 my $res = $cb->(GET($u));
 163                 is(301, $res->code, "redirect for legacy /f");
 164                 my $location = $res->header('Location');
 165                 like($location, qr!/blah\@example\.com/\z!,
 166                         'redirected with missing /');
 167         });
 168 }
 169
 170 test_psgi($app, sub {
 171         my ($cb) = @_;
 172         my $atomurl = 'http://example.com/test/new.atom';
 173         my $res = $cb->(GET('http://example.com/test/new.html'));
 174         is(200, $res->code, 'success response received');
 175         like($res->content, qr!href="new\.atom"!,
 176                 'atom URL generated');
 177         like($res->content, qr!href="blah\@example\.com/"!,
 178                 'index generated');
 179         like($res->content, qr!1993-10-02!, 'date set');
 180 });
 181
 182 test_psgi($app, sub {
 183         my ($cb) = @_;
 184         my $res = $cb->(GET($pfx . '/atom.xml'));
 185         is(200, $res->code, 'success response received for atom');
 186         my $body = $res->content;
 187         like($body, qr!link\s+href="\Q$pfx\E/blah\@example\.com/"!s,
 188                 'atom feed generated correct URL');
 189         like($body, qr/<title>test for public-inbox/,
 190                 "set title in XML feed");
 191         like($body, qr/zzzzzz/, 'body included');
 192         $res = $cb->(GET($pfx . '/description'));
 193         like($res->content, qr/test for public-inbox/, 'got description');
 194 });
 195
 196 test_psgi($app, sub {
 197         my ($cb) = @_;
 198         my $path = '/blah@example.com/';
 199         my $res = $cb->(GET($pfx . $path));
 200         is(200, $res->code, "success for $path");
 201         my $html = $res->content;
 202         like($html, qr!<title>hihi - Me</title>!, 'HTML returned');
 203         like($html, qr!<a\nhref="raw"!s, 'raw link present');
 204         like($html, qr!&gt; quoted text!s, 'quoted text inline');
 205
 206         $path .= 'f/';
 207         $res = $cb->(GET($pfx . $path));
 208         is(301, $res->code, "redirect for $path");
 209         my $location = $res->header('Location');
 210         like($location, qr!/blah\@example\.com/\z!,
 211                 '/$MESSAGE_ID/f/ redirected to /$MESSAGE_ID/');
 212
 213         $res = $cb->(GET($pfx . '/multipart@example.com/'));
 214         like($res->content,
 215                 qr/hi\n.*-- Attachment #2.*\nbye\n/s, 'multipart split');
 216
 217         $res = $cb->(GET($pfx . '/patch@example.com/'));
 218         $html = $res->content;
 219         like($html, qr!see attached!, 'original body');
 220         like($html, qr!.*Attachment #2: foo&(?:amp|#38);\.patch --!,
 221                 'parts split with filename');
 222
 223         $res = $cb->(GET($pfx . '/qp@example.com/'));
 224         like($res->content, qr/\bhi = bye\b/, "HTML output decoded QP");
 225 });
 226
 227 test_psgi($app, sub {
 228         my ($cb) = @_;
 229         my $res = $cb->(GET($pfx . '/blah@example.com/raw'));
 230         is(200, $res->code, 'success response received for /*/raw');
 231         like($res->content, qr!^From !sm, "mbox returned");
 232 });
 233
 234 # legacy redirects
 235 foreach my $t (qw(m f)) {
 236         test_psgi($app, sub {
 237                 my ($cb) = @_;
 238                 my $res = $cb->(GET($pfx . "/$t/blah\@example.com.txt"));
 239                 is(301, $res->code, "redirect for old $t .txt link");
 240                 my $location = $res->header('Location');
 241                 like($location, qr!/blah\@example\.com/raw\z!,
 242                         ".txt redirected to /raw");
 243         });
 244 }
 245
 246 my %umap = (
 247         'm' => '',
 248         'f' => '',
 249         't' => 't/',
 250 );
 251 while (my ($t, $e) = each %umap) {
 252         test_psgi($app, sub {
 253                 my ($cb) = @_;
 254                 my $res = $cb->(GET($pfx . "/$t/blah\@example.com.html"));
 255                 is(301, $res->code, "redirect for old $t .html link");
 256                 my $location = $res->header('Location');
 257                 like($location,
 258                         qr!/blah\@example\.com/$e(?:#u)?\z!,
 259                         ".html redirected to new location");
 260         });
 261 }
 262 foreach my $sfx (qw(mbox mbox.gz)) {
 263         test_psgi($app, sub {
 264                 my ($cb) = @_;
 265                 my $res = $cb->(GET($pfx . "/t/blah\@example.com.$sfx"));
 266                 is(301, $res->code, 'redirect for old thread link');
 267                 my $location = $res->header('Location');
 268                 like($location,
 269                      qr!/blah\@example\.com/t\.mbox(?:\.gz)?\z!,
 270                      "$sfx redirected to /mbox.gz");
 271         });
 272 }
 273 test_psgi($app, sub {
 274         my ($cb) = @_;
 275         # for a while, we used to support /$INBOX/$X40/
 276         # when we "compressed" long Message-IDs to SHA-1
 277         # Now we're stuck supporting them forever :<
 278         foreach my $path (@ls) {
 279                 $path =~ tr!/!!d;
 280                 my $from = "http://example.com/test/$path/";
 281                 my $res = $cb->(GET($from));
 282                 is(301, $res->code, 'is permanent redirect');
 283                 like($res->header('Location'),
 284                         qr!/test/blah\@example\.com/!,
 285                         'redirect from x40 MIDs works');
 286         }
 287 });
 288
 289 # dumb HTTP clone/fetch support
 290 test_psgi($app, sub {
 291         my ($cb) = @_;
 292         my $path = '/test/info/refs';
 293         my $req = HTTP::Request->new('GET' => $path);
 294         my $res = $cb->($req);
 295         is(200, $res->code, 'refs readable');
 296         my $orig = $res->content;
 297
 298         $req->header('Range', 'bytes=5-10');
 299         $res = $cb->($req);
 300         is(206, $res->code, 'got partial response');
 301         is($res->content, substr($orig, 5, 6), 'partial body OK');
 302
 303         $req->header('Range', 'bytes=5-');
 304         $res = $cb->($req);
 305         is(206, $res->code, 'got partial another response');
 306         is($res->content, substr($orig, 5), 'partial body OK past end');
 307 });
 308
 309 # things which should fail
 310 test_psgi($app, sub {
 311         my ($cb) = @_;
 312
 313         my $res = $cb->(PUT('/'));
 314         is(405, $res->code, 'no PUT to / allowed');
 315         $res = $cb->(PUT('/test/'));
 316         is(405, $res->code, 'no PUT /$INBOX allowed');
 317
 318         # TODO
 319         # $res = $cb->(GET('/'));
 320 });
 321
 322 done_testing();