t/search-thr-index.t

   1 # Copyright (C) 2017-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use bytes (); # only for bytes::length
   6 use Test::More;
   7 use File::Temp qw/tempdir/;
   8 use PublicInbox::MID qw(mids);
   9 use Email::MIME;
  10 eval { require Search::Xapian };
  11 plan skip_all => "Search::Xapian missing for search" if $@;
  12 require PublicInbox::SearchIdx;
  13 my $tmpdir = tempdir('pi-search-thr-index.XXXXXX', TMPDIR => 1, CLEANUP => 1);
  14 my $git_dir = "$tmpdir/a.git";
  15
  16 is(0, system(qw(git init -q --bare), $git_dir), "git init (main)");
  17 my $rw = PublicInbox::SearchIdx->new($git_dir, 1);
  18 ok($rw, "search indexer created");
  19 my $data = <<'EOF';
  20 Subject: [RFC 00/14]
  21 Message-Id: <1-bw@g>
  22
  23 Subject: [RFC 09/14]
  24 Message-Id: <10-bw@g>
  25 In-Reply-To: <1-bw@g>
  26 References: <1-bw@g>
  27
  28 Subject: [RFC 03/14]
  29 Message-Id: <4-bw@g>
  30 In-Reply-To: <1-bw@g>
  31 References: <1-bw@g>
  32
  33 EOF
  34
  35 my $num = 0;
  36 # nb. using internal API, fragile!
  37 my $xdb = $rw->begin_txn_lazy;
  38 my @mids;
  39
  40 foreach (reverse split(/\n\n/, $data)) {
  41         $_ .= "\n";
  42         my $mime = Email::MIME->new(\$_);
  43         $mime->header_set('From' => 'bw@g');
  44         $mime->header_set('To' => 'git@vger.kernel.org');
  45         my $bytes = bytes::length($mime->as_string);
  46         my $mid = mids($mime->header_obj)->[0];
  47         my $doc_id = $rw->add_message($mime, $bytes, ++$num, 'ignored', $mid);
  48         push @mids, $mid;
  49         ok($doc_id, 'message added: '. $mid);
  50 }
  51
  52 my $prev;
  53 my %tids;
  54 my $dbh = $rw->{over}->connect;
  55 foreach my $mid (@mids) {
  56         my $msgs = $rw->{over}->get_thread($mid);
  57         is(3, scalar(@$msgs), "got all messages from $mid");
  58         foreach my $m (@$msgs) {
  59                 my $tid = $dbh->selectrow_array(<<'', undef, $m->{num});
  60 SELECT tid FROM over WHERE num = ? LIMIT 1
  61
  62                 $tids{$tid}++;
  63         }
  64 }
  65
  66 is(scalar keys %tids, 1, 'all messages have the same tid');
  67
  68 $rw->commit_txn_lazy;
  69
  70 $xdb = $rw->begin_txn_lazy;
  71 {
  72         my $mime = Email::MIME->new(<<'');
  73 Subject: [RFC 00/14]
  74 Message-Id: <1-bw@g>
  75 From: bw@g
  76 To: git@vger.kernel.org
  77
  78         my $dbh = $rw->{over}->connect;
  79         my ($id, $prev);
  80         my $reidx = $rw->{over}->next_by_mid('1-bw@g', \$id, \$prev);
  81         ok(defined $reidx);
  82         my $num = $reidx->{num};
  83         my $tid0 = $dbh->selectrow_array(<<'', undef, $num);
  84 SELECT tid FROM over WHERE num = ? LIMIT 1
  85
  86         my $bytes = bytes::length($mime->as_string);
  87         my $mid = mids($mime->header_obj)->[0];
  88         my $doc_id = $rw->add_message($mime, $bytes, $num, 'ignored', $mid);
  89         ok($doc_id, 'message reindexed'. $mid);
  90         is($doc_id, $num, "article number unchanged: $num");
  91
  92         my $tid1 = $dbh->selectrow_array(<<'', undef, $num);
  93 SELECT tid FROM over WHERE num = ? LIMIT 1
  94
  95         is($tid1, $tid0, 'tid unchanged on reindex');
  96 }
  97
  98 $rw->commit_txn_lazy;
  99
 100 done_testing();
 101
 102 1;