t/run.perl

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2019-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Parallel test runner which preloads code and reuses worker processes
   6 # to give a nice speedup over prove(1).  It also generates per-test
   7 # .log files (similar to automake tests).
   8 #
   9 # *.t files run by this should not rely on global state.
  10 #
  11 # Usage: $PERL -I lib -w t/run.perl -j4
  12 # Or via prove(1): prove -lvw t/run.perl :: -j4
  13 use strict;
  14 use v5.10.1;
  15 use IO::Handle; # ->autoflush
  16 use PublicInbox::TestCommon;
  17 use PublicInbox::Spawn;
  18 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  19 use Errno qw(EINTR);
  20 use Fcntl qw(:seek);
  21 use POSIX qw(WNOHANG);
  22 use File::Temp ();
  23 my $jobs = 1;
  24 my $repeat = 1;
  25 $| = 1;
  26 our $log_suffix = '.log';
  27 my ($shuffle, %pids, @err);
  28 GetOptions('j|jobs=i' => \$jobs,
  29         'repeat=i' => \$repeat,
  30         'log=s' => \$log_suffix,
  31         's|shuffle' => \$shuffle,
  32 ) or die "Usage: $0 [-j JOBS] [--log=SUFFIX] [--repeat RUNS]";
  33 if (($ENV{TEST_RUN_MODE} // 2) == 0) {
  34         die "$0 is not compatible with TEST_RUN_MODE=0\n";
  35 }
  36 my @tests = scalar(@ARGV) ? @ARGV : glob('t/*.t');
  37 open my $cwd_fh, '<', '.' or die "open .: $!";
  38 open my $OLDOUT, '>&STDOUT' or die "dup STDOUT: $!";
  39 open my $OLDERR, '>&STDERR' or die "dup STDERR: $!";
  40 $OLDOUT->autoflush(1);
  41 $OLDERR->autoflush(1);
  42
  43 my ($run_log, $tmp_rl);
  44 my $rl = $ENV{TEST_RUN_LOG};
  45 unless ($rl) {
  46         $tmp_rl = File::Temp->new(CLEANUP => 1);
  47         $rl = $tmp_rl->filename;
  48 }
  49 open $run_log, '+>>', $rl or die "open $rl: $!";
  50 $run_log->autoflush(1); # one reader, many writers
  51
  52 key2sub($_) for @tests; # precache
  53
  54 my ($for_destroy, $lei_env, $lei_daemon_pid, $owner_pid);
  55
  56 # TEST_LEI_DAEMON_PERSIST is currently broken.  I get ECONNRESET from
  57 # lei even with high kern.ipc.soacceptqueue=1073741823 or SOMAXCONN, not
  58 # sure why.  Also, testing our internal inotify usage is unreliable
  59 # because lei-daemon uses a single inotify FD for all clients.
  60 if ($ENV{TEST_LEI_DAEMON_PERSIST} && !$ENV{TEST_LEI_DAEMON_PERSIST_DIR} &&
  61                 (PublicInbox::Spawn->can('recv_cmd4') ||
  62                         eval { require Socket::MsgHdr })) {
  63         $lei_env = {};
  64         ($lei_env->{XDG_RUNTIME_DIR}, $for_destroy) = tmpdir;
  65         $ENV{TEST_LEI_DAEMON_PERSIST_DIR} = $lei_env->{XDG_RUNTIME_DIR};
  66         run_script([qw(lei daemon-pid)], $lei_env, { 1 => \$lei_daemon_pid });
  67         chomp $lei_daemon_pid;
  68         $lei_daemon_pid =~ /\A[0-9]+\z/ or die "no daemon pid: $lei_daemon_pid";
  69         kill(0, $lei_daemon_pid) or die "kill $lei_daemon_pid: $!";
  70         if (my $t = $ENV{GNU_TAIL}) {
  71                 system("$t --pid=$lei_daemon_pid -F " .
  72                         "$lei_env->{XDG_RUNTIME_DIR}/lei/errors.log >&2 &");
  73         }
  74         if (my $strace_cmd = $ENV{STRACE_CMD}) {
  75                 system("$strace_cmd -p $lei_daemon_pid &");
  76         }
  77         $owner_pid = $$;
  78 }
  79
  80 if ($shuffle) {
  81         require List::Util;
  82 } elsif (open(my $prove_state, '<', '.prove') && eval { require YAML::XS }) {
  83         # reuse "prove --state=save" data to start slowest tests, first
  84         my $state = YAML::XS::Load(do { local $/; <$prove_state> });
  85         my $t = $state->{tests};
  86         @tests = sort {
  87                 ($t->{$b}->{elapsed} // 0) <=> ($t->{$a}->{elapsed} // 0)
  88         } @tests;
  89 }
  90
  91 our $tb = Test::More->builder;
  92
  93 sub DIE (;$) {
  94         print $OLDERR @_;
  95         exit(1);
  96 }
  97
  98 our ($worker, $worker_test);
  99
 100 sub test_status () {
 101         $? = 255 if $? == 0 && !$tb->is_passing;
 102         my $status = $? ? 'not ok' : 'ok';
 103         chdir($cwd_fh) or DIE "fchdir: $!";
 104         if ($log_suffix ne '') {
 105                 my $log = $worker_test;
 106                 $log =~ s/\.t\z/$log_suffix/;
 107                 my $skip = '';
 108                 if (open my $fh, '<', $log) {
 109                         my @not_ok = grep(!/^(?:ok |[ \t]*#)/ms, <$fh>);
 110                         my $last = $not_ok[-1] // '';
 111                         pop @not_ok if $last =~ /^[0-9]+\.\.[0-9]+$/;
 112                         my $pfx = "# $log: ";
 113                         print $OLDERR map { $pfx.$_ } @not_ok;
 114                         seek($fh, 0, SEEK_SET) or die "seek: $!";
 115
 116                         # show unique skip texts and the number of times
 117                         # each text was skipped
 118                         local $/;
 119                         my @sk = (<$fh> =~ m/^ok [0-9]+ (# skip [^\n]+)/mgs);
 120                         if (@sk) {
 121                                 my %nr;
 122                                 my @err = grep { !$nr{$_}++ } @sk;
 123                                 print $OLDERR "$pfx$_ ($nr{$_})\n" for @err;
 124                                 $skip = ' # total skipped: '.scalar(@sk);
 125                         }
 126                 } else {
 127                         print $OLDERR "could not open: $log: $!\n";
 128                 }
 129                 print $OLDOUT "$status $worker_test$skip\n";
 130         }
 131 }
 132
 133 # Test::Builder or Test2::Hub may call exit() from plan(skip_all => ...)
 134 END { test_status() if (defined($worker_test) && $worker == $$) }
 135
 136 sub run_test ($) {
 137         my ($test) = @_;
 138         syswrite($run_log, "$$ $test\n");
 139         my $log_fh;
 140         if ($log_suffix ne '') {
 141                 my $log = $test;
 142                 $log =~ s/\.[^\.]+\z/$log_suffix/ or DIE "can't log for $test";
 143                 open $log_fh, '>', $log or DIE "open $log: $!";
 144                 $log_fh->autoflush(1);
 145                 $tb->output($log_fh);
 146                 $tb->failure_output($log_fh);
 147                 $tb->todo_output($log_fh);
 148                 open STDOUT, '>&', $log_fh or DIE "1>$log: $!";
 149                 open STDERR, '>&', $log_fh or DIE "2>$log: $!";
 150         }
 151         $worker_test = $test;
 152         run_script([$test]);
 153         test_status();
 154         $worker_test = undef;
 155         push @err, "$test ($?)" if $?;
 156 }
 157
 158 sub UINT_SIZE () { 4 }
 159
 160 # worker processes will SIGUSR1 the producer process when it
 161 # sees EOF on the pipe.  On FreeBSD 11.2 and Perl 5.30.0,
 162 # sys/ioctl.ph gives the wrong value for FIONREAD().
 163 my $producer = $$;
 164 my $eof; # we stop respawning if true
 165
 166 my $start_worker = sub {
 167         my ($j, $rd, $wr, $todo) = @_;
 168         my $pid = fork // DIE "fork: $!";
 169         if ($pid == 0) {
 170                 close $wr if $wr;
 171                 $worker = $$;
 172                 while (1) {
 173                         my $r = sysread($rd, my $buf, UINT_SIZE);
 174                         if (!defined($r)) {
 175                                 next if $! == EINTR;
 176                                 DIE "sysread: $!";
 177                         }
 178                         last if $r == 0;
 179                         DIE "short read $r" if $r != UINT_SIZE;
 180                         my $t = unpack('I', $buf);
 181                         run_test($todo->[$t]);
 182                         $tb->reset;
 183                 }
 184                 kill 'USR1', $producer if !$eof; # sets $eof in $producer
 185                 DIE join('', map { "E: $_\n" } @err) if @err;
 186                 exit(0);
 187         } else {
 188                 $pids{$pid} = $j;
 189         }
 190 };
 191
 192 # negative $repeat means loop forever:
 193 for (my $i = $repeat; $i != 0; $i--) {
 194         my @todo = $shuffle ? List::Util::shuffle(@tests) : @tests;
 195
 196         # single-producer, multi-consumer queue relying on POSIX pipe semantics
 197         # POSIX.1-2008 stipulates a regular file should work, but Linux <3.14
 198         # had broken read(2) semantics according to the read(2) manpage
 199         pipe(my ($rd, $wr)) or DIE "pipe: $!";
 200
 201         # fill the queue before forking so children can start earlier
 202         my $n = (POSIX::PIPE_BUF / UINT_SIZE);
 203         if ($n >= $#todo) {
 204                 print $wr join('', map { pack('I', $_) } (0..$#todo)) or DIE;
 205                 undef $wr;
 206         } else { # write what we can...
 207                 $wr->autoflush(1);
 208                 print $wr join('', map { pack('I', $_) } (0..$n)) or DIE;
 209                 $n += 1; # and send more ($n..$#todo), later
 210         }
 211         $eof = undef;
 212         local $SIG{USR1} = sub { $eof = 1 };
 213         my $sigchld = sub {
 214                 my ($sig) = @_;
 215                 my $flags = $sig ? WNOHANG : 0;
 216                 while (1) {
 217                         my $pid = waitpid(-1, $flags) or return;
 218                         return if $pid < 0;
 219                         my $j = delete $pids{$pid};
 220                         if (!defined($j)) {
 221                                 push @err, "reaped unknown $pid ($?)";
 222                                 next;
 223                         }
 224                         if ($?) {
 225                                 seek($run_log, 0, SEEK_SET);
 226                                 chomp(my @t = grep(/^$pid /, <$run_log>));
 227                                 $t[0] //= "$pid unknown";
 228                                 push @err, "job[$j] ($?) PID=$t[-1]";
 229                         }
 230                         # skip_all can exit(0), respawn if needed:
 231                         if (!$eof) {
 232                                 print $OLDERR "# respawning job[$j]\n";
 233                                 $start_worker->($j, $rd, $wr, \@todo);
 234                         }
 235                 }
 236         };
 237
 238         # start the workers to consume the queue
 239         for (my $j = 0; $j < $jobs; $j++) {
 240                 $start_worker->($j, $rd, $wr, \@todo);
 241         }
 242         if ($wr) {
 243                 local $SIG{CHLD} = $sigchld;
 244                 # too many tests to fit in the pipe before starting workers,
 245                 # send the rest now the workers are running
 246                 print $wr join('', map { pack('I', $_) } ($n..$#todo)) or DIE;
 247                 undef $wr;
 248         }
 249
 250         $sigchld->(0) while scalar(keys(%pids));
 251         DIE join('', map { "E: $_\n" } @err) if @err;
 252 }
 253
 254 print $OLDOUT "1..".($repeat * scalar(@tests))."\n" if $repeat >= 0;
 255 if ($lei_env && $$ == $owner_pid) {
 256         my $opt = { 1 => $OLDOUT, 2 => $OLDERR };
 257         my $cur_daemon_pid;
 258         run_script([qw(lei daemon-pid)], $lei_env, { 1 => \$cur_daemon_pid });
 259         run_script([qw(lei daemon-kill)], $lei_env, $opt);
 260         DIE "lei daemon restarted\n" if $cur_daemon_pid != $lei_daemon_pid;
 261 }