t/spawn.t

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::Spawn qw(which spawn popen_rd);
   7
   8 {
   9         my $true = which('true');
  10         ok($true, "'true' command found with which()");
  11 }
  12
  13 {
  14         my $pid = spawn(['true']);
  15         ok($pid, 'spawned process');
  16         is(waitpid($pid, 0), $pid, 'waitpid succeeds on spawned process');
  17         is($?, 0, 'true exited successfully');
  18 }
  19
  20 {
  21         my ($r, $w);
  22         pipe $r, $w or die "pipe failed: $!";
  23         my $pid = spawn(['echo', 'hello world'], undef, { 1 => fileno($w) });
  24         close $w or die "close pipe[1] failed: $!";
  25         is(<$r>, "hello world\n", 'read stdout of spawned from pipe');
  26         is(waitpid($pid, 0), $pid, 'waitpid succeeds on spawned process');
  27         is($?, 0, 'true exited successfully');
  28 }
  29
  30 {
  31         my ($r, $w);
  32         pipe $r, $w or die "pipe failed: $!";
  33         my $pid = spawn(['sh', '-c', 'echo $HELLO'],
  34                 { 'HELLO' => 'world' }, { 1 => fileno($w) });
  35         close $w or die "close pipe[1] failed: $!";
  36         is(<$r>, "world\n", 'read stdout of spawned from pipe');
  37         is(waitpid($pid, 0), $pid, 'waitpid succeeds on spawned process');
  38         is($?, 0, 'sh exited successfully');
  39 }
  40
  41 {
  42         my ($r, $w);
  43         pipe $r, $w or die "pipe failed: $!";
  44         my $pid = spawn(['env'], {}, { -env => 1, 1 => fileno($w) });
  45         close $w or die "close pipe[1] failed: $!";
  46         ok(!defined(<$r>), 'read stdout of spawned from pipe');
  47         is(waitpid($pid, 0), $pid, 'waitpid succeeds on spawned process');
  48         is($?, 0, 'env(1) exited successfully');
  49 }
  50
  51 {
  52         my $fh = popen_rd([qw(echo hello)]);
  53         ok(fileno($fh) >= 0, 'tied fileno works');
  54         my $l = <$fh>;
  55         is($l, "hello\n", 'tied readline works');
  56         $l = <$fh>;
  57         ok(!$l, 'tied readline works for EOF');
  58 }
  59
  60 {
  61         my $fh = popen_rd([qw(printf foo\nbar)]);
  62         ok(fileno($fh) >= 0, 'tied fileno works');
  63         my @line = <$fh>;
  64         is_deeply(\@line, [ "foo\n", 'bar' ], 'wantarray works on readline');
  65 }
  66
  67 {
  68         my $fh = popen_rd([qw(echo hello)]);
  69         my $buf;
  70         is(sysread($fh, $buf, 6), 6, 'sysread got 6 bytes');
  71         is($buf, "hello\n", 'tied gets works');
  72         is(sysread($fh, $buf, 6), 0, 'sysread got EOF');
  73         $? = 1;
  74         ok(close($fh), 'close succeeds');
  75         is($?, 0, '$? set properly');
  76 }
  77
  78 {
  79         my $fh = popen_rd([qw(false)]);
  80         ok(!close($fh), 'close fails on false');
  81         isnt($?, 0, '$? set properly: '.$?);
  82 }
  83
  84 SKIP: {
  85         eval {
  86                 require BSD::Resource;
  87                 defined(BSD::Resource::RLIMIT_CPU())
  88         } or skip 'BSD::Resource::RLIMIT_CPU missing', 3;
  89         my ($r, $w);
  90         pipe($r, $w) or die "pipe: $!";
  91         my $cmd = ['sh', '-c', 'while true; do :; done'];
  92         my $fd = fileno($w);
  93         my $opt = { RLIMIT_CPU => [ 1, 1 ], RLIMIT_CORE => [ 0, 0 ], 1 => $fd };
  94         my $pid = spawn($cmd, undef, $opt);
  95         close $w or die "close(w): $!";
  96         my $rset = '';
  97         vec($rset, fileno($r), 1) = 1;
  98         ok(select($rset, undef, undef, 5), 'child died before timeout');
  99         is(waitpid($pid, 0), $pid, 'XCPU child process reaped');
 100         isnt($?, 0, 'non-zero exit status');
 101 }
 102
 103 done_testing();
 104
 105 1;