t/plack.t

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Email::MIME;
   7 use File::Temp qw/tempdir/;
   8 my $psgi = "./examples/public-inbox.psgi";
   9 my $tmpdir = tempdir('pi-plack-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  10 my $pi_config = "$tmpdir/config";
  11 my $maindir = "$tmpdir/main.git";
  12 my $addr = 'test-public@example.com';
  13 my $cfgpfx = "publicinbox.test";
  14 my @mods = qw(HTTP::Request::Common Plack::Test URI::Escape);
  15 foreach my $mod (@mods) {
  16         eval "require $mod";
  17         plan skip_all => "$mod missing for plack.t" if $@;
  18 }
  19 use_ok 'PublicInbox::Import';
  20 use_ok 'PublicInbox::Git';
  21 my @ls;
  22
  23 foreach my $mod (@mods) { use_ok $mod; }
  24 {
  25         ok(-f $psgi, "psgi example file found");
  26         is(0, system(qw(git init -q --bare), $maindir), "git init (main)");
  27         open my $fh, '>', "$maindir/description" or die "open: $!\n";
  28         print $fh "test for public-inbox\n";
  29         close $fh or die "close: $!\n";
  30         my %cfg = (
  31                 "$cfgpfx.address" => $addr,
  32                 "$cfgpfx.mainrepo" => $maindir,
  33                 "$cfgpfx.url" => 'http://example.com/test/',
  34                 "$cfgpfx.newsgroup" => 'inbox.test',
  35         );
  36         while (my ($k,$v) = each %cfg) {
  37                 is(0, system(qw(git config --file), $pi_config, $k, $v),
  38                         "setup $k");
  39         }
  40
  41         # ensure successful message delivery
  42         {
  43                 my $mime = Email::MIME->new(<<EOF);
  44 From: Me <me\@example.com>
  45 To: You <you\@example.com>
  46 Cc: $addr
  47 Message-Id: <blah\@example.com>
  48 Subject: hihi
  49 Date: Thu, 01 Jan 1970 00:00:00 +0000
  50
  51 zzzzzz
  52 EOF
  53                 my $git = PublicInbox::Git->new($maindir);
  54                 my $im = PublicInbox::Import->new($git, 'test', $addr);
  55                 $im->add($mime);
  56                 $im->done;
  57                 my $rev = `git --git-dir="$maindir" rev-list HEAD`;
  58                 like($rev, qr/\A[a-f0-9]{40}/, "good revision committed");
  59                 @ls = `git --git-dir="$maindir" ls-tree -r --name-only HEAD`;
  60                 chomp @ls;
  61         }
  62         my $app = eval {
  63                 local $ENV{PI_CONFIG} = $pi_config;
  64                 require $psgi;
  65         };
  66
  67         test_psgi($app, sub {
  68                 my ($cb) = @_;
  69                 foreach my $u (qw(robots.txt favicon.ico .well-known/foo)) {
  70                         my $res = $cb->(GET("http://example.com/$u"));
  71                         is($res->code, 404, "$u is missing");
  72                 }
  73         });
  74
  75         # redirect with newsgroup
  76         test_psgi($app, sub {
  77                 my ($cb) = @_;
  78                 my $from = 'http://example.com/inbox.test';
  79                 my $to = 'http://example.com/test/';
  80                 my $res = $cb->(GET($from));
  81                 is($res->code, 301, 'newsgroup name is permanent redirect');
  82                 is($to, $res->header('Location'), 'redirect location matches');
  83                 $from .= '/';
  84                 is($res->code, 301, 'newsgroup name/ is permanent redirect');
  85                 is($to, $res->header('Location'), 'redirect location matches');
  86         });
  87
  88         # redirect with trailing /
  89         test_psgi($app, sub {
  90                 my ($cb) = @_;
  91                 my $from = 'http://example.com/test';
  92                 my $to = "$from/";
  93                 my $res = $cb->(GET($from));
  94                 is(301, $res->code, 'is permanent redirect');
  95                 is($to, $res->header('Location'),
  96                         'redirect location matches with trailing slash');
  97         });
  98
  99         my $pfx = 'http://example.com/test';
 100         foreach my $t (qw(t T)) {
 101                 test_psgi($app, sub {
 102                         my ($cb) = @_;
 103                         my $u = $pfx . "/blah\@example.com/$t";
 104                         my $res = $cb->(GET($u));
 105                         is(301, $res->code, "redirect for missing /");
 106                         my $location = $res->header('Location');
 107                         like($location, qr!/\Q$t\E/#u\z!,
 108                                 'redirected with missing /');
 109                 });
 110         }
 111         foreach my $t (qw(f)) {
 112                 test_psgi($app, sub {
 113                         my ($cb) = @_;
 114                         my $u = $pfx . "/blah\@example.com/$t";
 115                         my $res = $cb->(GET($u));
 116                         is(301, $res->code, "redirect for legacy /f");
 117                         my $location = $res->header('Location');
 118                         like($location, qr!/blah\@example\.com/\z!,
 119                                 'redirected with missing /');
 120                 });
 121         }
 122
 123         test_psgi($app, sub {
 124                 my ($cb) = @_;
 125                 my $atomurl = 'http://example.com/test/new.atom';
 126                 my $res = $cb->(GET('http://example.com/test/new.html'));
 127                 is(200, $res->code, 'success response received');
 128                 like($res->content, qr!href="new\.atom"!,
 129                         'atom URL generated');
 130                 like($res->content, qr!href="blah\@example\.com/"!,
 131                         'index generated');
 132         });
 133
 134         test_psgi($app, sub {
 135                 my ($cb) = @_;
 136                 my $res = $cb->(GET($pfx . '/atom.xml'));
 137                 is(200, $res->code, 'success response received for atom');
 138                 like($res->content,
 139                         qr!link\s+href="\Q$pfx\E/blah\@example\.com/"!s,
 140                         'atom feed generated correct URL');
 141         });
 142
 143         test_psgi($app, sub {
 144                 my ($cb) = @_;
 145                 my $path = '/blah@example.com/';
 146                 my $res = $cb->(GET($pfx . $path));
 147                 is(200, $res->code, "success for $path");
 148                 like($res->content, qr!<title>hihi - Me</title>!,
 149                         "HTML returned");
 150
 151                 $path .= 'f/';
 152                 $res = $cb->(GET($pfx . $path));
 153                 is(301, $res->code, "redirect for $path");
 154                 my $location = $res->header('Location');
 155                 like($location, qr!/blah\@example\.com/\z!,
 156                         '/$MESSAGE_ID/f/ redirected to /$MESSAGE_ID/');
 157         });
 158
 159         test_psgi($app, sub {
 160                 my ($cb) = @_;
 161                 my $res = $cb->(GET($pfx . '/blah@example.com/raw'));
 162                 is(200, $res->code, 'success response received for /*/raw');
 163                 like($res->content, qr!^From !sm, "mbox returned");
 164         });
 165
 166         # legacy redirects
 167         foreach my $t (qw(m f)) {
 168                 test_psgi($app, sub {
 169                         my ($cb) = @_;
 170                         my $res = $cb->(GET($pfx . "/$t/blah\@example.com.txt"));
 171                         is(301, $res->code, "redirect for old $t .txt link");
 172                         my $location = $res->header('Location');
 173                         like($location, qr!/blah\@example\.com/raw\z!,
 174                                 ".txt redirected to /raw");
 175                 });
 176         }
 177
 178         my %umap = (
 179                 'm' => '',
 180                 'f' => '',
 181                 't' => 't/',
 182         );
 183         while (my ($t, $e) = each %umap) {
 184                 test_psgi($app, sub {
 185                         my ($cb) = @_;
 186                         my $res = $cb->(GET($pfx . "/$t/blah\@example.com.html"));
 187                         is(301, $res->code, "redirect for old $t .html link");
 188                         my $location = $res->header('Location');
 189                         like($location,
 190                                 qr!/blah\@example\.com/$e(?:#u)?\z!,
 191                                 ".html redirected to new location");
 192                 });
 193         }
 194         foreach my $sfx (qw(mbox mbox.gz)) {
 195                 test_psgi($app, sub {
 196                         my ($cb) = @_;
 197                         my $res = $cb->(GET($pfx . "/t/blah\@example.com.$sfx"));
 198                         is(301, $res->code, 'redirect for old thread link');
 199                         my $location = $res->header('Location');
 200                         like($location,
 201                              qr!/blah\@example\.com/t\.mbox(?:\.gz)?\z!,
 202                              "$sfx redirected to /mbox.gz");
 203                 });
 204         }
 205         test_psgi($app, sub {
 206                 my ($cb) = @_;
 207                 # for a while, we used to support /$INBOX/$X40/
 208                 # when we "compressed" long Message-IDs to SHA-1
 209                 # Now we're stuck supporting them forever :<
 210                 foreach my $path (@ls) {
 211                         $path =~ tr!/!!d;
 212                         my $from = "http://example.com/test/$path/";
 213                         my $res = $cb->(GET($from));
 214                         is(301, $res->code, 'is permanent redirect');
 215                         like($res->header('Location'),
 216                                 qr!/test/blah\@example\.com/!,
 217                                 'redirect from x40 MIDs works');
 218                 }
 219         });
 220 }
 221
 222 done_testing();