t/psgi_search.t

   1 # Copyright (C) 2017-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use File::Temp qw/tempdir/;
   7 use Email::MIME;
   8 use PublicInbox::Config;
   9 use PublicInbox::WWW;
  10 my @mods = qw(PublicInbox::SearchIdx HTTP::Request::Common Plack::Test
  11                 URI::Escape Plack::Builder);
  12 foreach my $mod (@mods) {
  13         eval "require $mod";
  14         plan skip_all => "$mod missing for psgi_search.t" if $@;
  15 }
  16 use_ok $_ foreach @mods;
  17 my $tmpdir = tempdir('pi-psgi-search.XXXXXX', TMPDIR => 1, CLEANUP => 1);
  18 my $git_dir = "$tmpdir/a.git";
  19
  20 is(0, system(qw(git init -q --bare), $git_dir), "git init (main)");
  21 my $rw = PublicInbox::SearchIdx->new($git_dir, 1);
  22 ok($rw, "search indexer created");
  23 my $digits = '10010260936330';
  24 my $ua = 'Pine.LNX.4.10';
  25 my $mid = "$ua.$digits.2460-100000\@penguin.transmeta.com";
  26 my $data = <<"EOF";
  27 Subject: test
  28 Message-ID: <$mid>
  29 From: Ævar Arnfjörð Bjarmason <avarab\@example>
  30 To: git\@vger.kernel.org
  31
  32 EOF
  33
  34 my $num = 0;
  35 # nb. using internal API, fragile!
  36 $rw->begin_txn_lazy;
  37
  38 foreach (reverse split(/\n\n/, $data)) {
  39         $_ .= "\n";
  40         my $mime = Email::MIME->new(\$_);
  41         my $bytes = bytes::length($mime->as_string);
  42         my $doc_id = $rw->add_message($mime, $bytes, ++$num, 'ignored');
  43         ok($doc_id, 'message added');
  44 }
  45
  46 $rw->commit_txn_lazy;
  47
  48 my $cfgpfx = "publicinbox.test";
  49 my $config = PublicInbox::Config->new({
  50         "$cfgpfx.address" => 'git@vger.kernel.org',
  51         "$cfgpfx.mainrepo" => $git_dir,
  52 });
  53 my $www = PublicInbox::WWW->new($config);
  54 test_psgi(sub { $www->call(@_) }, sub {
  55         my ($cb) = @_;
  56         my $res;
  57         $res = $cb->(GET('/test/?q=%C3%86var'));
  58         my $html = $res->content;
  59         like($html, qr/<title>&#198;var - /, 'HTML escaped in title');
  60         my @res = ($html =~ m/\?q=(.+var)\b/g);
  61         ok(scalar(@res), 'saw query strings');
  62         my %uniq = map { $_ => 1 } @res;
  63         is(1, scalar keys %uniq, 'all query values identical in HTML');
  64         is('%C3%86var', (keys %uniq)[0], 'matches original query');
  65         ok(index($html, 'by &#198;var Arnfj&#246;r&#240; Bjarmason') >= 0,
  66                 "displayed Ævar's name properly in HTML");
  67
  68         my $warn = [];
  69         local $SIG{__WARN__} = sub { push @$warn, @_ };
  70         $res = $cb->(GET('/test/?q=s:test&l=5e'));
  71         is($res->code, 200, 'successful search result');
  72         is_deeply([], $warn, 'no warnings from non-numeric comparison');
  73
  74         $res = $cb->(POST('/test/?q=s:bogus&x=m'));
  75         is($res->code, 404, 'failed search result gives 404');
  76         is_deeply([], $warn, 'no warnings');
  77
  78         my $mid_re = qr/\Q$mid\E/o;
  79         while (length($digits) > 8) {
  80                 $res = $cb->(GET("/test/$ua.$digits/"));
  81                 is($res->code, 300, 'partial match found while truncated');
  82                 like($res->content, qr/\b1 partial match found\b/);
  83                 like($res->content, $mid_re, 'found mid in response');
  84                 chop($digits);
  85         }
  86 });
  87
  88 done_testing();
  89
  90 1;