t/search.t

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use File::Temp qw/tempdir/;
   7 use PublicInbox::Search;
   8 use Email::MIME;
   9 use Data::Dumper;
  10 my $tmpdir = tempdir(CLEANUP => 1);
  11 my $git_dir = "$tmpdir/a.git";
  12 my ($root_id, $last_id);
  13
  14 is(0, system(qw(git init -q --bare), $git_dir), "git init (main)");
  15 eval { PublicInbox::Search->new($git_dir) };
  16 ok($@, "exception raised on non-existent DB");
  17
  18 my $rw = PublicInbox::Search->new($git_dir, 1);
  19 my $ro = PublicInbox::Search->new($git_dir);
  20
  21 {
  22         my $root = Email::MIME->create(
  23                 header_str => [
  24                         Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  25                         Subject => 'hello world',
  26                         'Message-ID' => '<root@s>',
  27                         From => 'John Smith <js@example.com>',
  28                         To => 'list@example.com',
  29                 ],
  30                 body => "\\m/\n");
  31         my $last = Email::MIME->create(
  32                 header_str => [
  33                         Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
  34                         Subject => 'Re: hello world',
  35                         'In-Reply-To' => '<root@s>',
  36                         'Message-ID' => '<last@s>',
  37                         From => 'John Smith <js@example.com>',
  38                         To => 'list@example.com',
  39                 ],
  40                 body => "goodbye forever :<\n");
  41
  42         my $rv;
  43         $root_id = $rw->add_message($root);
  44         is($root_id, int($root_id), "root_id is an integer: $root_id");
  45         $last_id = $rw->add_message($last);
  46         is($last_id, int($last_id), "last_id is an integer: $last_id");
  47 }
  48
  49 sub filter_mids {
  50         my ($res) = @_;
  51         sort(map { (split(/\n/, $_))[0] } @{$res->{msgs}});
  52 }
  53
  54 {
  55         $ro->reopen;
  56         my $found = $ro->lookup_message('<root@s>');
  57         ok($found, "message found");
  58         is($root_id, $found->{doc_id}, 'doc_id set correctly');
  59         $found->ensure_metadata;
  60         is($found->mid, 'root@s', 'mid set correctly');
  61         ok(int($found->thread_id) > 0, 'thread_id is an integer');
  62
  63         my @exp = sort qw(root@s last@s);
  64         my $res = $ro->query("path:hello_world");
  65         my @res = filter_mids($res);
  66         is_deeply(\@res, \@exp, 'got expected results for path: match');
  67
  68         foreach my $p (qw(hello hello_ hello_world2 hello_world_)) {
  69                 $res = $ro->query("path:$p");
  70                 is($res->{count}, 0, "path variant `$p' does not match");
  71         }
  72
  73         $res = $ro->query('subject:(hello world)');
  74         @res = filter_mids($res);
  75         is_deeply(\@res, \@exp, 'got expected results for subject:() match');
  76
  77         $res = $ro->query('subject:"hello world"');
  78         @res = filter_mids($res);
  79         is_deeply(\@res, \@exp, 'got expected results for subject:"" match');
  80
  81         $res = $ro->query('subject:"hello world"', {limit => 1});
  82         is(scalar @{$res->{msgs}}, 1, "limit works");
  83         my $first = $res->{msgs}->[0];
  84
  85         $res = $ro->query('subject:"hello world"', {offset => 1});
  86         is(scalar @{$res->{msgs}}, 1, "offset works");
  87         my $second = $res->{msgs}->[0];
  88
  89         isnt($first, $second, "offset returned different result from limit");
  90
  91         foreach my $f (qw(inreplyto references)) {
  92                 $res = $ro->query($f . ':root@s');
  93                 @res = filter_mids($res);
  94                 is_deeply(\@res, [ 'last@s' ],
  95                           "got expected results for $f: match");
  96                 $res = $ro->query($f . ':root');
  97                 is($res->{count}, 0, "no partial mid match");
  98         }
  99 }
 100
 101 # ghost vivication
 102 {
 103         $rw->reopen;
 104         my $rmid = '<ghost-message@s>';
 105         my $reply_to_ghost = Email::MIME->create(
 106                 header_str => [
 107                         Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
 108                         Subject => 'Re: ghosts',
 109                         'Message-ID' => '<ghost-reply@s>',
 110                         'In-Reply-To' => $rmid,
 111                         From => 'Time Traveler <tt@example.com>',
 112                         To => 'list@example.com',
 113                 ],
 114                 body => "-_-\n");
 115
 116         my $rv;
 117         my $reply_id = $rw->add_message($reply_to_ghost);
 118         is($reply_id, int($reply_id), "reply_id is an integer: $reply_id");
 119
 120         my $was_ghost = Email::MIME->create(
 121                 header_str => [
 122                         Date => 'Sat, 02 Oct 2010 00:00:01 +0000',
 123                         Subject => 'ghosts',
 124                         'Message-ID' => $rmid,
 125                         From => 'Laggy Sender <lag@example.com>',
 126                         To => 'list@example.com',
 127                 ],
 128                 body => "are real\n");
 129
 130         my $ghost_id = $rw->add_message($was_ghost);
 131         is($ghost_id, int($ghost_id), "ghost_id is an integer: $ghost_id");
 132         ok($ghost_id < $reply_id, "ghost vivified from earlier message");
 133 }
 134
 135 # search thread on ghost
 136 {
 137         $ro->reopen;
 138
 139         # Subject:
 140         my $res = $ro->query('ghost');
 141         my @exp = sort qw(ghost-message@s ghost-reply@s);
 142         my @res = filter_mids($res);
 143         is_deeply(\@res, \@exp, 'got expected results for Subject match');
 144
 145         # body
 146         $res = $ro->query('goodbye');
 147         is((split(/\n/, $res->{msgs}->[0]))[0], 'last@s',
 148            'got goodbye message body');
 149 }
 150
 151 # long message-id
 152 {
 153         $rw->reopen;
 154         $ro->reopen;
 155         my $long_mid = 'last' . ('x' x 60). '@s';
 156         my $long_midc = Digest::SHA::sha1_hex($long_mid);
 157
 158         my $long = Email::MIME->create(
 159                 header_str => [
 160                         Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
 161                         Subject => 'long message ID',
 162                         'References' => '<root@s> <last@s>',
 163                         'In-Reply-To' => '<last@s>',
 164                         'Message-ID' => "<$long_mid>",
 165                         From => '"Long I.D." <long-id@example.com>',
 166                         To => 'list@example.com',
 167                 ],
 168                 body => "wut\n");
 169         my $long_id = $rw->add_message($long);
 170         is($long_id, int($long_id), "long_id is an integer: $long_id");
 171
 172         $ro->reopen;
 173         my $res = $ro->query('references:root@s');
 174         my @res = filter_mids($res);
 175         is_deeply(\@res, [ sort('last@s', $long_midc) ],
 176                   "got expected results for references: match");
 177
 178         my $replies = $ro->get_replies('root@s');
 179         $replies = [ filter_mids($replies) ];
 180         is_deeply($replies, [ filter_mids($res) ], "get_replies matches");
 181
 182         my $long_reply_mid = 'reply-to-long@1';
 183         my $long_reply = Email::MIME->create(
 184                 header_str => [
 185                         Subject => 'I break references',
 186                         Date => 'Sat, 02 Oct 2010 00:00:00 +0000',
 187                         'Message-ID' => "<$long_reply_mid>",
 188                         # No References:
 189                         # 'References' => '<root@s> <last@s> <'.$long_mid.'>',
 190                         'In-Reply-To' => "<$long_mid>",
 191                         From => '"no1 <no1@example.com>',
 192                         To => 'list@example.com',
 193                 ],
 194                 body => "no References\n");
 195         ok($rw->add_message($long_reply) > $long_id, "inserted long reply");
 196
 197         $ro->reopen;
 198         my $t = $ro->get_thread('root@s');
 199         is($t->{count}, 4, "got all 4 mesages in thread");
 200         my @exp = sort($long_reply_mid, 'root@s', 'last@s', $long_midc);
 201         @res = filter_mids($t);
 202         is_deeply(\@res, \@exp, "get_thread works");
 203 }
 204
 205 # quote prioritization
 206 {
 207         $rw->reopen;
 208         $rw->add_message(Email::MIME->create(
 209                 header_str => [
 210                         Date => 'Sat, 02 Oct 2010 00:00:01 +0000',
 211                         Subject => 'hello',
 212                         'Message-ID' => '<quote@a>',
 213                         From => 'Quoter <quoter@example.com>',
 214                         To => 'list@example.com',
 215                 ],
 216                 body => "> theatre illusions\nfade\n"));
 217
 218         $rw->add_message(Email::MIME->create(
 219                 header_str => [
 220                         Date => 'Sat, 02 Oct 2010 00:00:02 +0000',
 221                         Subject => 'hello',
 222                         'Message-ID' => '<nquote@a>',
 223                         From => 'Non-Quoter<non-quoter@example.com>',
 224                         To => 'list@example.com',
 225                 ],
 226                 body => "theatre\nfade\n"));
 227         my $res = $rw->query("theatre");
 228         is($res->{count}, 2, "got both matches");
 229         like($res->{msgs}->[0], qr/\Anquote\@a/, "non-quoted scores higher");
 230         like($res->{msgs}->[1], qr/\Aquote\@a/, "quoted result still returned");
 231
 232         $res = $rw->query("illusions");
 233         is($res->{count}, 1, "got a match for quoted text");
 234         like($res->{msgs}->[0], qr/\Aquote\@a/,
 235                 "quoted result returned if nothing else");
 236 }
 237
 238 done_testing();
 239
 240 1;