t/qspawn.t

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use Test::More;
   5 use_ok 'PublicInbox::Qspawn';
   6
   7 {
   8         my $cmd = [qw(sh -c), 'echo >&2 err; echo out'];
   9         my $qsp = PublicInbox::Qspawn->new($cmd, {}, { 2 => 1 });
  10         my $res;
  11         $qsp->psgi_qx({}, undef, sub { $res = ${$_[0]} });
  12         is($res, "err\nout\n", 'captured stderr and stdout');
  13 }
  14
  15 sub finish_err ($) {
  16         my ($qsp) = @_;
  17         $qsp->finish;
  18         $qsp->{err};
  19 }
  20
  21 my $limiter = PublicInbox::Qspawn::Limiter->new(1);
  22 {
  23         my $x = PublicInbox::Qspawn->new([qw(true)]);
  24         my $run = 0;
  25         $x->start($limiter, sub {
  26                 my ($rpipe) = @_;
  27                 is(0, sysread($rpipe, my $buf, 1), 'read zero bytes');
  28                 ok(!finish_err($x), 'no error on finish');
  29                 $run = 1;
  30         });
  31         is($run, 1, 'callback ran alright');
  32 }
  33
  34 {
  35         my $x = PublicInbox::Qspawn->new([qw(false)]);
  36         my $run = 0;
  37         $x->start($limiter, sub {
  38                 my ($rpipe) = @_;
  39                 is(0, sysread($rpipe, my $buf, 1), 'read zero bytes from false');
  40                 ok(finish_err($x), 'error on finish');
  41                 $run = 1;
  42         });
  43         is($run, 1, 'callback ran alright');
  44 }
  45
  46 foreach my $cmd ([qw(sleep 1)], [qw(sh -c), 'sleep 1; false']) {
  47         my $s = PublicInbox::Qspawn->new($cmd);
  48         my @run;
  49         $s->start($limiter, sub {
  50                 my ($rpipe) = @_;
  51                 push @run, 'sleep';
  52                 is(0, sysread($rpipe, my $buf, 1), 'read zero bytes');
  53         });
  54         my $n = 0;
  55         my @t = map {
  56                 my $i = $n++;
  57                 my $x = PublicInbox::Qspawn->new([qw(true)]);
  58                 $x->start($limiter, sub {
  59                         my ($rpipe) = @_;
  60                         push @run, $i;
  61                 });
  62                 [$x, $i]
  63         } (0..2);
  64
  65         if ($cmd->[-1] =~ /false\z/) {
  66                 ok(finish_err($s), 'got error on false after sleep');
  67         } else {
  68                 ok(!finish_err($s), 'no error on sleep');
  69         }
  70         ok(!finish_err($_->[0]), "true $_->[1] succeeded") foreach @t;
  71         is_deeply([qw(sleep 0 1 2)], \@run, 'ran in order');
  72 }
  73
  74 done_testing();
  75
  76 1;