t/search-thr-index.t

   1 # Copyright (C) 2017-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use bytes (); # only for bytes::length
   6 use Test::More;
   7 use File::Temp qw/tempdir/;
   8 use PublicInbox::MID qw(mids);
   9 use Email::MIME;
  10 my @mods = qw(DBI DBD::SQLite Search::Xapian);
  11 foreach my $mod (@mods) {
  12         eval "require $mod";
  13         plan skip_all => "missing $mod for $0" if $@;
  14 }
  15 require PublicInbox::SearchIdx;
  16 my $tmpdir = tempdir('pi-search-thr-index.XXXXXX', TMPDIR => 1, CLEANUP => 1);
  17 my $git_dir = "$tmpdir/a.git";
  18
  19 is(0, system(qw(git init -q --bare), $git_dir), "git init (main)");
  20 my $rw = PublicInbox::SearchIdx->new($git_dir, 1);
  21 ok($rw, "search indexer created");
  22 my $data = <<'EOF';
  23 Subject: [RFC 00/14]
  24 Message-Id: <1-bw@g>
  25
  26 Subject: [RFC 09/14]
  27 Message-Id: <10-bw@g>
  28 In-Reply-To: <1-bw@g>
  29 References: <1-bw@g>
  30
  31 Subject: [RFC 03/14]
  32 Message-Id: <4-bw@g>
  33 In-Reply-To: <1-bw@g>
  34 References: <1-bw@g>
  35
  36 EOF
  37
  38 my $num = 0;
  39 # nb. using internal API, fragile!
  40 my $xdb = $rw->begin_txn_lazy;
  41 my @mids;
  42
  43 foreach (reverse split(/\n\n/, $data)) {
  44         $_ .= "\n";
  45         my $mime = Email::MIME->new(\$_);
  46         $mime->header_set('From' => 'bw@g');
  47         $mime->header_set('To' => 'git@vger.kernel.org');
  48         my $bytes = bytes::length($mime->as_string);
  49         my $mid = mids($mime->header_obj)->[0];
  50         my $doc_id = $rw->add_message($mime, $bytes, ++$num, 'ignored', $mid);
  51         push @mids, $mid;
  52         ok($doc_id, 'message added: '. $mid);
  53 }
  54
  55 my $prev;
  56 my %tids;
  57 my $dbh = $rw->{over}->connect;
  58 foreach my $mid (@mids) {
  59         my $msgs = $rw->{over}->get_thread($mid);
  60         is(3, scalar(@$msgs), "got all messages from $mid");
  61         foreach my $m (@$msgs) {
  62                 my $tid = $dbh->selectrow_array(<<'', undef, $m->{num});
  63 SELECT tid FROM over WHERE num = ? LIMIT 1
  64
  65                 $tids{$tid}++;
  66         }
  67 }
  68
  69 is(scalar keys %tids, 1, 'all messages have the same tid');
  70
  71 $rw->commit_txn_lazy;
  72
  73 $xdb = $rw->begin_txn_lazy;
  74 {
  75         my $mime = Email::MIME->new(<<'');
  76 Subject: [RFC 00/14]
  77 Message-Id: <1-bw@g>
  78 From: bw@g
  79 To: git@vger.kernel.org
  80
  81         my $dbh = $rw->{over}->connect;
  82         my ($id, $prev);
  83         my $reidx = $rw->{over}->next_by_mid('1-bw@g', \$id, \$prev);
  84         ok(defined $reidx);
  85         my $num = $reidx->{num};
  86         my $tid0 = $dbh->selectrow_array(<<'', undef, $num);
  87 SELECT tid FROM over WHERE num = ? LIMIT 1
  88
  89         my $bytes = bytes::length($mime->as_string);
  90         my $mid = mids($mime->header_obj)->[0];
  91         my $doc_id = $rw->add_message($mime, $bytes, $num, 'ignored', $mid);
  92         ok($doc_id, 'message reindexed'. $mid);
  93         is($doc_id, $num, "article number unchanged: $num");
  94
  95         my $tid1 = $dbh->selectrow_array(<<'', undef, $num);
  96 SELECT tid FROM over WHERE num = ? LIMIT 1
  97
  98         is($tid1, $tid0, 'tid unchanged on reindex');
  99 }
 100
 101 $rw->commit_txn_lazy;
 102
 103 done_testing();
 104
 105 1;