t/v2writable.t

   1 # Copyright (C) 2018-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::ContentId qw(content_digest);
   8 use File::Temp qw/tempdir/;
   9 require './t/common.perl';
  10 require_git(2.6);
  11 foreach my $mod (qw(DBD::SQLite Search::Xapian)) {
  12         eval "require $mod";
  13         plan skip_all => "$mod missing for nntpd.t" if $@;
  14 }
  15 use_ok 'PublicInbox::V2Writable';
  16 umask 007;
  17 my $inboxdir = tempdir('pi-v2writable-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  18 my $ibx = {
  19         inboxdir => $inboxdir,
  20         name => 'test-v2writable',
  21         version => 2,
  22         -primary_address => 'test@example.com',
  23 };
  24 $ibx = PublicInbox::Inbox->new($ibx);
  25 my $mime = PublicInbox::MIME->create(
  26         header => [
  27                 From => 'a@example.com',
  28                 To => 'test@example.com',
  29                 Subject => 'this is a subject',
  30                 'Message-ID' => '<a-mid@b>',
  31                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  32         ],
  33         body => "hello world\n",
  34 );
  35
  36 my $im = PublicInbox::V2Writable->new($ibx, {nproc => 1});
  37 is($im->{shards}, 1, 'one shard when forced');
  38 ok($im->add($mime), 'ordinary message added');
  39 foreach my $f ("$inboxdir/msgmap.sqlite3",
  40                 glob("$inboxdir/xap*/*"),
  41                 glob("$inboxdir/xap*/*/*")) {
  42         my @st = stat($f);
  43         my ($bn) = (split(m!/!, $f))[-1];
  44         is($st[2] & 07777, -f _ ? 0660 : 0770,
  45                 "default sharedRepository respected for $bn");
  46 }
  47
  48 my $git0;
  49
  50 if ('ensure git configs are correct') {
  51         my @cmd = (qw(git config), "--file=$inboxdir/all.git/config",
  52                 qw(core.sharedRepository 0644));
  53         is(system(@cmd), 0, "set sharedRepository in all.git");
  54         $git0 = PublicInbox::Git->new("$inboxdir/git/0.git");
  55         chomp(my $v = $git0->qx(qw(config core.sharedRepository)));
  56         is($v, '0644', 'child repo inherited core.sharedRepository');
  57         chomp($v = $git0->qx(qw(config --bool repack.writeBitmaps)));
  58         is($v, 'true', 'child repo inherited repack.writeBitmaps');
  59 }
  60
  61 {
  62         my @warn;
  63         local $SIG{__WARN__} = sub { push @warn, @_ };
  64         is($im->add($mime), undef, 'obvious duplicate rejected');
  65         is(scalar(@warn), 0, 'no warning about resent message');
  66
  67         @warn = ();
  68         $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  69         is($im->add($mime), undef, 'secondary MID ignored if first matches');
  70         my $sec = PublicInbox::MIME->new($mime->as_string);
  71         $sec->header_set('Date');
  72         $sec->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  73         ok($im->add($sec), 'secondary MID used if data is different');
  74         like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
  75         like(join(' ', @warn), qr/alternative/, 'warned about alternative');
  76         is_deeply([ '<a-mid@b>', '<c@d>' ],
  77                 [ $sec->header_obj->header_raw('Message-Id') ],
  78                 'no new Message-Id added');
  79
  80         my $sane_mid = qr/\A<[\w\-\.]+\@\w+>\z/;
  81         @warn = ();
  82         $mime->header_set('Message-Id', '<a-mid@b>');
  83         $mime->body_set('different');
  84         ok($im->add($mime), 'reused mid ok');
  85         like(join(' ', @warn), qr/reused/, 'warned about reused MID');
  86         my @mids = $mime->header_obj->header_raw('Message-Id');
  87         is($mids[0], '<a-mid@b>', 'original mid not changed');
  88         like($mids[1], $sane_mid, 'new MID added');
  89         is(scalar(@mids), 2, 'only one new MID added');
  90
  91         @warn = ();
  92         $mime->header_set('Message-Id', '<a-mid@b>');
  93         $mime->body_set('this one needs a random mid');
  94         my $hdr = $mime->header_obj;
  95         my $gen = PublicInbox::Import::digest2mid(content_digest($mime), $hdr);
  96         unlike($gen, qr![\+/=]!, 'no URL-unfriendly chars in Message-Id');
  97         my $fake = PublicInbox::MIME->new($mime->as_string);
  98         $fake->header_set('Message-Id', "<$gen>");
  99         ok($im->add($fake), 'fake added easily');
 100         is_deeply(\@warn, [], 'no warnings from a faker');
 101         ok($im->add($mime), 'random MID made');
 102         like(join(' ', @warn), qr/using random/, 'warned about using random');
 103         @mids = $mime->header_obj->header_raw('Message-Id');
 104         is($mids[0], '<a-mid@b>', 'original mid not changed');
 105         like($mids[1], $sane_mid, 'new MID added');
 106         is(scalar(@mids), 2, 'only one new MID added');
 107
 108         @warn = ();
 109         $mime->header_set('Message-Id');
 110         ok($im->add($mime), 'random MID made for MID free message');
 111         @mids = $mime->header_obj->header_raw('Message-Id');
 112         like($mids[0], $sane_mid, 'mid was generated');
 113         is(scalar(@mids), 1, 'new generated');
 114 }
 115
 116 {
 117         $mime->header_set('Message-Id', '<abcde@1>', '<abcde@2>');
 118         $mime->header_set('References', '<zz-mid@b>');
 119         ok($im->add($mime), 'message with multiple Message-ID');
 120         $im->done;
 121         my ($total, undef) = $ibx->over->recent;
 122         is($ibx->mm->num_highwater, $total, 'got expected highwater value');
 123         my $srch = $ibx->search;
 124         my $mset1 = $srch->reopen->query('m:abcde@1', { mset => 1 });
 125         is($mset1->size, 1, 'message found by first MID');
 126         my $mset2 = $srch->reopen->query('m:abcde@2', { mset => 1 });
 127         is($mset2->size, 1, 'message found by second MID');
 128         is((($mset1->items)[0])->get_docid, (($mset2->items)[0])->get_docid,
 129                 'same document') if ($mset1->size);
 130 }
 131
 132 {
 133         use Net::NNTP;
 134         my $err = "$inboxdir/stderr.log";
 135         my $out = "$inboxdir/stdout.log";
 136         my $group = 'inbox.comp.test.v2writable';
 137         my $pi_config = "$inboxdir/pi_config";
 138         open my $fh, '>', $pi_config or die "open: $!\n";
 139         print $fh <<EOF
 140 [publicinbox "test-v2writable"]
 141         inboxdir = $inboxdir
 142         version = 2
 143         address = test\@example.com
 144         newsgroup = $group
 145 EOF
 146         ;
 147         close $fh or die "close: $!\n";
 148         my $sock = tcp_server();
 149         ok($sock, 'sock created');
 150         my $pid;
 151         my $len;
 152         END { kill 'TERM', $pid if defined $pid };
 153         my $nntpd = 'blib/script/public-inbox-nntpd';
 154         my $cmd = [ $nntpd, "--stdout=$out", "--stderr=$err" ];
 155         $pid = spawn_listener({ PI_CONFIG => $pi_config }, $cmd, [ $sock ]);
 156         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 157         my $n = Net::NNTP->new($host_port);
 158         $n->group($group);
 159         my $x = $n->xover('1-');
 160         my %uniq;
 161         foreach my $num (sort { $a <=> $b } keys %$x) {
 162                 my $mid = $x->{$num}->[3];
 163                 is($uniq{$mid}++, 0, "MID for $num is unique in XOVER");
 164                 is_deeply($n->xhdr('Message-ID', $num),
 165                          { $num => $mid }, "XHDR lookup OK on num $num");
 166                 is_deeply($n->xhdr('Message-ID', $mid),
 167                          { $mid => $mid }, "XHDR lookup OK on MID $num");
 168         }
 169         my %nn;
 170         foreach my $mid (@{$n->newnews(0, $group)}) {
 171                 is($nn{$mid}++, 0, "MID is unique in NEWNEWS");
 172         }
 173         is_deeply([sort keys %nn], [sort keys %uniq]);
 174
 175         my %lg;
 176         foreach my $num (@{$n->listgroup($group)}) {
 177                 is($lg{$num}++, 0, "num is unique in LISTGROUP");
 178         }
 179         is_deeply([sort keys %lg], [sort keys %$x],
 180                 'XOVER and LISTGROUPS return the same article numbers');
 181
 182         my $xref = $n->xhdr('Xref', '1-');
 183         is_deeply([sort keys %lg], [sort keys %$xref], 'Xref range OK');
 184
 185         my $mids = $n->xhdr('Message-ID', '1-');
 186         is_deeply([sort keys %lg], [sort keys %$xref], 'Message-ID range OK');
 187
 188         my $rover = $n->xrover('1-');
 189         is_deeply([sort keys %lg], [sort keys %$rover], 'XROVER range OK');
 190 };
 191 {
 192         my @log = qw(log --no-decorate --no-abbrev --no-notes --no-color);
 193         my @before = $git0->qx(@log, qw(--pretty=oneline));
 194         my $before = $git0->qx(@log, qw(--pretty=raw --raw -r));
 195         $im = PublicInbox::V2Writable->new($ibx, {nproc => 2});
 196         is($im->{shards}, 1, 'detected single shard from previous');
 197         my $smsg = $im->remove($mime, 'test removal');
 198         $im->done;
 199         my @after = $git0->qx(@log, qw(--pretty=oneline));
 200         my $tip = shift @after;
 201         like($tip, qr/\A[a-f0-9]+ test removal\n\z/s,
 202                 'commit message propagated to git');
 203         is_deeply(\@after, \@before, 'only one commit written to git');
 204         is($ibx->mm->num_for($smsg->mid), undef, 'no longer in Msgmap by mid');
 205         my $num = $smsg->{num};
 206         like($num, qr/\A\d+\z/, 'numeric number in return message');
 207         is($ibx->mm->mid_for($num), undef, 'no longer in Msgmap by num');
 208         my $srch = $ibx->search->reopen;
 209         my $mset = $srch->query('m:'.$smsg->mid, { mset => 1});
 210         is($mset->size, 0, 'no longer found in Xapian');
 211         my @log1 = (@log, qw(-1 --pretty=raw --raw -r --no-renames));
 212         is($srch->{over_ro}->get_art($num), undef,
 213                 'removal propagated to Over DB');
 214
 215         my $after = $git0->qx(@log1);
 216         if ($after =~ m!( [a-f0-9]+ )A\td$!m) {
 217                 my $oid = $1;
 218                 ok(index($before, $oid) > 0, 'no new blob introduced');
 219         } else {
 220                 fail('failed to extract blob from log output');
 221         }
 222         is($im->remove($mime, 'test removal'), undef,
 223                 'remove is idempotent');
 224         $im->done;
 225         is($git0->qx(@log1),
 226                 $after, 'no git history made with idempotent remove');
 227         eval { $im->done };
 228         ok(!$@, '->done is idempotent');
 229 }
 230
 231 {
 232         ok($im->add($mime), 'add message to be purged');
 233         local $SIG{__WARN__} = sub {};
 234         ok(my $cmts = $im->purge($mime), 'purged message');
 235         like($cmts->[0], qr/\A[a-f0-9]{40}\z/, 'purge returned current commit');
 236         $im->done;
 237
 238         # again
 239         is($im->purge($mime), undef, 'no-op returns undef');
 240 }
 241
 242 {
 243         my $x = 'x'x250;
 244         my $y = 'y'x250;
 245         local $SIG{__WARN__} = sub {};
 246         $mime->header_set('Subject', 'long mid');
 247         $mime->header_set('Message-ID', "<$x>");
 248         ok($im->add($mime), 'add excessively long Message-ID');
 249
 250         $mime->header_set('Message-ID', "<$y>");
 251         $mime->header_set('References', "<$x>");
 252         ok($im->add($mime), 'add excessively long References');
 253         $im->barrier;
 254
 255         my $msgs = $ibx->search->{over_ro}->get_thread('x'x244);
 256         is(2, scalar(@$msgs), 'got both messages');
 257         is($msgs->[0]->{mid}, 'x'x244, 'stored truncated mid');
 258         is($msgs->[1]->{references}, '<'.('x'x244).'>', 'stored truncated ref');
 259         is($msgs->[1]->{mid}, 'y'x244, 'stored truncated mid(2)');
 260         $im->done;
 261 }
 262
 263 done_testing();