t/run.perl

   1 #!/usr/bin/perl -w
   2 # Copyright (C) all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Parallel test runner which preloads code and reuses worker processes
   6 # to give a nice speedup over prove(1).  It also generates per-test
   7 # .log files (similar to automake tests).
   8 #
   9 # *.t files run by this should not rely on global state.
  10 #
  11 # Usage: $PERL -I lib -w t/run.perl -j4
  12 # Or via prove(1): prove -lvw t/run.perl :: -j4
  13 use v5.12;
  14 use IO::Handle; # ->autoflush
  15 use PublicInbox::TestCommon;
  16 use PublicInbox::Spawn;
  17 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  18 use Errno qw(EINTR);
  19 use Fcntl qw(:seek);
  20 use POSIX qw(WNOHANG);
  21 use File::Temp ();
  22 my $jobs = 1;
  23 my $repeat = 1;
  24 $| = 1;
  25 our $log_suffix = '.log';
  26 my ($shuffle, %pids, @err);
  27 GetOptions('j|jobs=i' => \$jobs,
  28         'repeat=i' => \$repeat,
  29         'log=s' => \$log_suffix,
  30         's|shuffle' => \$shuffle,
  31 ) or die "Usage: $0 [-j JOBS] [--log=SUFFIX] [--repeat RUNS]";
  32 if (($ENV{TEST_RUN_MODE} // 2) == 0) {
  33         die "$0 is not compatible with TEST_RUN_MODE=0\n";
  34 }
  35 my @tests = scalar(@ARGV) ? @ARGV : glob('t/*.t');
  36 open my $cwd_fh, '<', '.' or die "open .: $!";
  37 open my $OLDOUT, '>&STDOUT' or die "dup STDOUT: $!";
  38 open my $OLDERR, '>&STDERR' or die "dup STDERR: $!";
  39 $OLDOUT->autoflush(1);
  40 $OLDERR->autoflush(1);
  41
  42 my ($run_log, $tmp_rl);
  43 my $rl = $ENV{TEST_RUN_LOG};
  44 unless ($rl) {
  45         $tmp_rl = File::Temp->new(CLEANUP => 1);
  46         $rl = $tmp_rl->filename;
  47 }
  48 open $run_log, '+>>', $rl or die "open $rl: $!";
  49 $run_log->autoflush(1); # one reader, many writers
  50
  51 key2sub($_) for @tests; # precache
  52
  53 my ($for_destroy, $lei_env, $lei_daemon_pid, $owner_pid);
  54
  55 # TEST_LEI_DAEMON_PERSIST is currently broken.  I get ECONNRESET from
  56 # lei even with high kern.ipc.soacceptqueue=1073741823 or SOMAXCONN, not
  57 # sure why.  Also, testing our internal inotify usage is unreliable
  58 # because lei-daemon uses a single inotify FD for all clients.
  59 if ($ENV{TEST_LEI_DAEMON_PERSIST} && !$ENV{TEST_LEI_DAEMON_PERSIST_DIR} &&
  60                 (PublicInbox::Spawn->can('recv_cmd4') ||
  61                         eval { require Socket::MsgHdr })) {
  62         $lei_env = {};
  63         ($lei_env->{XDG_RUNTIME_DIR}, $for_destroy) = tmpdir;
  64         $ENV{TEST_LEI_DAEMON_PERSIST_DIR} = $lei_env->{XDG_RUNTIME_DIR};
  65         run_script([qw(lei daemon-pid)], $lei_env, { 1 => \$lei_daemon_pid });
  66         chomp $lei_daemon_pid;
  67         $lei_daemon_pid =~ /\A[0-9]+\z/ or die "no daemon pid: $lei_daemon_pid";
  68         kill(0, $lei_daemon_pid) or die "kill $lei_daemon_pid: $!";
  69         if (my $t = $ENV{GNU_TAIL}) {
  70                 system("$t --pid=$lei_daemon_pid -F " .
  71                         "$lei_env->{XDG_RUNTIME_DIR}/lei/errors.log >&2 &");
  72         }
  73         if (my $strace_cmd = $ENV{STRACE_CMD}) {
  74                 system("$strace_cmd -p $lei_daemon_pid &");
  75         }
  76         $owner_pid = $$;
  77 }
  78
  79 if ($shuffle) {
  80         require List::Util;
  81 } elsif (open(my $prove_state, '<', '.prove') && eval { require YAML::XS }) {
  82         # reuse "prove --state=save" data to start slowest tests, first
  83         my $state = YAML::XS::Load(do { local $/; <$prove_state> });
  84         my $t = $state->{tests};
  85         @tests = sort {
  86                 ($t->{$b}->{elapsed} // 0) <=> ($t->{$a}->{elapsed} // 0)
  87         } @tests;
  88 }
  89
  90 our $tb = Test::More->builder;
  91
  92 sub DIE (;$) {
  93         print $OLDERR @_;
  94         exit(1);
  95 }
  96
  97 our ($worker, $worker_test);
  98
  99 sub test_status () {
 100         $? = 255 if $? == 0 && !$tb->is_passing;
 101         my $status = $? ? 'not ok' : 'ok';
 102         chdir($cwd_fh) or DIE "fchdir: $!";
 103         if ($log_suffix ne '') {
 104                 my $log = $worker_test;
 105                 $log =~ s/\.t\z/$log_suffix/;
 106                 my $skip = '';
 107                 if (open my $fh, '<', $log) {
 108                         my @not_ok = grep(!/^(?:ok |[ \t]*#)/ms, <$fh>);
 109                         my $last = $not_ok[-1] // '';
 110                         pop @not_ok if $last =~ /^[0-9]+\.\.[0-9]+$/;
 111                         my $pfx = "# $log: ";
 112                         print $OLDERR map { $pfx.$_ } @not_ok;
 113                         seek($fh, 0, SEEK_SET) or die "seek: $!";
 114
 115                         # show unique skip texts and the number of times
 116                         # each text was skipped
 117                         local $/;
 118                         my @sk = (<$fh> =~ m/^ok [0-9]+ (# skip [^\n]+)/mgs);
 119                         if (@sk) {
 120                                 my %nr;
 121                                 my @err = grep { !$nr{$_}++ } @sk;
 122                                 print $OLDERR "$pfx$_ ($nr{$_})\n" for @err;
 123                                 $skip = ' # total skipped: '.scalar(@sk);
 124                         }
 125                 } else {
 126                         print $OLDERR "could not open: $log: $!\n";
 127                 }
 128                 print $OLDOUT "$status $worker_test$skip\n";
 129         }
 130 }
 131
 132 # Test::Builder or Test2::Hub may call exit() from plan(skip_all => ...)
 133 END { test_status() if (defined($worker_test) && $worker == $$) }
 134
 135 sub run_test ($) {
 136         my ($test) = @_;
 137         syswrite($run_log, "$$ $test\n");
 138         my $log_fh;
 139         if ($log_suffix ne '') {
 140                 my $log = $test;
 141                 $log =~ s/\.[^\.]+\z/$log_suffix/ or DIE "can't log for $test";
 142                 open $log_fh, '>', $log or DIE "open $log: $!";
 143                 $log_fh->autoflush(1);
 144                 $tb->output($log_fh);
 145                 $tb->failure_output($log_fh);
 146                 $tb->todo_output($log_fh);
 147                 open STDOUT, '>&', $log_fh or DIE "1>$log: $!";
 148                 open STDERR, '>&', $log_fh or DIE "2>$log: $!";
 149         }
 150         $worker_test = $test;
 151         run_script([$test]);
 152         test_status();
 153         $worker_test = undef;
 154         push @err, "$test ($?)" if $?;
 155 }
 156
 157 sub UINT_SIZE () { 4 }
 158
 159 # worker processes will SIGUSR1 the producer process when it
 160 # sees EOF on the pipe.  On FreeBSD 11.2 and Perl 5.30.0,
 161 # sys/ioctl.ph gives the wrong value for FIONREAD().
 162 my $producer = $$;
 163 my $eof; # we stop respawning if true
 164
 165 my $start_worker = sub {
 166         my ($j, $rd, $wr, $todo) = @_;
 167         my $pid = fork // DIE "fork: $!";
 168         if ($pid == 0) {
 169                 close $wr;
 170                 $SIG{USR1} = undef; # undo parent $SIG{USR1}
 171                 $worker = $$;
 172                 while (1) {
 173                         my $r = sysread($rd, my $buf, UINT_SIZE);
 174                         if (!defined($r)) {
 175                                 next if $! == EINTR;
 176                                 DIE "sysread: $!";
 177                         }
 178                         last if $r == 0;
 179                         DIE "short read $r" if $r != UINT_SIZE;
 180                         my $t = unpack('I', $buf);
 181                         run_test($todo->[$t]);
 182                         $tb->reset;
 183                 }
 184                 kill 'USR1', $producer if !$eof; # sets $eof in $producer
 185                 if (@err) { # write to run_log for $sigchld handler
 186                         syswrite($run_log, "$$ @err\n");
 187                         DIE join('', map { "E: $_\n" } @err);
 188                 }
 189                 exit(0);
 190         } else {
 191                 $pids{$pid} = $j;
 192         }
 193 };
 194
 195 # negative $repeat means loop forever:
 196 for (my $i = $repeat; $i != 0; $i--) {
 197         my @todo = $shuffle ? List::Util::shuffle(@tests) : @tests;
 198
 199         # single-producer, multi-consumer queue relying on POSIX pipe semantics
 200         # POSIX.1-2008 stipulates a regular file should work, but Linux <3.14
 201         # had broken read(2) semantics according to the read(2) manpage
 202         pipe(my ($rd, $wr)) or DIE "pipe: $!";
 203
 204         # fill the queue before forking so children can start earlier
 205         $wr->autoflush(1);
 206         $wr->blocking(0);
 207         my $todo_buf = join('', map { pack('I', $_) } (0..$#todo));
 208         my $woff = syswrite($wr, $todo_buf) // DIE "syswrite: $!";
 209         substr($todo_buf, 0, $woff, '');
 210         $eof = undef;
 211         local $SIG{USR1} = sub { $eof = 1 };
 212         my $sigchld = sub {
 213                 my ($sig) = @_;
 214                 my $flags = $sig ? WNOHANG : 0;
 215                 while (1) {
 216                         my $pid = waitpid(-1, $flags) or return;
 217                         return if $pid < 0;
 218                         my $j = delete $pids{$pid};
 219                         if (!defined($j)) {
 220                                 push @err, "reaped unknown $pid ($?)";
 221                                 next;
 222                         }
 223                         if ($?) {
 224                                 seek($run_log, 0, SEEK_SET);
 225                                 chomp(my @t = grep(/^$pid /, <$run_log>));
 226                                 $t[0] //= "$pid unknown";
 227                                 push @err, "job[$j] ($?) PID=$t[-1]";
 228                         }
 229                         # skip_all can exit(0), respawn if needed:
 230                         if (!$eof) {
 231                                 print $OLDERR "# respawning job[$j]\n";
 232                                 $start_worker->($j, $rd, $wr, \@todo);
 233                         }
 234                 }
 235         };
 236
 237         # start the workers to consume the queue
 238         for (my $j = 0; $j < $jobs; $j++) {
 239                 $start_worker->($j, $rd, $wr, \@todo);
 240         }
 241         {
 242                 local $SIG{CHLD} = $sigchld;
 243                 # too many tests to fit in the pipe before starting workers,
 244                 # send the rest now the workers are running
 245                 $wr->blocking(1);
 246                 print $wr $todo_buf or DIE;
 247                 close $wr;
 248         }
 249
 250         $sigchld->(0) while scalar(keys(%pids));
 251         DIE join('', map { "E: $_\n" } @err) if @err;
 252 }
 253
 254 print $OLDOUT "1..".($repeat * scalar(@tests))."\n" if $repeat >= 0;
 255 if ($lei_env && $$ == $owner_pid) {
 256         my $opt = { 1 => $OLDOUT, 2 => $OLDERR };
 257         my $cur_daemon_pid;
 258         run_script([qw(lei daemon-pid)], $lei_env, { 1 => \$cur_daemon_pid });
 259         run_script([qw(lei daemon-kill)], $lei_env, $opt);
 260         DIE "lei daemon restarted\n" if $cur_daemon_pid != $lei_daemon_pid;
 261 }