t/psgi_v2.t

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use File::Temp qw/tempdir/;
   7 use PublicInbox::MIME;
   8 use PublicInbox::Config;
   9 use PublicInbox::WWW;
  10 use PublicInbox::MID qw(mids);
  11 my @mods = qw(DBD::SQLite Search::Xapian HTTP::Request::Common Plack::Test
  12                 URI::Escape Plack::Builder);
  13 foreach my $mod (@mods) {
  14         eval "require $mod";
  15         plan skip_all => "$mod missing for psgi_v2_dupes.t" if $@;
  16 }
  17 use_ok($_) for @mods;
  18 use_ok 'PublicInbox::V2Writable';
  19 my $mainrepo = tempdir('pi-v2_dupes-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  20 my $ibx = {
  21         mainrepo => $mainrepo,
  22         name => 'test-v2writable',
  23         version => 2,
  24         -primary_address => 'test@example.com',
  25 };
  26 $ibx = PublicInbox::Inbox->new($ibx);
  27 my $new_mid;
  28
  29 my $im = PublicInbox::V2Writable->new($ibx, 1);
  30 $im->{parallel} = 0;
  31
  32 my $mime = PublicInbox::MIME->create(
  33         header => [
  34                 From => 'a@example.com',
  35                 To => 'test@example.com',
  36                 Subject => 'this is a subject',
  37                 'Message-ID' => '<a-mid@b>',
  38                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  39         ],
  40         body => "hello world\n",
  41 );
  42 ok($im->add($mime), 'added one message');
  43 $mime->body_set("hello world!\n");
  44
  45 my @warn;
  46 local $SIG{__WARN__} = sub { push @warn, @_ };
  47 $mime->header_set(Date => 'Fri, 02 Oct 1993 00:01:00 +0000');
  48 ok($im->add($mime), 'added duplicate-but-different message');
  49 is(scalar(@warn), 1, 'got one warning');
  50 my $mids = mids($mime->header_obj);
  51 $new_mid = $mids->[1];
  52 $im->done;
  53
  54 my $cfgpfx = "publicinbox.v2test";
  55 my $cfg = {
  56         "$cfgpfx.address" => $ibx->{-primary_address},
  57         "$cfgpfx.mainrepo" => $mainrepo,
  58 };
  59 my $config = PublicInbox::Config->new($cfg);
  60 my $www = PublicInbox::WWW->new($config);
  61 my ($res, $raw, @from_);
  62 test_psgi(sub { $www->call(@_) }, sub {
  63         my ($cb) = @_;
  64         $res = $cb->(GET('/v2test/a-mid@b/raw'));
  65         $raw = $res->content;
  66         like($raw, qr/^hello world$/m, 'got first message');
  67         like($raw, qr/^hello world!$/m, 'got second message');
  68         @from_ = ($raw =~ m/^From /mg);
  69         is(scalar(@from_), 2, 'two From_ lines');
  70
  71         $res = $cb->(GET("/v2test/$new_mid/raw"));
  72         $raw = $res->content;
  73         like($raw, qr/^hello world!$/m, 'second message with new Message-Id');
  74         @from_ = ($raw =~ m/^From /mg);
  75         is(scalar(@from_), 1, 'only one From_ line');
  76
  77         # Atom feed should sort by Date: (if Received is missing)
  78         $res = $cb->(GET('/v2test/new.atom'));
  79         my @bodies = ($res->content =~ />(hello [^<]+)</mg);
  80         is_deeply(\@bodies, [ "hello world!\n", "hello world\n" ],
  81                 'Atom ordering is chronological');
  82
  83         # new.html should sort by Date:, too (if Received is missing)
  84         $res = $cb->(GET('/v2test/new.html'));
  85         @bodies = ($res->content =~ /^(hello [^<]+)$/mg);
  86         is_deeply(\@bodies, [ "hello world!\n", "hello world\n" ],
  87                 'new.html ordering is chronological');
  88 });
  89
  90 $mime->header_set('Message-Id', 'a-mid@b');
  91 $mime->body_set("hello ghosts\n");
  92 ok($im->add($mime), 'added 3rd duplicate-but-different message');
  93 is(scalar(@warn), 2, 'got another warning');
  94 like($warn[0], qr/mismatched/, 'warned about mismatched messages');
  95 is($warn[0], $warn[1], 'both warnings are the same');
  96
  97 $mids = mids($mime->header_obj);
  98 my $third = $mids->[-1];
  99 $im->done;
 100
 101 test_psgi(sub { $www->call(@_) }, sub {
 102         my ($cb) = @_;
 103         $res = $cb->(GET("/v2test/$third/raw"));
 104         $raw = $res->content;
 105         like($raw, qr/^hello ghosts$/m, 'got third message');
 106         @from_ = ($raw =~ m/^From /mg);
 107         is(scalar(@from_), 1, 'one From_ line');
 108
 109         $res = $cb->(GET('/v2test/a-mid@b/raw'));
 110         $raw = $res->content;
 111         like($raw, qr/^hello world$/m, 'got first message');
 112         like($raw, qr/^hello world!$/m, 'got second message');
 113         like($raw, qr/^hello ghosts$/m, 'got third message');
 114         @from_ = ($raw =~ m/^From /mg);
 115         is(scalar(@from_), 3, 'three From_ lines');
 116         $config->each_inbox(sub { $_[0]->search->reopen });
 117
 118         SKIP: {
 119                 eval { require IO::Uncompress::Gunzip };
 120                 skip 'IO::Uncompress::Gunzip missing', 4 if $@;
 121
 122                 $res = $cb->(GET('/v2test/a-mid@b/t.mbox.gz'));
 123                 my $out;
 124                 my $in = $res->content;
 125                 my $status = IO::Uncompress::Gunzip::gunzip(\$in => \$out);
 126                 like($out, qr/^hello world$/m, 'got first in t.mbox.gz');
 127                 like($out, qr/^hello world!$/m, 'got second in t.mbox.gz');
 128                 like($out, qr/^hello ghosts$/m, 'got third in t.mbox.gz');
 129                 @from_ = ($out =~ m/^From /mg);
 130                 is(scalar(@from_), 3, 'three From_ lines in t.mbox.gz');
 131
 132                 # search interface
 133                 $res = $cb->(POST('/v2test/?q=m:a-mid@b&x=m'));
 134                 $in = $res->content;
 135                 $status = IO::Uncompress::Gunzip::gunzip(\$in => \$out);
 136                 like($out, qr/^hello world$/m, 'got first in mbox POST');
 137                 like($out, qr/^hello world!$/m, 'got second in mbox POST');
 138                 like($out, qr/^hello ghosts$/m, 'got third in mbox POST');
 139                 @from_ = ($out =~ m/^From /mg);
 140                 is(scalar(@from_), 3, 'three From_ lines in mbox POST');
 141
 142                 # all.mbox.gz interface
 143                 $res = $cb->(GET('/v2test/all.mbox.gz'));
 144                 $in = $res->content;
 145                 $status = IO::Uncompress::Gunzip::gunzip(\$in => \$out);
 146                 like($out, qr/^hello world$/m, 'got first in all.mbox');
 147                 like($out, qr/^hello world!$/m, 'got second in all.mbox');
 148                 like($out, qr/^hello ghosts$/m, 'got third in all.mbox');
 149                 @from_ = ($out =~ m/^From /mg);
 150                 is(scalar(@from_), 3, 'three From_ lines in all.mbox');
 151         };
 152
 153         $res = $cb->(GET('/v2test/?q=m:a-mid@b&x=t'));
 154         is($res->code, 200, 'success with threaded search');
 155         my $raw = $res->content;
 156         ok($raw =~ s/\A.*>Results 1-3 of 3<//s, 'got all results');
 157         my @over = ($raw =~ m/\d{4}-\d+-\d+\s+\d+:\d+ (.+)$/gm);
 158         is_deeply(\@over, [ '<a', '` <a', '` <a' ], 'threaded messages show up');
 159
 160         local $SIG{__WARN__} = 'DEFAULT';
 161         $res = $cb->(GET('/v2test/a-mid@b/'));
 162         $raw = $res->content;
 163         like($raw, qr/^hello world$/m, 'got first message');
 164         like($raw, qr/^hello world!$/m, 'got second message');
 165         like($raw, qr/^hello ghosts$/m, 'got third message');
 166         @from_ = ($raw =~ m/>From: /mg);
 167         is(scalar(@from_), 3, 'three From: lines');
 168         foreach my $mid ('a-mid@b', $new_mid, $third) {
 169                 like($raw, qr/&lt;\Q$mid\E&gt;/s, "Message-ID $mid shown");
 170         }
 171         like($raw, qr/\b3\+ messages\b/, 'thread overview shown');
 172
 173         my $exp = [ qw(<a-mid@b> <reuse@mid>) ];
 174         $mime->header_set('Message-Id', @$exp);
 175         $mime->header_set('Subject', '4th dupe');
 176         local $SIG{__WARN__} = sub {};
 177         ok($im->add($mime), 'added one message');
 178         $im->done;
 179         my @h = $mime->header('Message-ID');
 180         is_deeply($exp, \@h, 'reused existing Message-ID');
 181
 182         $config->each_inbox(sub { $_[0]->search->reopen });
 183
 184         $res = $cb->(GET('/v2test/new.atom'));
 185         my @ids = ($res->content =~ m!<id>urn:uuid:([^<]+)</id>!sg);
 186         my %ids;
 187         $ids{$_}++ for @ids;
 188         is_deeply([qw(1 1 1 1)], [values %ids], 'feed ids unique');
 189
 190         $res = $cb->(GET('/v2test/reuse@mid/T/'));
 191         $raw = $res->content;
 192         like($raw, qr/\b4\+ messages\b/, 'thread overview shown with /T/');
 193         @over = ($raw =~ m/^\d{4}-\d+-\d+\s+\d+:\d+ (.+)$/gm);
 194         is_deeply(\@over, [ '<a', '` <a', '` <a', '` <a' ],
 195                 'duplicate messages share the same root');
 196
 197         $res = $cb->(GET('/v2test/reuse@mid/t/'));
 198         $raw = $res->content;
 199         like($raw, qr/\b4\+ messages\b/, 'thread overview shown with /t/');
 200
 201         $res = $cb->(GET('/v2test/0/info/refs'));
 202         is($res->code, 200, 'got info refs for dumb clones');
 203         $res = $cb->(GET('/v2test/info/refs'));
 204         is($res->code, 404, 'unpartitioned git URL fails');
 205
 206         # ensure conflicted attachments can be resolved
 207         foreach my $body (qw(old new)) {
 208                 my $parts = [
 209                         PublicInbox::MIME->create(
 210                                 attributes => { content_type => 'text/plain' },
 211                                 body => 'blah',
 212                         ),
 213                         PublicInbox::MIME->create(
 214                                 attributes => {
 215                                         filename => 'attach.txt',
 216                                         content_type => 'text/plain',
 217                                 },
 218                                 body => $body
 219                         )
 220                 ];
 221                 $mime = PublicInbox::MIME->create(
 222                         parts => $parts,
 223                         header_str => [ From => 'root@z',
 224                                 'Message-ID' => '<a@dup>',
 225                                 Subject => 'hi']
 226                 );
 227                 ok($im->add($mime), "added attachment $body");
 228         }
 229         $im->done;
 230         $config->each_inbox(sub { $_[0]->search->reopen });
 231         $res = $cb->(GET('/v2test/a@dup/'));
 232         my @links = ($res->content =~ m!"\.\./([^/]+/2-attach\.txt)\"!g);
 233         is(scalar(@links), 2, 'both attachment links exist');
 234         isnt($links[0], $links[1], 'attachment links are different');
 235         {
 236                 my $old = $cb->(GET('/v2test/' . $links[0]));
 237                 my $new = $cb->(GET('/v2test/' . $links[1]));
 238                 is($old->content, 'old', 'got expected old content');
 239                 is($new->content, 'new', 'got expected new content');
 240         }
 241 });
 242
 243 done_testing();
 244
 245 1;