t/solver_git.t

   1 #!perl -w
   2 # Copyright (C) 2019-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 use Cwd qw(abs_path);
   8 require_git(2.6);
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use PublicInbox::Spawn qw(popen_rd which);
  11 require_mods(qw(DBD::SQLite Search::Xapian Plack::Util));
  12 my $git_dir = xqx([qw(git rev-parse --git-dir)], undef, {2 => \(my $null)});
  13 $? == 0 or plan skip_all => "$0 must be run from a git working tree";
  14 chomp $git_dir;
  15
  16 # needed for alternates, and --absolute-git-dir is only in git 2.13+
  17 $git_dir = abs_path($git_dir);
  18
  19 use_ok "PublicInbox::$_" for (qw(Inbox V2Writable Git SolverGit WWW));
  20 my $patch2 = eml_load 't/solve/0002-rename-with-modifications.patch';
  21 my $patch2_oid = git_sha(1, $patch2)->hexdigest;
  22
  23 my ($tmpdir, $for_destroy) = tmpdir();
  24 my $ibx = create_inbox 'v2', version => 2,
  25                         indexlevel => 'medium', sub {
  26         my ($im) = @_;
  27         $im->add(eml_load 't/solve/0001-simple-mod.patch') or BAIL_OUT;
  28         $im->add($patch2) or BAIL_OUT;
  29 };
  30 my $md = "$tmpdir/md";
  31 File::Path::mkpath([map { $md.$_ } (qw(/ /cur /new /tmp))]);
  32 symlink(abs_path('t/solve/0001-simple-mod.patch'), "$md/cur/foo:2,") or
  33         xbail "symlink: $!";
  34
  35 my $v1_0_0_tag = 'cb7c42b1e15577ed2215356a2bf925aef59cdd8d';
  36 my $v1_0_0_tag_short = substr($v1_0_0_tag, 0, 16);
  37 my $expect = '69df7d565d49fbaaeb0a067910f03dc22cd52bd0';
  38 my $non_existent = 'ee5e32211bf62ab6531bdf39b84b6920d0b6775a';
  39
  40 test_lei({tmpdir => "$tmpdir/blob"}, sub {
  41         lei_ok('blob', '--mail', $patch2_oid, '-I', $ibx->{inboxdir},
  42                 \'--mail works for existing oid');
  43         is($lei_out, $patch2->as_string, 'blob matches');
  44         ok(!lei('blob', '--mail', '69df7d5', '-I', $ibx->{inboxdir}),
  45                 "--mail won't run solver");
  46
  47         lei_ok('blob', '69df7d5', '-I', $ibx->{inboxdir});
  48         is(git_sha(1, \$lei_out)->hexdigest, $expect, 'blob contents output');
  49         my $prev = $lei_out;
  50         lei_ok(qw(blob --no-mail 69df7d5 -I), $ibx->{inboxdir});
  51         is($lei_out, $prev, '--no-mail works');
  52         ok(!lei(qw(blob -I), $ibx->{inboxdir}, $non_existent),
  53                         'non-existent blob fails');
  54         SKIP: {
  55                 skip '/.git exists', 1 if -e '/.git';
  56                 lei_ok(qw(-C / blob 69df7d5 -I), $ibx->{inboxdir},
  57                         "--git-dir=$git_dir");
  58                 is($lei_out, $prev, '--git-dir works');
  59
  60                 ok(!lei(qw(-C / blob --no-cwd 69df7d5 -I), $ibx->{inboxdir}),
  61                         '--no-cwd works');
  62
  63                 ok(!lei(qw(-C / blob -I), $ibx->{inboxdir}, $non_existent),
  64                         'non-existent blob fails');
  65         }
  66
  67         # fallbacks
  68         lei_ok('blob', $v1_0_0_tag, '-I', $ibx->{inboxdir});
  69         lei_ok('blob', $v1_0_0_tag_short, '-I', $ibx->{inboxdir});
  70 });
  71
  72 test_lei({tmpdir => "$tmpdir/rediff"}, sub {
  73         lei_ok(qw(rediff -q -U9 t/solve/0001-simple-mod.patch));
  74         like($lei_out, qr!^\Q+++\E b/TODO\n@@ -103,9 \+103,11 @@!sm,
  75                 'got more context with -U9');
  76         lei_ok(qw(rediff -q -U9 t/solve/bare.patch));
  77         my $exp = <<'EOM';
  78 diff --git a/script/public-inbox-extindex b/script/public-inbox-extindex
  79 old mode 100644
  80 new mode 100755
  81 index 15ac20eb..771486c4
  82 --- a/script/public-inbox-extindex
  83 +++ b/script/public-inbox-extindex
  84 @@ -1,13 +1,12 @@
  85  #!perl -w
  86 EOM
  87         ok(index($lei_out, $exp) >= 0,
  88                 'preserve mode, regen header + context from -U0 patch');
  89 });
  90
  91 test_lei({tmpdir => "$tmpdir/index-eml-only"}, sub {
  92         lei_ok(qw(index), $md);
  93         lei_ok(qw(blob 69df7d5)); # hits LeiSearch->smsg_eml -> lms->local_blob
  94 });
  95
  96 my $git = PublicInbox::Git->new($git_dir);
  97 $ibx->{-repo_objs} = [ $git ];
  98 my $res;
  99 my $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 100 open my $log, '+>>', "$tmpdir/solve.log" or die "open: $!";
 101 my $psgi_env = { 'psgi.errors' => \*STDERR, 'psgi.url_scheme' => 'http',
 102                 'HTTP_HOST' => 'example.com' };
 103 $solver->solve($psgi_env, $log, '69df7d5', {});
 104 ok($res, 'solved a blob!');
 105 my $wt_git = $res->[0];
 106 is(ref($wt_git), 'PublicInbox::Git', 'got a git object for the blob');
 107 is($res->[1], $expect, 'resolved blob to unabbreviated identifier');
 108 is($res->[2], 'blob', 'type specified');
 109 is($res->[3], 4405, 'size returned');
 110
 111 is(ref($wt_git->cat_file($res->[1])), 'SCALAR', 'wt cat-file works');
 112 is_deeply([$expect, 'blob', 4405],
 113           [$wt_git->check($res->[1])], 'wt check works');
 114
 115 my $oid = $expect;
 116 for my $i (1..2) {
 117         my $more;
 118         my $s = PublicInbox::SolverGit->new($ibx, sub { $more = $_[0] });
 119         $s->solve($psgi_env, $log, $oid, {});
 120         is($more->[1], $expect, 'resolved blob to long OID '.$i);
 121         chop($oid);
 122 }
 123
 124 $solver = undef;
 125 $res = undef;
 126 my $wt_git_dir = $wt_git->{git_dir};
 127 $wt_git = undef;
 128 ok(!-d $wt_git_dir, 'no references to WT held');
 129
 130 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 131 $solver->solve($psgi_env, $log, '0'x40, {});
 132 is($res, undef, 'no error on z40');
 133
 134 my $git_v2_20_1_tag = '7a95a1cd084cb665c5c2586a415e42df0213af74';
 135 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 136 $solver->solve($psgi_env, $log, $git_v2_20_1_tag, {});
 137 is($res, undef, 'no error on a tag not in our repo');
 138
 139 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 140 $solver->solve($psgi_env, $log, '0a92431', {});
 141 ok($res, 'resolved without hints');
 142
 143 my $hints = {
 144         oid_a => '3435775',
 145         path_a => 'HACKING',
 146         path_b => 'CONTRIBUTING'
 147 };
 148 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 149 $solver->solve($psgi_env, $log, '0a92431', $hints);
 150 my $hinted = $res;
 151 # don't compare ::Git objects:
 152 shift @$res; shift @$hinted;
 153 is_deeply($res, $hinted, 'hints work (or did not hurt :P');
 154
 155 my @psgi = qw(HTTP::Request::Common Plack::Test URI::Escape Plack::Builder);
 156 SKIP: {
 157         require_mods(@psgi, 7 + scalar(@psgi));
 158         use_ok($_) for @psgi;
 159         my $binfoo = "$ibx->{inboxdir}/binfoo.git";
 160         my $l = "$ibx->{inboxdir}/inbox.lock";
 161         -f $l or BAIL_OUT "BUG: $l missing: $!";
 162         require_ok 'PublicInbox::ViewVCS';
 163         my $big_size = do {
 164                 no warnings 'once';
 165                 $PublicInbox::ViewVCS::MAX_SIZE + 1;
 166         };
 167         my %bin = (big => $big_size, small => 1);
 168         my %oid; # (small|big) => OID
 169         my $lk = bless { lock_path => $l }, 'PublicInbox::Lock';
 170         my $acq = $lk->lock_for_scope;
 171         my $stamp = "$binfoo/stamp";
 172         if (open my $fh, '<', $stamp) {
 173                 %oid = map { chomp; split(/=/, $_) } (<$fh>);
 174         } else {
 175                 PublicInbox::Import::init_bare($binfoo);
 176                 my $cmd = [ qw(git hash-object -w --stdin) ];
 177                 my $env = { GIT_DIR => $binfoo };
 178                 open my $fh, '>', "$stamp.$$" or BAIL_OUT;
 179                 while (my ($label, $size) = each %bin) {
 180                         pipe(my ($rin, $win)) or BAIL_OUT;
 181                         my $rout = popen_rd($cmd , $env, { 0 => $rin });
 182                         $rin = undef;
 183                         print { $win } ("\0" x $size) or BAIL_OUT;
 184                         close $win or BAIL_OUT;
 185                         chomp(my $x = <$rout>);
 186                         close $rout or BAIL_OUT "$?";
 187                         print $fh "$label=$x\n" or BAIL_OUT;
 188                         $oid{$label} = $x;
 189                 }
 190                 close $fh or BAIL_OUT;
 191                 rename("$stamp.$$", $stamp) or BAIL_OUT;
 192         }
 193         undef $acq;
 194         # ensure the PSGI frontend (ViewVCS) works:
 195         my $name = $ibx->{name};
 196         my $cfgpfx = "publicinbox.$name";
 197         my $cfgpath = "$tmpdir/httpd-config";
 198         open my $cfgfh, '>', $cfgpath or die;
 199         print $cfgfh <<EOF or die;
 200 [publicinbox "$name"]
 201         address = $ibx->{-primary_address}
 202         inboxdir = $ibx->{inboxdir}
 203         coderepo = public-inbox
 204         coderepo = binfoo
 205         url = http://example.com/$name
 206 [coderepo "public-inbox"]
 207         dir = $git_dir
 208         cgiturl = http://example.com/public-inbox
 209 [coderepo "binfoo"]
 210         dir = $binfoo
 211         cgiturl = http://example.com/binfoo
 212 EOF
 213         close $cfgfh or die;
 214         my $cfg = PublicInbox::Config->new($cfgpath);
 215         my $www = PublicInbox::WWW->new($cfg);
 216         my $client = sub {
 217                 my ($cb) = @_;
 218                 my $mid = '20190401081523.16213-1-BOFH@YHBT.net';
 219                 my @warn;
 220                 my $res = do {
 221                         local $SIG{__WARN__} = sub { push @warn, @_ };
 222                         $cb->(GET("/$name/$mid/"));
 223                 };
 224                 is_deeply(\@warn, [], 'no warnings from rendering diff');
 225                 like($res->content, qr!>&#937;</a>!, 'omega escaped');
 226
 227                 $res = $cb->(GET("/$name/3435775/s/"));
 228                 is($res->code, 200, 'success with existing blob');
 229
 230                 $res = $cb->(GET("/$name/".('0'x40).'/s/'));
 231                 is($res->code, 404, 'failure with null OID');
 232
 233                 $res = $cb->(GET("/$name/$non_existent/s/"));
 234                 is($res->code, 404, 'failure with null OID');
 235
 236                 $res = $cb->(GET("/$name/$v1_0_0_tag/s/"));
 237                 is($res->code, 200, 'shows commit (unabbreviated)');
 238                 $res = $cb->(GET("/$name/$v1_0_0_tag_short/s/"));
 239                 is($res->code, 200, 'shows commit (abbreviated)');
 240                 while (my ($label, $size) = each %bin) {
 241                         $res = $cb->(GET("/$name/$oid{$label}/s/"));
 242                         is($res->code, 200, "$label binary file");
 243                         ok(index($res->content, "blob $size bytes") >= 0,
 244                                 "showed $label binary blob size");
 245                         $res = $cb->(GET("/$name/$oid{$label}/s/raw"));
 246                         is($res->code, 200, "$label raw binary download");
 247                         is($res->content, "\0" x $size,
 248                                 "$label content matches");
 249                 }
 250         };
 251         test_psgi(sub { $www->call(@_) }, $client);
 252         SKIP: {
 253                 require_mods(qw(Plack::Test::ExternalServer), 7);
 254                 my $env = { PI_CONFIG => $cfgpath };
 255                 my $sock = tcp_server() or die;
 256                 my ($out, $err) = map { "$tmpdir/std$_.log" } qw(out err);
 257                 my $cmd = [ qw(-httpd -W0), "--stdout=$out", "--stderr=$err" ];
 258                 my $td = start_script($cmd, $env, { 3 => $sock });
 259                 my ($h, $p) = tcp_host_port($sock);
 260                 my $url = "http://$h:$p";
 261                 local $ENV{PLACK_TEST_EXTERNALSERVER_URI} = $url;
 262                 Plack::Test::ExternalServer::test_psgi(client => $client);
 263                 skip 'no curl', 1 unless which('curl');
 264
 265                 mkdir "$tmpdir/ext" // xbail "mkdir $!";
 266                 test_lei({tmpdir => "$tmpdir/ext"}, sub {
 267                         my $rurl = "$url/$name";
 268                         lei_ok(qw(blob --no-mail 69df7d5 -I), $rurl);
 269                         is(git_sha(1, \$lei_out)->hexdigest, $expect,
 270                                 'blob contents output');
 271                         ok(!lei(qw(blob -I), $rurl, $non_existent),
 272                                         'non-existent blob fails');
 273                 });
 274         }
 275 }
 276
 277 done_testing();