t/v2writable.t

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 use strict;
   4 use warnings;
   5 use Test::More;
   6 use PublicInbox::MIME;
   7 use PublicInbox::ContentId qw(content_digest);
   8 use File::Temp qw/tempdir/;
   9 require './t/common.perl';
  10 require_git(2.6);
  11 foreach my $mod (qw(DBD::SQLite Search::Xapian)) {
  12         eval "require $mod";
  13         plan skip_all => "$mod missing for nntpd.t" if $@;
  14 }
  15 use_ok 'PublicInbox::V2Writable';
  16 umask 007;
  17 my $mainrepo = tempdir('pi-v2writable-XXXXXX', TMPDIR => 1, CLEANUP => 1);
  18 my $ibx = {
  19         mainrepo => $mainrepo,
  20         name => 'test-v2writable',
  21         version => 2,
  22         -primary_address => 'test@example.com',
  23 };
  24 $ibx = PublicInbox::Inbox->new($ibx);
  25 my $mime = PublicInbox::MIME->create(
  26         header => [
  27                 From => 'a@example.com',
  28                 To => 'test@example.com',
  29                 Subject => 'this is a subject',
  30                 'Message-ID' => '<a-mid@b>',
  31                 Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
  32         ],
  33         body => "hello world\n",
  34 );
  35
  36 my $im = eval {
  37         local $ENV{NPROC} = '1';
  38         PublicInbox::V2Writable->new($ibx, 1);
  39 };
  40 is($im->{partitions}, 1, 'one partition when forced');
  41 ok($im->add($mime), 'ordinary message added');
  42 foreach my $f ("$mainrepo/msgmap.sqlite3",
  43                 glob("$mainrepo/xap*/*"),
  44                 glob("$mainrepo/xap*/*/*")) {
  45         my @st = stat($f);
  46         my ($bn) = (split(m!/!, $f))[-1];
  47         is($st[2] & 07777, -f _ ? 0660 : 0770,
  48                 "default sharedRepository respected for $bn");
  49 }
  50
  51 my $git0;
  52
  53 if ('ensure git configs are correct') {
  54         my @cmd = (qw(git config), "--file=$mainrepo/all.git/config",
  55                 qw(core.sharedRepository 0644));
  56         is(system(@cmd), 0, "set sharedRepository in all.git");
  57         $git0 = PublicInbox::Git->new("$mainrepo/git/0.git");
  58         chomp(my $v = $git0->qx(qw(config core.sharedRepository)));
  59         is($v, '0644', 'child repo inherited core.sharedRepository');
  60         chomp($v = $git0->qx(qw(config --bool repack.writeBitmaps)));
  61         is($v, 'true', 'child repo inherited repack.writeBitmaps');
  62 }
  63
  64 {
  65         my @warn;
  66         local $SIG{__WARN__} = sub { push @warn, @_ };
  67         is($im->add($mime), undef, 'obvious duplicate rejected');
  68         is(scalar(@warn), 0, 'no warning about resent message');
  69
  70         @warn = ();
  71         $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  72         is($im->add($mime), undef, 'secondary MID ignored if first matches');
  73         my $sec = PublicInbox::MIME->new($mime->as_string);
  74         $sec->header_set('Date');
  75         $sec->header_set('Message-Id', '<a-mid@b>', '<c@d>');
  76         ok($im->add($sec), 'secondary MID used if data is different');
  77         like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
  78         like(join(' ', @warn), qr/alternative/, 'warned about alternative');
  79         is_deeply([ '<a-mid@b>', '<c@d>' ],
  80                 [ $sec->header_obj->header_raw('Message-Id') ],
  81                 'no new Message-Id added');
  82
  83         my $sane_mid = qr/\A<[\w\-\.]+\@\w+>\z/;
  84         @warn = ();
  85         $mime->header_set('Message-Id', '<a-mid@b>');
  86         $mime->body_set('different');
  87         ok($im->add($mime), 'reused mid ok');
  88         like(join(' ', @warn), qr/reused/, 'warned about reused MID');
  89         my @mids = $mime->header_obj->header_raw('Message-Id');
  90         is($mids[0], '<a-mid@b>', 'original mid not changed');
  91         like($mids[1], $sane_mid, 'new MID added');
  92         is(scalar(@mids), 2, 'only one new MID added');
  93
  94         @warn = ();
  95         $mime->header_set('Message-Id', '<a-mid@b>');
  96         $mime->body_set('this one needs a random mid');
  97         my $hdr = $mime->header_obj;
  98         my $gen = PublicInbox::Import::digest2mid(content_digest($mime), $hdr);
  99         unlike($gen, qr![\+/=]!, 'no URL-unfriendly chars in Message-Id');
 100         my $fake = PublicInbox::MIME->new($mime->as_string);
 101         $fake->header_set('Message-Id', "<$gen>");
 102         ok($im->add($fake), 'fake added easily');
 103         is_deeply(\@warn, [], 'no warnings from a faker');
 104         ok($im->add($mime), 'random MID made');
 105         like(join(' ', @warn), qr/using random/, 'warned about using random');
 106         @mids = $mime->header_obj->header_raw('Message-Id');
 107         is($mids[0], '<a-mid@b>', 'original mid not changed');
 108         like($mids[1], $sane_mid, 'new MID added');
 109         is(scalar(@mids), 2, 'only one new MID added');
 110
 111         @warn = ();
 112         $mime->header_set('Message-Id');
 113         ok($im->add($mime), 'random MID made for MID free message');
 114         @mids = $mime->header_obj->header_raw('Message-Id');
 115         like($mids[0], $sane_mid, 'mid was generated');
 116         is(scalar(@mids), 1, 'new generated');
 117 }
 118
 119 {
 120         $mime->header_set('Message-Id', '<abcde@1>', '<abcde@2>');
 121         $mime->header_set('References', '<zz-mid@b>');
 122         ok($im->add($mime), 'message with multiple Message-ID');
 123         $im->done;
 124         my $srch = $ibx->search;
 125         my $mset1 = $srch->reopen->query('m:abcde@1', { mset => 1 });
 126         is($mset1->size, 1, 'message found by first MID');
 127         my $mset2 = $srch->reopen->query('m:abcde@2', { mset => 1 });
 128         is($mset2->size, 1, 'message found by second MID');
 129         is((($mset1->items)[0])->get_docid, (($mset2->items)[0])->get_docid,
 130                 'same document') if ($mset1->size);
 131 }
 132
 133 SKIP: {
 134         use Net::NNTP;
 135         use IO::Socket;
 136         use Socket qw(SO_KEEPALIVE IPPROTO_TCP TCP_NODELAY);
 137         eval { require PublicInbox::DS };
 138         skip "PublicInbox::DS missing $@", 2 if $@;
 139         my $err = "$mainrepo/stderr.log";
 140         my $out = "$mainrepo/stdout.log";
 141         my %opts = (
 142                 LocalAddr => '127.0.0.1',
 143                 ReuseAddr => 1,
 144                 Proto => 'tcp',
 145                 Type => SOCK_STREAM,
 146                 Listen => 1024,
 147         );
 148         my $group = 'inbox.comp.test.v2writable';
 149         my $pi_config = "$mainrepo/pi_config";
 150         open my $fh, '>', $pi_config or die "open: $!\n";
 151         print $fh <<EOF
 152 [publicinbox "test-v2writable"]
 153         mainrepo = $mainrepo
 154         version = 2
 155         address = test\@example.com
 156         newsgroup = $group
 157 EOF
 158         ;
 159         close $fh or die "close: $!\n";
 160         my $sock = IO::Socket::INET->new(%opts);
 161         ok($sock, 'sock created');
 162         my $pid;
 163         my $len;
 164         END { kill 'TERM', $pid if defined $pid };
 165         my $nntpd = 'blib/script/public-inbox-nntpd';
 166         my $cmd = [ $nntpd, "--stdout=$out", "--stderr=$err" ];
 167         $pid = spawn_listener({ PI_CONFIG => $pi_config }, $cmd, [ $sock ]);
 168         my $host_port = $sock->sockhost . ':' . $sock->sockport;
 169         my $n = Net::NNTP->new($host_port);
 170         $n->group($group);
 171         my $x = $n->xover('1-');
 172         my %uniq;
 173         foreach my $num (sort { $a <=> $b } keys %$x) {
 174                 my $mid = $x->{$num}->[3];
 175                 is($uniq{$mid}++, 0, "MID for $num is unique in XOVER");
 176                 is_deeply($n->xhdr('Message-ID', $num),
 177                          { $num => $mid }, "XHDR lookup OK on num $num");
 178                 is_deeply($n->xhdr('Message-ID', $mid),
 179                          { $mid => $mid }, "XHDR lookup OK on MID $num");
 180         }
 181         my %nn;
 182         foreach my $mid (@{$n->newnews(0, $group)}) {
 183                 is($nn{$mid}++, 0, "MID is unique in NEWNEWS");
 184         }
 185         is_deeply([sort keys %nn], [sort keys %uniq]);
 186
 187         my %lg;
 188         foreach my $num (@{$n->listgroup($group)}) {
 189                 is($lg{$num}++, 0, "num is unique in LISTGROUP");
 190         }
 191         is_deeply([sort keys %lg], [sort keys %$x],
 192                 'XOVER and LISTGROUPS return the same article numbers');
 193
 194         my $xref = $n->xhdr('Xref', '1-');
 195         is_deeply([sort keys %lg], [sort keys %$xref], 'Xref range OK');
 196
 197         my $mids = $n->xhdr('Message-ID', '1-');
 198         is_deeply([sort keys %lg], [sort keys %$xref], 'Message-ID range OK');
 199
 200         my $rover = $n->xrover('1-');
 201         is_deeply([sort keys %lg], [sort keys %$rover], 'XROVER range OK');
 202 };
 203 {
 204         local $ENV{NPROC} = 2;
 205         my @log = qw(log --no-decorate --no-abbrev --no-notes --no-color);
 206         my @before = $git0->qx(@log, qw(--pretty=oneline));
 207         my $before = $git0->qx(@log, qw(--pretty=raw --raw -r));
 208         $im = PublicInbox::V2Writable->new($ibx, 1);
 209         is($im->{partitions}, 1, 'detected single partition from previous');
 210         my $smsg = $im->remove($mime, 'test removal');
 211         $im->done;
 212         my @after = $git0->qx(@log, qw(--pretty=oneline));
 213         my $tip = shift @after;
 214         like($tip, qr/\A[a-f0-9]+ test removal\n\z/s,
 215                 'commit message propagated to git');
 216         is_deeply(\@after, \@before, 'only one commit written to git');
 217         is($ibx->mm->num_for($smsg->mid), undef, 'no longer in Msgmap by mid');
 218         my $num = $smsg->{num};
 219         like($num, qr/\A\d+\z/, 'numeric number in return message');
 220         is($ibx->mm->mid_for($num), undef, 'no longer in Msgmap by num');
 221         my $srch = $ibx->search->reopen;
 222         my $mset = $srch->query('m:'.$smsg->mid, { mset => 1});
 223         is($mset->size, 0, 'no longer found in Xapian');
 224         my @log1 = (@log, qw(-1 --pretty=raw --raw -r --no-renames));
 225         is($srch->{over_ro}->get_art($num), undef,
 226                 'removal propagated to Over DB');
 227
 228         my $after = $git0->qx(@log1);
 229         if ($after =~ m!( [a-f0-9]+ )A\td$!m) {
 230                 my $oid = $1;
 231                 ok(index($before, $oid) > 0, 'no new blob introduced');
 232         } else {
 233                 fail('failed to extract blob from log output');
 234         }
 235         is($im->remove($mime, 'test removal'), undef,
 236                 'remove is idempotent');
 237         $im->done;
 238         is($git0->qx(@log1),
 239                 $after, 'no git history made with idempotent remove');
 240         eval { $im->done };
 241         ok(!$@, '->done is idempotent');
 242 }
 243
 244 {
 245         ok($im->add($mime), 'add message to be purged');
 246         local $SIG{__WARN__} = sub {};
 247         ok(my $cmts = $im->purge($mime), 'purged message');
 248         like($cmts->[0], qr/\A[a-f0-9]{40}\z/, 'purge returned current commit');
 249         $im->done;
 250
 251         # again
 252         is($im->purge($mime), undef, 'no-op returns undef');
 253 }
 254
 255 {
 256         my $x = 'x'x250;
 257         my $y = 'y'x250;
 258         local $SIG{__WARN__} = sub {};
 259         $mime->header_set('Subject', 'long mid');
 260         $mime->header_set('Message-ID', "<$x>");
 261         ok($im->add($mime), 'add excessively long Message-ID');
 262
 263         $mime->header_set('Message-ID', "<$y>");
 264         $mime->header_set('References', "<$x>");
 265         ok($im->add($mime), 'add excessively long References');
 266         $im->barrier;
 267
 268         my $msgs = $ibx->search->reopen->get_thread('x'x244);
 269         is(2, scalar(@$msgs), 'got both messages');
 270         is($msgs->[0]->{mid}, 'x'x244, 'stored truncated mid');
 271         is($msgs->[1]->{references}, '<'.('x'x244).'>', 'stored truncated ref');
 272         is($msgs->[1]->{mid}, 'y'x244, 'stored truncated mid(2)');
 273         $im->done;
 274 }
 275
 276 done_testing();