t/v2writable.t

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::ContentId qw(content_digest content_id);
   8 use PublicInbox::TestCommon;
   9 use Cwd qw(abs_path);
  10 require_git(2.6);
  11 require_mods(qw(DBD::SQLite Search::Xapian));
  12 local $ENV{HOME} = abs_path('t');
  13 use_ok 'PublicInbox::V2Writable';
  14 umask 007;
  15 my ($inboxdir, $for_destroy) = tmpdir();
  16 my $ibx = {
  17         inboxdir => $inboxdir,
  18         name => 'test-v2writable',
  19         version => 2,
  20         -primary_address => 'test@example.com',
  21 };
  22 $ibx = PublicInbox::Inbox->new($ibx);
  23 my $mime = PublicInbox::MIME->new(<<'EOF');
  24 From: a@example.com
  25 To: test@example.com
  26 Subject: this is a subject
  27 Message-ID: <a-mid@b>
  28 Date: Fri, 02 Oct 1993 00:00:00 +0000
  29
  30 hello world
  31 EOF
  32 my $im = PublicInbox::V2Writable->new($ibx, {nproc => 1});
  33 is($im->{shards}, 1, 'one shard when forced');
  34 ok($im->add($mime), 'ordinary message added');
  35 foreach my $f ("$inboxdir/msgmap.sqlite3",
  36                 glob("$inboxdir/xap*/*"),
  37                 glob("$inboxdir/xap*/*/*")) {
  38         my @st = stat($f);
  39         my ($bn) = (split(m!/!, $f))[-1];
  40         is($st[2] & 07777, -f _ ? 0660 : 0770,
  41                 "default sharedRepository respected for $bn");
  42 }
  43
  44 my $git0;
  45
  46 if ('ensure git configs are correct') {
  47         my @cmd = (qw(git config), "--file=$inboxdir/all.git/config",
  48                 qw(core.sharedRepository 0644));
  49         is(xsys(@cmd), 0, "set sharedRepository in all.git");
  50         $git0 = PublicInbox::Git->new("$inboxdir/git/0.git");
  51         chomp(my $v = $git0->qx(qw(config core.sharedRepository)));
  52         is($v, '0644', 'child repo inherited core.sharedRepository');
  53         chomp($v = $git0->qx(qw(config --bool repack.writeBitmaps)));
  54         is($v, 'true', 'child repo inherited repack.writeBitmaps');
  55 }
  56
  57 {
  58         my @warn;
  59         local $SIG{__WARN__} = sub { push @warn, @_ };
  60         is($im->add($mime), undef, 'obvious duplicate rejected');
  61         is(scalar(@warn), 0, 'no warning about resent message');
  62
  63         @warn = ();
  64         $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  65         is($im->add($mime), undef, 'secondary MID ignored if first matches');
  66         my $sec = PublicInbox::MIME->new($mime->as_string);
  67         $sec->header_set('Date');
  68         $sec->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  69         ok($im->add($sec), 'secondary MID used if data is different');
  70         like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
  71         like(join(' ', @warn), qr/alternative/, 'warned about alternative');
  72         is_deeply([ '<a-mid@b>', '<c@d>' ],
  73                 [ $sec->header_obj->header_raw('Message-Id') ],
  74                 'no new Message-Id added');
  75
  76         my $sane_mid = qr/\A<[\w\-\.]+\@\w+>\z/;
  77         @warn = ();
  78         $mime->header_set('Message-Id', '<a-mid@b>');
  79         $mime->body_set('different');
  80         ok($im->add($mime), 'reused mid ok');
  81         like(join(' ', @warn), qr/reused/, 'warned about reused MID');
  82         my @mids = $mime->header_obj->header_raw('Message-Id');
  83         is($mids[0], '<a-mid@b>', 'original mid not changed');
  84         like($mids[1], $sane_mid, 'new MID added');
  85         is(scalar(@mids), 2, 'only one new MID added');
  86
  87         @warn = ();
  88         $mime->header_set('Message-Id', '<a-mid@b>');
  89         $mime->body_set('this one needs a random mid');
  90         my $hdr = $mime->header_obj;
  91         my $gen = PublicInbox::Import::digest2mid(content_digest($mime), $hdr);
  92         unlike($gen, qr![\+/=]!, 'no URL-unfriendly chars in Message-Id');
  93         my $fake = PublicInbox::MIME->new($mime->as_string);
  94         $fake->header_set('Message-Id', "<$gen>");
  95         ok($im->add($fake), 'fake added easily');
  96         is_deeply(\@warn, [], 'no warnings from a faker');
  97         ok($im->add($mime), 'random MID made');
  98         like(join(' ', @warn), qr/using random/, 'warned about using random');
  99         @mids = $mime->header_obj->header_raw('Message-Id');
 100         is($mids[0], '<a-mid@b>', 'original mid not changed');
 101         like($mids[1], $sane_mid, 'new MID added');
 102         is(scalar(@mids), 2, 'only one new MID added');
 103
 104         @warn = ();
 105         $mime->header_set('Message-Id');
 106         ok($im->add($mime), 'random MID made for MID free message');
 107         @mids = $mime->header_obj->header_raw('Message-Id');
 108         like($mids[0], $sane_mid, 'mid was generated');
 109         is(scalar(@mids), 1, 'new generated');
 110
 111         @warn = ();
 112         $mime->header_set('Message-Id', '<space@ (NXDOMAIN) >');
 113         ok($im->add($mime), 'message added with space in Message-Id');
 114         is_deeply([], \@warn);
 115 }
 116
 117 {
 118         $mime->header_set('Message-Id', '<abcde@1>', '<abcde@2>');
 119         $mime->header_set('X-Alt-Message-Id', '<alt-id-for-nntp>');
 120         $mime->header_set('References', '<zz-mid@b>');
 121         ok($im->add($mime), 'message with multiple Message-ID');
 122         $im->done;
 123         my ($total, undef) = $ibx->over->recent;
 124         is($ibx->mm->num_highwater, $total, 'got expected highwater value');
 125         my $srch = $ibx->search;
 126         my $mset1 = $srch->reopen->query('m:abcde@1', { mset => 1 });
 127         is($mset1->size, 1, 'message found by first MID');
 128         my $mset2 = $srch->reopen->query('m:abcde@2', { mset => 1 });
 129         is($mset2->size, 1, 'message found by second MID');
 130         is((($mset1->items)[0])->get_docid, (($mset2->items)[0])->get_docid,
 131                 'same document') if ($mset1->size);
 132
 133         my $alt = $srch->reopen->query('m:alt-id-for-nntp', { mset => 1 });
 134         is($alt->size, 1, 'message found by alt MID (NNTP)');
 135         is((($alt->items)[0])->get_docid, (($mset1->items)[0])->get_docid,
 136                 'same document') if ($mset1->size);
 137         $mime->header_set('X-Alt-Message-Id');
 138
 139         my %uniq;
 140         for my $mid (qw(abcde@1 abcde@2 alt-id-for-nntp)) {
 141                 my $msgs = $ibx->over->get_thread($mid);
 142                 my $key = join(' ', sort(map { $_->{num} } @$msgs));
 143                 $uniq{$key}++;
 144         }
 145         is(scalar(keys(%uniq)), 1, 'all alt Message-ID queries give same smsg');
 146         is_deeply([values(%uniq)], [3], '3 queries, 3 results');
 147 }
 148
 149 {
 150         use Net::NNTP;
 151         my $err = "$inboxdir/stderr.log";
 152         my $out = "$inboxdir/stdout.log";
 153         my $group = 'inbox.comp.test.v2writable';
 154         my $pi_config = "$inboxdir/pi_config";
 155         open my $fh, '>', $pi_config or die "open: $!\n";
 156         print $fh <<EOF
 157 [publicinbox "test-v2writable"]
 158         inboxdir = $inboxdir
 159         version = 2
 160         address = test\@example.com
 161         newsgroup = $group
 162 EOF
 163         ;
 164         close $fh or die "close: $!\n";
 165         my $sock = tcp_server();
 166         ok($sock, 'sock created');
 167         my $len;
 168         my $cmd = [ '-nntpd', '-W0', "--stdout=$out", "--stderr=$err" ];
 169         my $env = { PI_CONFIG => $pi_config };
 170         my $td = start_script($cmd, $env, { 3 => $sock });
 171         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 172         my $n = Net::NNTP->new($host_port);
 173         $n->group($group);
 174         my $x = $n->xover('1-');
 175         my %uniq;
 176         foreach my $num (sort { $a <=> $b } keys %$x) {
 177                 my $mid = $x->{$num}->[3];
 178                 is($uniq{$mid}++, 0, "MID for $num is unique in XOVER");
 179                 is_deeply($n->xhdr('Message-ID', $num),
 180                          { $num => $mid }, "XHDR lookup OK on num $num");
 181
 182                 # FIXME PublicInbox::NNTP (server) doesn't handle spaces in
 183                 # Message-ID, but neither does Net::NNTP (client)
 184                 next if $mid =~ / /;
 185
 186                 is_deeply($n->xhdr('Message-ID', $mid),
 187                          { $mid => $mid }, "XHDR lookup OK on MID $mid ($num)");
 188         }
 189         my %nn;
 190         foreach my $mid (@{$n->newnews(0, $group)}) {
 191                 is($nn{$mid}++, 0, "MID is unique in NEWNEWS");
 192         }
 193         is_deeply([sort keys %nn], [sort keys %uniq]);
 194
 195         my %lg;
 196         foreach my $num (@{$n->listgroup($group)}) {
 197                 is($lg{$num}++, 0, "num is unique in LISTGROUP");
 198         }
 199         is_deeply([sort keys %lg], [sort keys %$x],
 200                 'XOVER and LISTGROUPS return the same article numbers');
 201
 202         my $xref = $n->xhdr('Xref', '1-');
 203         is_deeply([sort keys %lg], [sort keys %$xref], 'Xref range OK');
 204
 205         my $mids = $n->xhdr('Message-ID', '1-');
 206         is_deeply([sort keys %lg], [sort keys %$xref], 'Message-ID range OK');
 207
 208         my $rover = $n->xrover('1-');
 209         is_deeply([sort keys %lg], [sort keys %$rover], 'XROVER range OK');
 210 };
 211 {
 212         my @log = qw(log --no-decorate --no-abbrev --no-notes --no-color);
 213         my @before = $git0->qx(@log, qw(--pretty=oneline));
 214         my $before = $git0->qx(@log, qw(--pretty=raw --raw -r));
 215         $im = PublicInbox::V2Writable->new($ibx, {nproc => 2});
 216         is($im->{shards}, 1, 'detected single shard from previous');
 217         my ($mark, $rm_mime, $smsg) = $im->remove($mime, 'test removal');
 218         is(content_id($rm_mime), content_id($mime),
 219                         'removed object returned matches');
 220         ok(defined($mark), 'mark set');
 221         $im->done;
 222         my @after = $git0->qx(@log, qw(--pretty=oneline));
 223         my $tip = shift @after;
 224         like($tip, qr/\A[a-f0-9]+ test removal\n\z/s,
 225                 'commit message propagated to git');
 226         is_deeply(\@after, \@before, 'only one commit written to git');
 227         is($ibx->mm->num_for($smsg->mid), undef, 'no longer in Msgmap by mid');
 228         my $num = $smsg->{num};
 229         like($num, qr/\A\d+\z/, 'numeric number in return message');
 230         is($ibx->mm->mid_for($num), undef, 'no longer in Msgmap by num');
 231         my $srch = $ibx->search->reopen;
 232         my $mset = $srch->query('m:'.$smsg->mid, { mset => 1});
 233         is($mset->size, 0, 'no longer found in Xapian');
 234         my @log1 = (@log, qw(-1 --pretty=raw --raw -r --no-renames));
 235         is($srch->{over_ro}->get_art($num), undef,
 236                 'removal propagated to Over DB');
 237
 238         my $after = $git0->qx(@log1);
 239         if ($after =~ m!( [a-f0-9]+ )A\td$!m) {
 240                 my $oid = $1;
 241                 ok(index($before, $oid) > 0, 'no new blob introduced');
 242         } else {
 243                 fail('failed to extract blob from log output');
 244         }
 245         is($im->remove($mime, 'test removal'), undef,
 246                 'remove is idempotent');
 247         $im->done;
 248         is($git0->qx(@log1),
 249                 $after, 'no git history made with idempotent remove');
 250         eval { $im->done };
 251         ok(!$@, '->done is idempotent');
 252 }
 253
 254 {
 255         ok($im->add($mime), 'add message to be purged');
 256         local $SIG{__WARN__} = sub {};
 257         ok(my $cmts = $im->purge($mime), 'purged message');
 258         like($cmts->[0], qr/\A[a-f0-9]{40}\z/, 'purge returned current commit');
 259         $im->done;
 260
 261         # again
 262         is($im->purge($mime), undef, 'no-op returns undef');
 263 }
 264
 265 {
 266         my $x = 'x'x250;
 267         my $y = 'y'x250;
 268         local $SIG{__WARN__} = sub {};
 269         $mime->header_set('Subject', 'long mid');
 270         $mime->header_set('Message-ID', "<$x>");
 271         ok($im->add($mime), 'add excessively long Message-ID');
 272
 273         $mime->header_set('Message-ID', "<$y>");
 274         $mime->header_set('References', "<$x>");
 275         ok($im->add($mime), 'add excessively long References');
 276         $im->barrier;
 277
 278         my $msgs = $ibx->search->{over_ro}->get_thread('x'x244);
 279         is(2, scalar(@$msgs), 'got both messages');
 280         is($msgs->[0]->{mid}, 'x'x244, 'stored truncated mid');
 281         is($msgs->[1]->{references}, '<'.('x'x244).'>', 'stored truncated ref');
 282         is($msgs->[1]->{mid}, 'y'x244, 'stored truncated mid(2)');
 283         $im->done;
 284 }
 285
 286 my $tmp = {
 287         inboxdir => "$inboxdir/non-existent/subdir",
 288         name => 'nope',
 289         version => 2,
 290         -primary_address => 'test@example.com',
 291 };
 292 eval {
 293         my $nope = PublicInbox::V2Writable->new($tmp);
 294         $nope->add($mime);
 295 };
 296 ok($@, 'V2Writable fails on non-existent dir');
 297
 298 {
 299         my $v2w = PublicInbox::V2Writable->new($tmp, 1);
 300         ok($v2w, 'creat flag works');
 301         $v2w->{parallel} = 0;
 302         $v2w->init_inbox(0);
 303         my $alt = "$tmp->{inboxdir}/all.git/objects/info/alternates";
 304         open my $fh, '>>', $alt or die $!;
 305         print $fh "$inboxdir/all.git/objects\n" or die $!;
 306         chmod(0664, $fh) or die "fchmod: $!";
 307         close $fh or die $!;
 308         open $fh, '<', $alt or die $!;
 309         my $before = do { local $/; <$fh> };
 310
 311         ok($v2w->git_init(3), 'init a new epoch');
 312         open $fh, '<', $alt or die $!;
 313         my $after = do { local $/; <$fh> };
 314         ok(index($after, $before) > 0,
 315                 'old contents preserved after adding epoch');
 316         like($after, qr!\A[^\n]+?/3\.git/objects\n!s,
 317                 'first line is newest epoch');
 318         my $mode = (stat($alt))[2] & 07777;
 319         is($mode, 0664, sprintf('0%03o', $mode).' is 0664');
 320 }
 321
 322 done_testing();