t/shared_kv.t

   1 #!perl -w
   2 # Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use Test::More;
   7 use PublicInbox::TestCommon;
   8 use_ok 'PublicInbox::SharedKV';
   9 my ($tmpdir, $for_destroy) = tmpdir();
  10 local $ENV{TMPDIR} = $tmpdir;
  11 my $skv = PublicInbox::SharedKV->new;
  12 my $skv_tmpdir = $skv->{"tmp$$.$skv"};
  13 ok(-d $skv_tmpdir, 'created a temporary dir');
  14 $skv->dbh;
  15 my $dead = "\xde\xad";
  16 my $beef = "\xbe\xef";
  17 my $cafe = "\xca\xfe";
  18 ok($skv->set($dead, $beef), 'set');
  19 is($skv->get($dead), $beef, 'get');
  20 ok($skv->set($dead, $beef), 'set idempotent');
  21 ok(!$skv->set_maybe($dead, $cafe), 'set_maybe ignores');
  22 ok($skv->set_maybe($cafe, $dead), 'set_maybe sets');
  23 is($skv->xchg($dead, $cafe), $beef, 'xchg');
  24 is($skv->get($dead), $cafe, 'get after xchg');
  25 is($skv->xchg($dead, undef), $cafe, 'xchg to undef');
  26 is($skv->get($dead), undef, 'get after xchg to undef');
  27 is($skv->get($cafe), $dead, 'get after set_maybe');
  28 ok($skv->index_values, 'index_values works');
  29 is($skv->replace_values($dead, $cafe), 1, 'replaced one by value');
  30 is($skv->get($cafe), $cafe, 'value updated');
  31 is($skv->replace_values($dead, $cafe), 0, 'replaced none by value');
  32 is($skv->xchg($dead, $cafe), undef, 'xchg from undef');
  33 is($skv->count, 2, 'count works');
  34
  35 my %seen;
  36 my $sth = $skv->each_kv_iter;
  37 while (my ($k, $v) = $sth->fetchrow_array) {
  38         $seen{$k} = $v;
  39 }
  40 is($seen{$dead}, $cafe, '$dead has expected value');
  41 is($seen{$cafe}, $cafe, '$cafe has expected value');
  42 is(scalar keys %seen, 2, 'iterated through all');
  43
  44 is($skv->replace_values($cafe, $dead), 2, 'replaced 2 by value');
  45 is($skv->delete_by_val('bogus'), 0, 'delete_by_val misses');
  46 is($skv->delete_by_val($dead), 2, 'delete_by_val hits');
  47 is($skv->delete_by_val($dead), 0, 'delete_by_val misses again');
  48
  49 undef $skv;
  50 ok(!-d $skv_tmpdir, 'temporary dir gone');
  51 $skv = PublicInbox::SharedKV->new("$tmpdir/dir", 'base');
  52 ok(-e "$tmpdir/dir/base.sqlite3", 'file created');
  53
  54 done_testing;