t/v2writable.t

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::ContentId qw(content_digest);
   8 use File::Temp qw/tempdir/;
   9 require './t/common.perl';
  10 foreach my $mod (qw(DBD::SQLite Search::Xapian)) {
  11         eval "require $mod";
  12         plan skip_all => "$mod missing for nntpd.t" if $@;
  13 }
  14 use_ok 'PublicInbox::V2Writable';
  15 umask 007;
  16 my $mainrepo = tempdir('pi-v2writable-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  17 my $ibx = {
  18         mainrepo => $mainrepo,
  19         name => 'test-v2writable',
  20         version => 2,
  21         -primary_address => 'test@example.com',
  22 };
  23 $ibx = PublicInbox::Inbox->new($ibx);
  24 my $mime = PublicInbox::MIME->create(
  25         header => [
  26                 From => 'a@example.com',
  27                 To => 'test@example.com',
  28                 Subject => 'this is a subject',
  29                 'Message-ID' => '<a-mid@b>',
  30                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  31         ],
  32         body => "hello world\n",
  33 );
  34
  35 my $im = eval {
  36         local $ENV{NPROC} = '1';
  37         PublicInbox::V2Writable->new($ibx, 1);
  38 };
  39 is($im->{partitions}, 1, 'one partition when forced');
  40 ok($im->add($mime), 'ordinary message added');
  41 foreach my $f ("$mainrepo/msgmap.sqlite3",
  42                 glob("$mainrepo/xap*/*"),
  43                 glob("$mainrepo/xap*/*/*")) {
  44         my @st = stat($f);
  45         my ($bn) = (split(m!/!, $f))[-1];
  46         is($st[2] & 07777, -f _ ? 0660 : 0770,
  47                 "default sharedRepository respected for $bn");
  48 }
  49
  50 my $git0;
  51
  52 if ('ensure git configs are correct') {
  53         my @cmd = (qw(git config), "--file=$mainrepo/all.git/config",
  54                 qw(core.sharedRepository 0644));
  55         is(system(@cmd), 0, "set sharedRepository in all.git");
  56         $git0 = PublicInbox::Git->new("$mainrepo/git/0.git");
  57         chomp(my $v = $git0->qx(qw(config core.sharedRepository)));
  58         is($v, '0644', 'child repo inherited core.sharedRepository');
  59         chomp($v = $git0->qx(qw(config --bool repack.writeBitmaps)));
  60         is($v, 'true', 'child repo inherited repack.writeBitmaps');
  61 }
  62
  63 {
  64         my @warn;
  65         local $SIG{__WARN__} = sub { push @warn, @_ };
  66         is($im->add($mime), undef, 'obvious duplicate rejected');
  67         is(scalar(@warn), 0, 'no warning about resent message');
  68
  69         @warn = ();
  70         $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  71         is($im->add($mime), undef, 'secondary MID ignored if first matches');
  72         my $sec = PublicInbox::MIME->new($mime->as_string);
  73         $sec->header_set('Date');
  74         $sec->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  75         ok($im->add($sec), 'secondary MID used if data is different');
  76         like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
  77         like(join(' ', @warn), qr/alternative/, 'warned about alternative');
  78         is_deeply([ '<a-mid@b>', '<c@d>' ],
  79                 [ $sec->header_obj->header_raw('Message-Id') ],
  80                 'no new Message-Id added');
  81
  82         my $sane_mid = qr/\A<[\w\-\.]+\@\w+>\z/;
  83         @warn = ();
  84         $mime->header_set('Message-Id', '<a-mid@b>');
  85         $mime->body_set('different');
  86         ok($im->add($mime), 'reused mid ok');
  87         like(join(' ', @warn), qr/reused/, 'warned about reused MID');
  88         my @mids = $mime->header_obj->header_raw('Message-Id');
  89         is($mids[0], '<a-mid@b>', 'original mid not changed');
  90         like($mids[1], $sane_mid, 'new MID added');
  91         is(scalar(@mids), 2, 'only one new MID added');
  92
  93         @warn = ();
  94         $mime->header_set('Message-Id', '<a-mid@b>');
  95         $mime->body_set('this one needs a random mid');
  96         my $hdr = $mime->header_obj;
  97         my $gen = PublicInbox::Import::digest2mid(content_digest($mime), $hdr);
  98         unlike($gen, qr![\+/=]!, 'no URL-unfriendly chars in Message-Id');
  99         my $fake = PublicInbox::MIME->new($mime->as_string);
 100         $fake->header_set('Message-Id', "<$gen>");
 101         ok($im->add($fake), 'fake added easily');
 102         is_deeply(\@warn, [], 'no warnings from a faker');
 103         ok($im->add($mime), 'random MID made');
 104         like(join(' ', @warn), qr/using random/, 'warned about using random');
 105         @mids = $mime->header_obj->header_raw('Message-Id');
 106         is($mids[0], '<a-mid@b>', 'original mid not changed');
 107         like($mids[1], $sane_mid, 'new MID added');
 108         is(scalar(@mids), 2, 'only one new MID added');
 109
 110         @warn = ();
 111         $mime->header_set('Message-Id');
 112         ok($im->add($mime), 'random MID made for MID free message');
 113         @mids = $mime->header_obj->header_raw('Message-Id');
 114         like($mids[0], $sane_mid, 'mid was generated');
 115         is(scalar(@mids), 1, 'new generated');
 116 }
 117
 118 {
 119         $mime->header_set('Message-Id', '<abcde@1>', '<abcde@2>');
 120         $mime->header_set('References', '<zz-mid@b>');
 121         ok($im->add($mime), 'message with multiple Message-ID');
 122         $im->done;
 123         my $srch = $ibx->search;
 124         my $mset1 = $srch->reopen->query('m:abcde@1', { mset => 1 });
 125         is($mset1->size, 1, 'message found by first MID');
 126         my $mset2 = $srch->reopen->query('m:abcde@2', { mset => 1 });
 127         is($mset2->size, 1, 'message found by second MID');
 128         is((($mset1->items)[0])->get_docid, (($mset2->items)[0])->get_docid,
 129                 'same document') if ($mset1->size);
 130 }
 131
 132 SKIP: {
 133         use Net::NNTP;
 134         use IO::Socket;
 135         use Socket qw(SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
 136         eval { require Danga::Socket };
 137         skip "Danga::Socket missing $@", 2 if $@;
 138         my $err = "$mainrepo/stderr.log";
 139         my $out = "$mainrepo/stdout.log";
 140         my %opts = (
 141                 LocalAddr => '127.0.0.1',
 142                 ReuseAddr => 1,
 143                 Proto => 'tcp',
 144                 Type => SOCK_STREAM,
 145                 Listen => 1024,
 146         );
 147         my $group = 'inbox.comp.test.v2writable';
 148         my $pi_config = "$mainrepo/pi_config";
 149         open my $fh, '>', $pi_config or die "open: $!\n";
 150         print $fh <<EOF
 151 [publicinbox "test-v2writable"]
 152         mainrepo = $mainrepo
 153         version = 2
 154         address = test\@example.com
 155         newsgroup = $group
 156 EOF
 157         ;
 158         close $fh or die "close: $!\n";
 159         my $sock = IO::Socket::INET->new(%opts);
 160         ok($sock, 'sock created');
 161         my $pid;
 162         my $len;
 163         END { kill 'TERM', $pid if defined $pid };
 164         my $nntpd = 'blib/script/public-inbox-nntpd';
 165         my $cmd = [ $nntpd, "--stdout=$out", "--stderr=$err" ];
 166         $pid = spawn_listener({ PI_CONFIG => $pi_config }, $cmd, [ $sock ]);
 167         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 168         my $n = Net::NNTP->new($host_port);
 169         $n->group($group);
 170         my $x = $n->xover('1-');
 171         my %uniq;
 172         foreach my $num (sort { $a <=> $b } keys %$x) {
 173                 my $mid = $x->{$num}->[3];
 174                 is($uniq{$mid}++, 0, "MID for $num is unique in XOVER");
 175                 is_deeply($n->xhdr('Message-ID', $num),
 176                          { $num => $mid }, "XHDR lookup OK on num $num");
 177                 is_deeply($n->xhdr('Message-ID', $mid),
 178                          { $mid => $mid }, "XHDR lookup OK on MID $num");
 179         }
 180         my %nn;
 181         foreach my $mid (@{$n->newnews(0, $group)}) {
 182                 is($nn{$mid}++, 0, "MID is unique in NEWNEWS");
 183         }
 184         is_deeply([sort keys %nn], [sort keys %uniq]);
 185
 186         my %lg;
 187         foreach my $num (@{$n->listgroup($group)}) {
 188                 is($lg{$num}++, 0, "num is unique in LISTGROUP");
 189         }
 190         is_deeply([sort keys %lg], [sort keys %$x],
 191                 'XOVER and LISTGROUPS return the same article numbers');
 192
 193         my $xref = $n->xhdr('Xref', '1-');
 194         is_deeply([sort keys %lg], [sort keys %$xref], 'Xref range OK');
 195
 196         my $mids = $n->xhdr('Message-ID', '1-');
 197         is_deeply([sort keys %lg], [sort keys %$xref], 'Message-ID range OK');
 198
 199         my $rover = $n->xrover('1-');
 200         is_deeply([sort keys %lg], [sort keys %$rover], 'XROVER range OK');
 201 };
 202 {
 203         local $ENV{NPROC} = 2;
 204         my @before = $git0->qx(qw(log --pretty=oneline));
 205         my $before = $git0->qx(qw(log --pretty=raw --raw -r --no-abbrev));
 206         $im = PublicInbox::V2Writable->new($ibx, 1);
 207         is($im->{partitions}, 1, 'detected single partition from previous');
 208         my $smsg = $im->remove($mime, 'test removal');
 209         $im->done;
 210         my @after = $git0->qx(qw(log --pretty=oneline));
 211         my $tip = shift @after;
 212         like($tip, qr/\A[a-f0-9]+ test removal\n\z/s,
 213                 'commit message propagated to git');
 214         is_deeply(\@after, \@before, 'only one commit written to git');
 215         is($ibx->mm->num_for($smsg->mid), undef, 'no longer in Msgmap by mid');
 216         my $num = $smsg->{num};
 217         like($num, qr/\A\d+\z/, 'numeric number in return message');
 218         is($ibx->mm->mid_for($num), undef, 'no longer in Msgmap by num');
 219         my $srch = $ibx->search->reopen;
 220         my $mset = $srch->query('m:'.$smsg->mid, { mset => 1});
 221         is($mset->size, 0, 'no longer found in Xapian');
 222         my @log1 = qw(log -1 --pretty=raw --raw -r --no-abbrev --no-renames);
 223         is($srch->{over_ro}->get_art($num), undef,
 224                 'removal propagated to Over DB');
 225
 226         my $after = $git0->qx(@log1);
 227         if ($after =~ m!( [a-f0-9]+ )A\td$!m) {
 228                 my $oid = $1;
 229                 ok(index($before, $oid) > 0, 'no new blob introduced');
 230         } else {
 231                 fail('failed to extract blob from log output');
 232         }
 233         is($im->remove($mime, 'test removal'), undef,
 234                 'remove is idempotent');
 235         $im->done;
 236         is($git0->qx(@log1),
 237                 $after, 'no git history made with idempotent remove');
 238         eval { $im->done };
 239         ok(!$@, '->done is idempotent');
 240 }
 241
 242 {
 243         ok($im->add($mime), 'add message to be purged');
 244         local $SIG{__WARN__} = sub {};
 245         ok(my $cmts = $im->purge($mime), 'purged message');
 246         like($cmts->[0], qr/\A[a-f0-9]{40}\z/, 'purge returned current commit');
 247         $im->done;
 248 }
 249
 250 {
 251         my @warn;
 252         my $x = 'x'x250;
 253         my $y = 'y'x250;
 254         local $SIG{__WARN__} = sub { push @warn, @_ };
 255         $mime->header_set('Subject', 'long mid');
 256         $mime->header_set('Message-ID', "<$x>");
 257         ok($im->add($mime), 'add excessively long Message-ID');
 258
 259         $mime->header_set('Message-ID', "<$y>");
 260         $mime->header_set('References', "<$x>");
 261         ok($im->add($mime), 'add excessively long References');
 262         $im->barrier;
 263
 264         my $msgs = $ibx->search->reopen->get_thread('x'x244);
 265         is(2, scalar(@$msgs), 'got both messages');
 266         is($msgs->[0]->{mid}, 'x'x244, 'stored truncated mid');
 267         is($msgs->[1]->{references}, '<'.('x'x244).'>', 'stored truncated ref');
 268         is($msgs->[1]->{mid}, 'y'x244, 'stored truncated mid(2)');
 269         $im->done;
 270 }
 271
 272 done_testing();