t/run.perl

   1 #!/usr/bin/perl -w
   2 # Copyright (C) 2019-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 #
   5 # Parallel test runner which preloads code and reuses worker processes
   6 # to give a nice speedup over prove(1).  It also generates per-test
   7 # .log files (similar to automake tests).
   8 #
   9 # *.t files run by this should not rely on global state.
  10 #
  11 # Usage: $PERL -I lib -w t/run.perl -j4
  12 # Or via prove(1): prove -lvw t/run.perl :: -j4
  13 use strict;
  14 use v5.10.1;
  15 use IO::Handle; # ->autoflush
  16 use PublicInbox::TestCommon;
  17 use PublicInbox::Spawn;
  18 use Getopt::Long qw(:config gnu_getopt no_ignore_case auto_abbrev);
  19 use Errno qw(EINTR);
  20 use Fcntl qw(:seek);
  21 use POSIX qw(_POSIX_PIPE_BUF WNOHANG);
  22 my $jobs = 1;
  23 my $repeat = 1;
  24 $| = 1;
  25 our $log_suffix = '.log';
  26 my ($shuffle, %pids, @err);
  27 GetOptions('j|jobs=i' => \$jobs,
  28         'repeat=i' => \$repeat,
  29         'log=s' => \$log_suffix,
  30         's|shuffle' => \$shuffle,
  31 ) or die "Usage: $0 [-j JOBS] [--log=SUFFIX] [--repeat RUNS]";
  32 if (($ENV{TEST_RUN_MODE} // 2) == 0) {
  33         die "$0 is not compatible with TEST_RUN_MODE=0\n";
  34 }
  35 my @tests = scalar(@ARGV) ? @ARGV : glob('t/*.t');
  36 open my $cwd_fh, '<', '.' or die "open .: $!";
  37 open my $OLDOUT, '>&STDOUT' or die "dup STDOUT: $!";
  38 open my $OLDERR, '>&STDERR' or die "dup STDERR: $!";
  39 $OLDOUT->autoflush(1);
  40 $OLDERR->autoflush(1);
  41
  42 key2sub($_) for @tests; # precache
  43
  44 my ($for_destroy, $lei_env, $lei_daemon_pid, $owner_pid);
  45 if (!$ENV{TEST_LEI_DAEMON_PERSIST_DIR} &&
  46                 (PublicInbox::Spawn->can('recv_cmd4') ||
  47                         eval { require Socket::MsgHdr })) {
  48         $lei_env = {};
  49         ($lei_env->{XDG_RUNTIME_DIR}, $for_destroy) = tmpdir;
  50         $ENV{TEST_LEI_DAEMON_PERSIST_DIR} = $lei_env->{XDG_RUNTIME_DIR};
  51         run_script([qw(lei daemon-pid)], $lei_env, { 1 => \$lei_daemon_pid });
  52         chomp $lei_daemon_pid;
  53         $lei_daemon_pid =~ /\A[0-9]+\z/ or die "no daemon pid: $lei_daemon_pid";
  54         kill(0, $lei_daemon_pid) or die "kill $lei_daemon_pid: $!";
  55         $owner_pid = $$;
  56 }
  57
  58 if ($shuffle) {
  59         require List::Util;
  60 } elsif (open(my $prove_state, '<', '.prove') && eval { require YAML::XS }) {
  61         # reuse "prove --state=save" data to start slowest tests, first
  62         my $state = YAML::XS::Load(do { local $/; <$prove_state> });
  63         my $t = $state->{tests};
  64         @tests = sort {
  65                 ($t->{$b}->{elapsed} // 0) <=> ($t->{$a}->{elapsed} // 0)
  66         } @tests;
  67 }
  68
  69 our $tb = Test::More->builder;
  70
  71 sub DIE (;$) {
  72         print $OLDERR @_;
  73         exit(1);
  74 }
  75
  76 our ($worker, $worker_test);
  77
  78 sub test_status () {
  79         $? = 255 if $? == 0 && !$tb->is_passing;
  80         my $status = $? ? 'not ok' : 'ok';
  81         chdir($cwd_fh) or DIE "fchdir: $!";
  82         if ($log_suffix ne '') {
  83                 my $log = $worker_test;
  84                 $log =~ s/\.t\z/$log_suffix/;
  85                 my $skip = '';
  86                 if (open my $fh, '<', $log) {
  87                         my @not_ok = grep(!/^(?:ok |[ \t]*#)/ms, <$fh>);
  88                         my $last = $not_ok[-1] // '';
  89                         pop @not_ok if $last =~ /^[0-9]+\.\.[0-9]+$/;
  90                         my $pfx = "# $log: ";
  91                         print $OLDERR map { $pfx.$_ } @not_ok;
  92                         seek($fh, 0, SEEK_SET) or die "seek: $!";
  93
  94                         # show unique skip texts and the number of times
  95                         # each text was skipped
  96                         local $/;
  97                         my @sk = (<$fh> =~ m/^ok [0-9]+ (# skip [^\n]+)/mgs);
  98                         if (@sk) {
  99                                 my %nr;
 100                                 my @err = grep { !$nr{$_}++ } @sk;
 101                                 print $OLDERR "$pfx$_ ($nr{$_})\n" for @err;
 102                                 $skip = ' # total skipped: '.scalar(@sk);
 103                         }
 104                 } else {
 105                         print $OLDERR "could not open: $log: $!\n";
 106                 }
 107                 print $OLDOUT "$status $worker_test$skip\n";
 108         }
 109 }
 110
 111 # Test::Builder or Test2::Hub may call exit() from plan(skip_all => ...)
 112 END { test_status() if (defined($worker_test) && $worker == $$) }
 113
 114 sub run_test ($) {
 115         my ($test) = @_;
 116         my $log_fh;
 117         if ($log_suffix ne '') {
 118                 my $log = $test;
 119                 $log =~ s/\.[^\.]+\z/$log_suffix/ or DIE "can't log for $test";
 120                 open $log_fh, '>', $log or DIE "open $log: $!";
 121                 $log_fh->autoflush(1);
 122                 $tb->output($log_fh);
 123                 $tb->failure_output($log_fh);
 124                 $tb->todo_output($log_fh);
 125                 open STDOUT, '>&', $log_fh or DIE "1>$log: $!";
 126                 open STDERR, '>&', $log_fh or DIE "2>$log: $!";
 127         }
 128         $worker_test = $test;
 129         run_script([$test]);
 130         test_status();
 131         $worker_test = undef;
 132         push @err, "$test ($?)" if $?;
 133 }
 134
 135 sub UINT_SIZE () { 4 }
 136
 137 # worker processes will SIGUSR1 the producer process when it
 138 # sees EOF on the pipe.  On FreeBSD 11.2 and Perl 5.30.0,
 139 # sys/ioctl.ph gives the wrong value for FIONREAD().
 140 my $producer = $$;
 141 my $eof; # we stop respawning if true
 142
 143 my $start_worker = sub {
 144         my ($j, $rd, $wr, $todo) = @_;
 145         my $pid = fork // DIE "fork: $!";
 146         if ($pid == 0) {
 147                 close $wr if $wr;
 148                 $worker = $$;
 149                 while (1) {
 150                         my $r = sysread($rd, my $buf, UINT_SIZE);
 151                         if (!defined($r)) {
 152                                 next if $! == EINTR;
 153                                 DIE "sysread: $!";
 154                         }
 155                         last if $r == 0;
 156                         DIE "short read $r" if $r != UINT_SIZE;
 157                         my $t = unpack('I', $buf);
 158                         run_test($todo->[$t]);
 159                         $tb->reset;
 160                 }
 161                 kill 'USR1', $producer if !$eof; # sets $eof in $producer
 162                 DIE join('', map { "E: $_\n" } @err) if @err;
 163                 exit(0);
 164         } else {
 165                 $pids{$pid} = $j;
 166         }
 167 };
 168
 169 # negative $repeat means loop forever:
 170 for (my $i = $repeat; $i != 0; $i--) {
 171         my @todo = $shuffle ? List::Util::shuffle(@tests) : @tests;
 172
 173         # single-producer, multi-consumer queue relying on POSIX pipe semantics
 174         # POSIX.1-2008 stipulates a regular file should work, but Linux <3.14
 175         # had broken read(2) semantics according to the read(2) manpage
 176         pipe(my ($rd, $wr)) or DIE "pipe: $!";
 177
 178         # fill the queue before forking so children can start earlier
 179         my $n = (_POSIX_PIPE_BUF / UINT_SIZE);
 180         if ($n >= $#todo) {
 181                 print $wr join('', map { pack('I', $_) } (0..$#todo)) or DIE;
 182                 undef $wr;
 183         } else { # write what we can...
 184                 $wr->autoflush(1);
 185                 print $wr join('', map { pack('I', $_) } (0..$n)) or DIE;
 186                 $n += 1; # and send more ($n..$#todo), later
 187         }
 188         $eof = undef;
 189         local $SIG{USR1} = sub { $eof = 1 };
 190         my $sigchld = sub {
 191                 my ($sig) = @_;
 192                 my $flags = $sig ? WNOHANG : 0;
 193                 while (1) {
 194                         my $pid = waitpid(-1, $flags) or return;
 195                         return if $pid < 0;
 196                         my $j = delete $pids{$pid};
 197                         if (!defined($j)) {
 198                                 push @err, "reaped unknown $pid ($?)";
 199                                 next;
 200                         }
 201                         push @err, "job[$j] ($?)" if $?;
 202                         # skip_all can exit(0), respawn if needed:
 203                         if (!$eof) {
 204                                 print $OLDERR "# respawning job[$j]\n";
 205                                 $start_worker->($j, $rd, $wr, \@todo);
 206                         }
 207                 }
 208         };
 209
 210         # start the workers to consume the queue
 211         for (my $j = 0; $j < $jobs; $j++) {
 212                 $start_worker->($j, $rd, $wr, \@todo);
 213         }
 214         if ($wr) {
 215                 local $SIG{CHLD} = $sigchld;
 216                 # too many tests to fit in the pipe before starting workers,
 217                 # send the rest now the workers are running
 218                 print $wr join('', map { pack('I', $_) } ($n..$#todo)) or DIE;
 219                 undef $wr;
 220         }
 221
 222         $sigchld->(0) while scalar(keys(%pids));
 223         DIE join('', map { "E: $_\n" } @err) if @err;
 224 }
 225
 226 print $OLDOUT "1..".($repeat * scalar(@tests))."\n" if $repeat >= 0;
 227 if ($lei_env && $$ == $owner_pid) {
 228         my $opt = { 1 => $OLDOUT, 2 => $OLDERR };
 229         run_script([qw(lei daemon-kill)], $lei_env, $opt);
 230 }