t/solver_git.t

   1 #!perl -w
   2 # Copyright (C) 2019-2021 all contributors <meta@public-inbox.org>
   3 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   4 use strict;
   5 use v5.10.1;
   6 use PublicInbox::TestCommon;
   7 use Cwd qw(abs_path);
   8 require_git(2.6);
   9 use PublicInbox::ContentHash qw(git_sha);
  10 use PublicInbox::Spawn qw(popen_rd which);
  11 require_mods(qw(DBD::SQLite Search::Xapian Plack::Util));
  12 my $git_dir = xqx([qw(git rev-parse --git-dir)], undef, {2 => \(my $null)});
  13 $? == 0 or plan skip_all => "$0 must be run from a git working tree";
  14 chomp $git_dir;
  15
  16 # needed for alternates, and --absolute-git-dir is only in git 2.13+
  17 $git_dir = abs_path($git_dir);
  18
  19 use_ok "PublicInbox::$_" for (qw(Inbox V2Writable Git SolverGit WWW));
  20 my $patch2 = eml_load 't/solve/0002-rename-with-modifications.patch';
  21 my $patch2_oid = git_sha(1, $patch2)->hexdigest;
  22
  23 my ($tmpdir, $for_destroy) = tmpdir();
  24 my $ibx = create_inbox 'v2', version => 2,
  25                         indexlevel => 'medium', sub {
  26         my ($im) = @_;
  27         $im->add(eml_load 't/solve/0001-simple-mod.patch') or BAIL_OUT;
  28         $im->add($patch2) or BAIL_OUT;
  29 };
  30 my $md = "$tmpdir/md";
  31 File::Path::mkpath([map { $md.$_ } (qw(/ /cur /new /tmp))]);
  32 symlink(abs_path('t/solve/0001-simple-mod.patch'), "$md/cur/foo:2,") or
  33         xbail "symlink: $!";
  34
  35 my $v1_0_0_tag = 'cb7c42b1e15577ed2215356a2bf925aef59cdd8d';
  36 my $v1_0_0_tag_short = substr($v1_0_0_tag, 0, 16);
  37 my $expect = '69df7d565d49fbaaeb0a067910f03dc22cd52bd0';
  38 my $non_existent = 'ee5e32211bf62ab6531bdf39b84b6920d0b6775a';
  39
  40 test_lei({tmpdir => "$tmpdir/blob"}, sub {
  41         lei_ok('blob', '--mail', $patch2_oid, '-I', $ibx->{inboxdir},
  42                 \'--mail works for existing oid');
  43         is($lei_out, $patch2->as_string, 'blob matches');
  44         ok(!lei('blob', '--mail', '69df7d5', '-I', $ibx->{inboxdir}),
  45                 "--mail won't run solver");
  46
  47         lei_ok('blob', '69df7d5', '-I', $ibx->{inboxdir});
  48         is(git_sha(1, \$lei_out)->hexdigest, $expect, 'blob contents output');
  49         my $prev = $lei_out;
  50         lei_ok(qw(blob --no-mail 69df7d5 -I), $ibx->{inboxdir});
  51         is($lei_out, $prev, '--no-mail works');
  52         ok(!lei(qw(blob -I), $ibx->{inboxdir}, $non_existent),
  53                         'non-existent blob fails');
  54         SKIP: {
  55                 skip '/.git exists', 1 if -e '/.git';
  56                 lei_ok(qw(-C / blob 69df7d5 -I), $ibx->{inboxdir},
  57                         "--git-dir=$git_dir");
  58                 is($lei_out, $prev, '--git-dir works');
  59
  60                 ok(!lei(qw(-C / blob --no-cwd 69df7d5 -I), $ibx->{inboxdir}),
  61                         '--no-cwd works');
  62
  63                 ok(!lei(qw(-C / blob -I), $ibx->{inboxdir}, $non_existent),
  64                         'non-existent blob fails');
  65         }
  66
  67         # fallbacks
  68         lei_ok('blob', $v1_0_0_tag, '-I', $ibx->{inboxdir});
  69         lei_ok('blob', $v1_0_0_tag_short, '-I', $ibx->{inboxdir});
  70 });
  71
  72 test_lei({tmpdir => "$tmpdir/rediff"}, sub {
  73         lei_ok(qw(rediff -q -U9 t/solve/0001-simple-mod.patch));
  74         like($lei_out, qr!^\Q+++\E b/TODO\n@@ -103,9 \+103,11 @@!sm,
  75                 'got more context with -U9');
  76         lei_ok(qw(rediff -q -U9 t/solve/bare.patch));
  77         my $exp = <<'EOM';
  78 diff --git a/script/public-inbox-extindex b/script/public-inbox-extindex
  79 old mode 100644
  80 new mode 100755
  81 index 15ac20eb..771486c4
  82 --- a/script/public-inbox-extindex
  83 +++ b/script/public-inbox-extindex
  84 @@ -1,13 +1,12 @@
  85  #!perl -w
  86 EOM
  87         ok(index($lei_out, $exp) >= 0,
  88                 'preserve mode, regen header + context from -U0 patch');
  89         my $e = { GIT_DIR => "$ENV{HOME}/.local/share/lei/store/ALL.git" };
  90         my @x = xqx([qw(git cat-file --batch-all-objects --batch-check)], $e);
  91         is_deeply(\@x, [], 'no objects stored') or diag explain(\@x);
  92 });
  93
  94 test_lei({tmpdir => "$tmpdir/index-eml-only"}, sub {
  95         lei_ok(qw(index), $md);
  96         lei_ok(qw(blob 69df7d5)); # hits LeiSearch->smsg_eml -> lms->local_blob
  97 });
  98
  99 my $git = PublicInbox::Git->new($git_dir);
 100 $ibx->{-repo_objs} = [ $git ];
 101 my $res;
 102 my $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 103 open my $log, '+>>', "$tmpdir/solve.log" or die "open: $!";
 104 my $psgi_env = { 'psgi.errors' => \*STDERR, 'psgi.url_scheme' => 'http',
 105                 'HTTP_HOST' => 'example.com' };
 106 $solver->solve($psgi_env, $log, '69df7d5', {});
 107 ok($res, 'solved a blob!');
 108 my $wt_git = $res->[0];
 109 is(ref($wt_git), 'PublicInbox::Git', 'got a git object for the blob');
 110 is($res->[1], $expect, 'resolved blob to unabbreviated identifier');
 111 is($res->[2], 'blob', 'type specified');
 112 is($res->[3], 4405, 'size returned');
 113
 114 is(ref($wt_git->cat_file($res->[1])), 'SCALAR', 'wt cat-file works');
 115 is_deeply([$expect, 'blob', 4405],
 116           [$wt_git->check($res->[1])], 'wt check works');
 117
 118 my $oid = $expect;
 119 for my $i (1..2) {
 120         my $more;
 121         my $s = PublicInbox::SolverGit->new($ibx, sub { $more = $_[0] });
 122         $s->solve($psgi_env, $log, $oid, {});
 123         is($more->[1], $expect, 'resolved blob to long OID '.$i);
 124         chop($oid);
 125 }
 126
 127 $solver = undef;
 128 $res = undef;
 129 my $wt_git_dir = $wt_git->{git_dir};
 130 $wt_git = undef;
 131 ok(!-d $wt_git_dir, 'no references to WT held');
 132
 133 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 134 $solver->solve($psgi_env, $log, '0'x40, {});
 135 is($res, undef, 'no error on z40');
 136
 137 my $git_v2_20_1_tag = '7a95a1cd084cb665c5c2586a415e42df0213af74';
 138 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 139 $solver->solve($psgi_env, $log, $git_v2_20_1_tag, {});
 140 is($res, undef, 'no error on a tag not in our repo');
 141
 142 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 143 $solver->solve($psgi_env, $log, '0a92431', {});
 144 ok($res, 'resolved without hints');
 145
 146 my $hints = {
 147         oid_a => '3435775',
 148         path_a => 'HACKING',
 149         path_b => 'CONTRIBUTING'
 150 };
 151 $solver = PublicInbox::SolverGit->new($ibx, sub { $res = $_[0] });
 152 $solver->solve($psgi_env, $log, '0a92431', $hints);
 153 my $hinted = $res;
 154 # don't compare ::Git objects:
 155 shift @$res; shift @$hinted;
 156 is_deeply($res, $hinted, 'hints work (or did not hurt :P');
 157
 158 my @psgi = qw(HTTP::Request::Common Plack::Test URI::Escape Plack::Builder);
 159 SKIP: {
 160         require_mods(@psgi, 7 + scalar(@psgi));
 161         use_ok($_) for @psgi;
 162         my $binfoo = "$ibx->{inboxdir}/binfoo.git";
 163         my $l = "$ibx->{inboxdir}/inbox.lock";
 164         -f $l or BAIL_OUT "BUG: $l missing: $!";
 165         require_ok 'PublicInbox::ViewVCS';
 166         my $big_size = do {
 167                 no warnings 'once';
 168                 $PublicInbox::ViewVCS::MAX_SIZE + 1;
 169         };
 170         my %bin = (big => $big_size, small => 1);
 171         my %oid; # (small|big) => OID
 172         my $lk = bless { lock_path => $l }, 'PublicInbox::Lock';
 173         my $acq = $lk->lock_for_scope;
 174         my $stamp = "$binfoo/stamp";
 175         if (open my $fh, '<', $stamp) {
 176                 %oid = map { chomp; split(/=/, $_) } (<$fh>);
 177         } else {
 178                 PublicInbox::Import::init_bare($binfoo);
 179                 my $cmd = [ qw(git hash-object -w --stdin) ];
 180                 my $env = { GIT_DIR => $binfoo };
 181                 open my $fh, '>', "$stamp.$$" or BAIL_OUT;
 182                 while (my ($label, $size) = each %bin) {
 183                         pipe(my ($rin, $win)) or BAIL_OUT;
 184                         my $rout = popen_rd($cmd , $env, { 0 => $rin });
 185                         $rin = undef;
 186                         print { $win } ("\0" x $size) or BAIL_OUT;
 187                         close $win or BAIL_OUT;
 188                         chomp(my $x = <$rout>);
 189                         close $rout or BAIL_OUT "$?";
 190                         print $fh "$label=$x\n" or BAIL_OUT;
 191                         $oid{$label} = $x;
 192                 }
 193                 close $fh or BAIL_OUT;
 194                 rename("$stamp.$$", $stamp) or BAIL_OUT;
 195         }
 196         undef $acq;
 197         # ensure the PSGI frontend (ViewVCS) works:
 198         my $name = $ibx->{name};
 199         my $cfgpfx = "publicinbox.$name";
 200         my $cfgpath = "$tmpdir/httpd-config";
 201         open my $cfgfh, '>', $cfgpath or die;
 202         print $cfgfh <<EOF or die;
 203 [publicinbox "$name"]
 204         address = $ibx->{-primary_address}
 205         inboxdir = $ibx->{inboxdir}
 206         coderepo = public-inbox
 207         coderepo = binfoo
 208         url = http://example.com/$name
 209 [coderepo "public-inbox"]
 210         dir = $git_dir
 211         cgiturl = http://example.com/public-inbox
 212 [coderepo "binfoo"]
 213         dir = $binfoo
 214         cgiturl = http://example.com/binfoo
 215 EOF
 216         close $cfgfh or die;
 217         my $cfg = PublicInbox::Config->new($cfgpath);
 218         my $www = PublicInbox::WWW->new($cfg);
 219         my $client = sub {
 220                 my ($cb) = @_;
 221                 my $mid = '20190401081523.16213-1-BOFH@YHBT.net';
 222                 my @warn;
 223                 my $res = do {
 224                         local $SIG{__WARN__} = sub { push @warn, @_ };
 225                         $cb->(GET("/$name/$mid/"));
 226                 };
 227                 is_deeply(\@warn, [], 'no warnings from rendering diff');
 228                 like($res->content, qr!>&#937;</a>!, 'omega escaped');
 229
 230                 $res = $cb->(GET("/$name/3435775/s/"));
 231                 is($res->code, 200, 'success with existing blob');
 232
 233                 $res = $cb->(GET("/$name/".('0'x40).'/s/'));
 234                 is($res->code, 404, 'failure with null OID');
 235
 236                 $res = $cb->(GET("/$name/$non_existent/s/"));
 237                 is($res->code, 404, 'failure with null OID');
 238
 239                 $res = $cb->(GET("/$name/$v1_0_0_tag/s/"));
 240                 is($res->code, 200, 'shows commit (unabbreviated)');
 241                 $res = $cb->(GET("/$name/$v1_0_0_tag_short/s/"));
 242                 is($res->code, 200, 'shows commit (abbreviated)');
 243                 while (my ($label, $size) = each %bin) {
 244                         $res = $cb->(GET("/$name/$oid{$label}/s/"));
 245                         is($res->code, 200, "$label binary file");
 246                         ok(index($res->content, "blob $size bytes") >= 0,
 247                                 "showed $label binary blob size");
 248                         $res = $cb->(GET("/$name/$oid{$label}/s/raw"));
 249                         is($res->code, 200, "$label raw binary download");
 250                         is($res->content, "\0" x $size,
 251                                 "$label content matches");
 252                 }
 253         };
 254         test_psgi(sub { $www->call(@_) }, $client);
 255         SKIP: {
 256                 require_mods(qw(Plack::Test::ExternalServer), 7);
 257                 my $env = { PI_CONFIG => $cfgpath };
 258                 my $sock = tcp_server() or die;
 259                 my ($out, $err) = map { "$tmpdir/std$_.log" } qw(out err);
 260                 my $cmd = [ qw(-httpd -W0), "--stdout=$out", "--stderr=$err" ];
 261                 my $td = start_script($cmd, $env, { 3 => $sock });
 262                 my ($h, $p) = tcp_host_port($sock);
 263                 my $url = "http://$h:$p";
 264                 local $ENV{PLACK_TEST_EXTERNALSERVER_URI} = $url;
 265                 Plack::Test::ExternalServer::test_psgi(client => $client);
 266                 skip 'no curl', 1 unless which('curl');
 267
 268                 mkdir "$tmpdir/ext" // xbail "mkdir $!";
 269                 test_lei({tmpdir => "$tmpdir/ext"}, sub {
 270                         my $rurl = "$url/$name";
 271                         lei_ok(qw(blob --no-mail 69df7d5 -I), $rurl);
 272                         is(git_sha(1, \$lei_out)->hexdigest, $expect,
 273                                 'blob contents output');
 274                         ok(!lei(qw(blob -I), $rurl, $non_existent),
 275                                         'non-existent blob fails');
 276                 });
 277         }
 278 }
 279
 280 done_testing();