t/v2mda.t

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use Fcntl qw(SEEK_SET);
   7 use Cwd;
   8 use PublicInbox::TestCommon;
   9 use PublicInbox::Eml;
  10 require_git(2.6);
  11
  12 my $V = 2;
  13 require_mods(qw(DBD::SQLite Search::Xapian));
  14 use_ok 'PublicInbox::V2Writable';
  15 my ($tmpdir, $for_destroy) = tmpdir();
  16 my $ibx = {
  17         inboxdir => "$tmpdir/inbox",
  18         name => 'test-v2writable',
  19         address => [ 'test@example.com' ],
  20 };
  21 my $mime = PublicInbox::Eml->new(<<'EOF');
  22 From: a@example.com
  23 To: test@example.com
  24 Subject: this is a subject
  25 Date: Fri, 02 Oct 1993 00:00:00 +0000
  26 Message-ID: <foo@bar>
  27 List-ID: <test.example.com>
  28
  29 hello world
  30 EOF
  31 my $main_bin = getcwd()."/t/main-bin";
  32 my $fail_bin = getcwd()."/t/fail-bin";
  33 local $ENV{PI_DIR} = "$tmpdir/foo";
  34 my $fail_path = "$fail_bin:blib/script:$ENV{PATH}";
  35 local $ENV{PATH} = "$main_bin:blib/script:$ENV{PATH}";
  36 my $faildir = "$tmpdir/fail";
  37 local $ENV{PI_EMERGENCY} = $faildir;
  38 ok(mkdir $faildir);
  39 my @cmd = (qw(-init), "-V$V", $ibx->{name},
  40                 $ibx->{inboxdir}, 'http://localhost/test',
  41                 $ibx->{address}->[0]);
  42 ok(run_script(\@cmd), 'initialized v2 inbox');
  43
  44 my $rdr = { 0 => \($mime->as_string) };
  45 local $ENV{ORIGINAL_RECIPIENT} = 'test@example.com';
  46 ok(run_script(['-mda'], undef, $rdr), 'mda delivered a message');
  47
  48 $ibx = PublicInbox::Inbox->new($ibx);
  49
  50 if ($V == 1) {
  51         ok(run_script([ '-index', "$tmpdir/inbox" ]), 'v1 indexed');
  52 }
  53 my $msgs = $ibx->search->query('');
  54 is(scalar(@$msgs), 1, 'only got one message');
  55 my $eml = $ibx->smsg_eml($msgs->[0]);
  56 is($eml->as_string, $mime->as_string, 'injected message');
  57
  58 {
  59         my @new = glob("$faildir/new/*");
  60         is_deeply(\@new, [], 'nothing in faildir');
  61         local $ENV{PATH} = $fail_path;
  62         $mime->header_set('Message-ID', '<bar@foo>');
  63         $rdr->{0} = \($mime->as_string);
  64         ok(run_script(['-mda'], undef, $rdr), 'mda did not die on "spam"');
  65         @new = glob("$faildir/new/*");
  66         is(scalar(@new), 1, 'got a message in faildir');
  67         $msgs = $ibx->search->reopen->query('');
  68         is(scalar(@$msgs), 1, 'no new message');
  69
  70         my $config = "$ENV{PI_DIR}/config";
  71         ok(-f $config, 'config exists');
  72         my $k = 'publicinboxmda.spamcheck';
  73         is(xsys('git', 'config', "--file=$config", $k, 'none'), 0,
  74                 'disabled spamcheck for mda');
  75
  76         ok(run_script(['-mda'], undef, $rdr), 'mda did not die');
  77         my @again = glob("$faildir/new/*");
  78         is_deeply(\@again, \@new, 'no new message in faildir');
  79         $msgs = $ibx->search->reopen->query('');
  80         is(scalar(@$msgs), 2, 'new message added OK');
  81 }
  82
  83 {
  84         my $patch = 't/data/0001.patch';
  85         open my $fh, '<', $patch or die "failed to open $patch: $!\n";
  86         $rdr->{0} = \(do { local $/; <$fh> });
  87         ok(run_script(['-mda'], undef, $rdr), 'mda delivered a patch');
  88         my $post = $ibx->search->reopen->query('dfpost:6e006fd7');
  89         is(scalar(@$post), 1, 'got one result for dfpost');
  90         my $pre = $ibx->search->query('dfpre:090d998');
  91         is(scalar(@$pre), 1, 'got one result for dfpre');
  92         is($post->[0]->{blob}, $pre->[0]->{blob}, 'same message in both cases');
  93 }
  94
  95 done_testing();