t/qspawn.t

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use Test::More;
   5 use_ok 'PublicInbox::Qspawn';
   6
   7 {
   8         my $cmd = [qw(sh -c), 'echo >&2 err; echo out'];
   9         my $qsp = PublicInbox::Qspawn->new($cmd, {}, { 2 => 1 });
  10         my $res;
  11         $qsp->psgi_qx({}, undef, sub { $res = ${$_[0]} });
  12         is($res, "err\nout\n", 'captured stderr and stdout');
  13 }
  14
  15 sub finish_err ($) {
  16         my ($qsp) = @_;
  17         $qsp->finish;
  18         $qsp->{err};
  19 }
  20
  21 my $limiter = PublicInbox::Qspawn::Limiter->new(1);
  22 {
  23         my $x = PublicInbox::Qspawn->new([qw(true)]);
  24         my $run = 0;
  25         $x->start($limiter, sub {
  26                 my ($self) = @_;
  27                 is(0, sysread($self->{rpipe}, my $buf, 1), 'read zero bytes');
  28                 ok(!finish_err($self), 'no error on finish');
  29                 $run = 1;
  30         });
  31         is($run, 1, 'callback ran alright');
  32 }
  33
  34 {
  35         my $x = PublicInbox::Qspawn->new([qw(false)]);
  36         my $run = 0;
  37         $x->start($limiter, sub {
  38                 my ($self) = @_;
  39                 is(0, sysread($self->{rpipe}, my $buf, 1),
  40                                 'read zero bytes from false');
  41                 ok(finish_err($self), 'error on finish');
  42                 $run = 1;
  43         });
  44         is($run, 1, 'callback ran alright');
  45 }
  46
  47 foreach my $cmd ([qw(sleep 1)], [qw(sh -c), 'sleep 1; false']) {
  48         my $s = PublicInbox::Qspawn->new($cmd);
  49         my @run;
  50         $s->start($limiter, sub {
  51                 my ($self) = @_;
  52                 push @run, 'sleep';
  53                 is(0, sysread($self->{rpipe}, my $buf, 1), 'read zero bytes');
  54         });
  55         my $n = 0;
  56         my @t = map {
  57                 my $i = $n++;
  58                 my $x = PublicInbox::Qspawn->new([qw(true)]);
  59                 $x->start($limiter, sub {
  60                         my ($self) = @_;
  61                         push @run, $i;
  62                 });
  63                 [$x, $i]
  64         } (0..2);
  65
  66         if ($cmd->[-1] =~ /false\z/) {
  67                 ok(finish_err($s), 'got error on false after sleep');
  68         } else {
  69                 ok(!finish_err($s), 'no error on sleep');
  70         }
  71         ok(!finish_err($_->[0]), "true $_->[1] succeeded") foreach @t;
  72         is_deeply([qw(sleep 0 1 2)], \@run, 'ran in order');
  73 }
  74
  75 done_testing();
  76
  77 1;